DOS Batch Suchen nach bestimmten String in der Logdateien und ein paar Zusatzaufgaben ...

Nun aber zur Sache:
ich bin auf der Suche nach einem Dos Batch-Script, mit dem ich die Fehlersuche in den Logdateien automatisieren kann, dazu folgendes Szenario:

- Diese Script sollte in der tagesaktuellen LOG Dateien ( *.log ) in bestimmten Verzeichnisse ( z.B. C:\test\logs ) nach dem String “ ERROR “ suchen,

- Täglich werden meherere Log Dateien erstellt, daher muss dieses Script in der Lage sein, die schon durchsuchten LOG Dateien, ausser Acht zu lassen,

- Das Ergebnis sollte in einem anderen Verzeichnis ausser C:\test\logs also in einer neuen LOG Datei festgehalten werden, und zwar:
1. Falls keine “ ERROR “ Meldung gefunden : echo “ es sind keine Fehler vorhanden “
2. Falls “ ERROR “ Meldung vorhanden: echo “ ACHTUNG: Fehler in der [ Name der LOG Datei ] “ ausgeben und eine E-Mail mit Fehlerangabe an bestimmte Adresse schicken

- Das Script wird über “ geplante Tasks “ gesteuert und wird mehrmals am Tag ausgeführt.

Es wäre sehr nett wenn Ihr Eure Erfahrungen mit mir teilen könnt, insbesonderes möchte ich den Kollegen BASTLA bitten, sich diese Angelegenheit anzuschauen und mir ein Feedback zu geben.

Danke!

Viele Grüße
tanbud
28.11.2012

@echo off & setlocal


set "LogDirs="E:\Test 1" "E:\Test 2""  
set "MasterLogDir=E:\MasterLog"  
set "ProtocolFile=E:\Protokoll\%Date%.log"  
set "LogFileType=log"  
set "SearchStr=ERROR"  

set "TimeStamp=%Date%_%Time::=-%"  
set "TimeStamp=%TimeStamp:~0,19%"  
set "MasterLogFile=%MasterLogDir%\%TimeStamp%.log"  
set "ErrorFound="  


if not exist "%ProtocolFile%" (  
  type NUL > "%ProtocolFile%"  
)

for %%d in (%LogDirs%) do (
  for /f "tokens=1,2 delims=:" %%f in ('findstr /i /c:"%SearchStr%" "%%~d\*.%LogFileType%"') do (  
    find /i "%%f:%%g" "%ProtocolFile%" 1>NUL 2>NUL || (  
      >>"%ProtocolFile%" echo %%f:%%g  
      >>"%MasterLogFile%" echo ACHTUNG: Fehler in Logfile "%%f:%%g"  
      set "ErrorFound=1"  
    )
  )
)

if not defined ErrorFound (
  >"%MasterLogFile%" echo Es sind keine Fehler vorhanden.  
) else (
  rem Stattdessen hier einen Aufruf von BLAT zum Versenden der EMAIL
  echo Datei %MasterLogFile% per EMail verschicken
)