DOS-Befehl zum Teilen eines Dateinamens gesucht

Hallo alle zusammen!
Ich hoffe sehr, dass mein Problem nicht zu komplex ist.

In der Abteilung Category Management werden regelmäßig Bilder von Produkten mit einer speziellen Kamera geschossen. Diese werden dann in einem Ordner als *.jpg gespeichert. Der Ordnername ist dabei der erste Teil (z.B. 6 Stellen) des EAN-Codes des Produktes, der Restteil der EAN ist der Name der *.jpg-Datei. Danach muss dieser Ordner nochmals in einen Pfad kopiert werden, auf den ein anderes Programm zugreift. Dieses Programm fordert dann aber Dateiendungen namens *.1
Soviel zur Ausgangslage.

Ich schrieb jetzt eine Batch, die genau dies alles durchführt. Dafür war es allerdings als Vorarbeit notwendig, manuell den Ordner mit dem ersten Teil der EAN zu benennen, die Datei darin eben mit dem Restteil.
Die Abteilung will jetzt natürlich, dass die Batch das einfach mal ganz lässig automatisch durchführt *kopfschuettel*.
Also sie wollen, dass man einfach aus dem Kameraprogramm die Bilder mit der vollen EAN als *.jpg speichert, die Batch soll daraus dann die weiteren Operationen starten.

Ein Mitarbeiter meinte, dass man es irgendwie über Umwege lösen kann, indem man den Dateinamen in eine *.txt-Datei kopiert und dann von dort aus teilen kann.
Ich bin dabei gerade total ratlos, wie ich das anstellen soll. Aber vielleicht poste ich erst einmal meine Batch:


Ordner 'a" ist der Ordner, der als temporärer Ordner für die ganze Operation fungiert. In ihm werden nach jetzigem Stand die Ordner mit den Bildern darin angelegt.
Zu Ordner "b" wird der Ordner erst einmal nur kopiert. Die erste Schleife benennt alle enthaltenen Dateien in *.1 um kopiert sie dann zu Ordner 'c" , der von dem anderen Programm genutzt wird. Die letzte Schleife löscht dann den Inhalt des temporären Ordners "a".
Die Schleifen waren übrigens nötig, da die Order und Dateinamen ja immer unterschiedlich sind, und dadurch nie direkt angesprochen werden können.

Ich hoffe ich habe das Problem halbwegs verständlich beschrieben!
Danke schon einmal vorab für jegliche Arten von Überlegungen von Euch!

Viele Grüße
Krauselutze

[Edit Biber] Codeformatierung- Tippfehlerberichtigung. Schliessendes Tag fehlte [/Edit]

@echo off & setlocal
set "verzeichnis=C:\Test\a"  
set "Kopie=C:\Test\b"  
set "Ziel=C:\Test\c"  

xcopy /s /y "%verzeichnis%\*.*" "%Kopie%\"  
for /d %%a in ("%verzeichnis%\*.*") do ren "%%a\*.jpg" "*.1"  
xcopy /s /y "%verzeichnis%\*.*" "%Ziel%\"  
del /f /q "%verzeichnis%\*.1"  
for /d %%i in ("%verzeichnis%\*.*") do rd /s /q "%%i"  

pushd "%verzeichnis%"  
for /f "delims=" %%i in ('dir /b /a-d *.jpg') do (  
    set "Bild=%%i"  
    set "Ordner=!Bild:~,6!"  
    set "Name=!Bild:~6!"  
    md "!Ordner!"  
    move "!Bild!" "!Ordner!\!Name!"  
)
popd

@echo off & setlocal enabledelayedexpansion

echo n|xcopy /s "%verzeichnis%\*.*" "%Ziel%\"

for /d %%i in ("%verzeichnis%\*.*") do (  
    md "%Ziel%\%%~nxi" 2>nul  
    for %%a in ("%%i\*.*") do if not exist "%Ziel%\%%~nxi\%%~nxa" move "%%a" "%Ziel%\%%~nxi\"  
)

for /d %%i in ("%verzeichnis%\*.*") do rd "%%i" 2>nul

@echo off & setlocal enabledelayedexpansion
set "verzeichnis=C:\Test\a"  
set "Kopie=C:\Test\b"  
set "Ziel=C:\Test\c"  

pushd "%verzeichnis%"  
for /f "delims=" %%i in ('dir /b /a-d *.jpg') do (  
    set "Bild=%%~ni"  
    set "Ordner=!Bild:~,6!"  
    set "Name=!Bild:~6!"  
    if not exist "%Ziel%\!Ordner!\!Name!.1" (  
        echo Verarbeite %%i
        xcopy "%%i" "%Kopie%\!Ordner!\!Name!.*">nul  
        md "%Ziel%\!Ordner!\" 2>nul  
        move "%%i" "%Ziel%\!Ordner!\!Name!.1"  
    ) else (
        echo Speichere %%i
        md "!Ordner!" 2>nul  
        move "%%i" "!Ordner!\!Name!.jpg"  
    )
)
popd

xcopy 4527896541234.jpg "%Ziel%\!Ordner!\!Name!.1*"

if "!Bild:~8!"=="" (echo kurz) else (echo lang)

@echo off & setlocal enabledelayedexpansion
set "verzeichnis=C:\Test\neue_Bilder_Temp\Suesse_Brotaufstriche"   
set "Kopie=C:\Test\b"   
set "Ziel=C:\Test\c"   


pushd "%verzeichnis%"   

for /f "delims=" %%i in ('dir /b /a-d *.jpg') do (   

    set "Bild=%%~ni"   

    if "!Bild:~13!"=="" (  

    set "Ordner=!Bild:~,7!"   
    set "Name=!Bild:~7!"   

    if not exist "%Ziel%\!Ordner!\!Name!.1" (   
      
        xcopy "%%i" "%Kopie%\!Ordner!\!Name!.*">nul   
        md "%Ziel%\!Ordner!\" 2>nul   
        move "%%i" "%Ziel%\!Ordner!\!Name!.1"   

    ) else ( 

        md "!Ordner!" 2>nul   
        move "%%i" "!Ordner!\!Name!.jpg"   

    )) else (

    set "Ordner=!Bild:~,5!"   
    set "Name=!Bild:~5!"   

    if not exist "%Ziel%\!Ordner!\!Name!.1" (   
      
        xcopy "%%i" "%Kopie%\!Ordner!\!Name!.*">nul   
        md "%Ziel%\!Ordner!\" 2>nul   
        move "%%i" "%Ziel%\!Ordner!\!Name!.1"   

    ) else ( 

        md "!Ordner!" 2>nul   
        move "%%i" "!Ordner!\!Name!.jpg"   

    ))

) 

popd

@echo off & setlocal enabledelayedexpansion
set "verzeichnis=C:\Test\neue_Bilder_Temp\Suesse_Brotaufstriche"   
set "Kopie=C:\Test\b"   
set "Ziel=C:\Test\c"   

pushd "%verzeichnis%"   
for /f "delims=" %%i in ('dir /b /a-d *.jpg') do (   
    set "Bild=%%~ni"   
    if "!Bild:~13!"=="" (  
        set "Ordner=!Bild:~,5!"   
        set "Name=!Bild:~5!"   
    ) else (
        set "Ordner=!Bild:~,7!"   
        set "Name=!Bild:~7!"   
    )

    if not exist "%Ziel%\!Ordner!\!Name!.1" (  
        xcopy "%%i" "%Kopie%\!Ordner!\!Name!.*">nul  
        md "%Ziel%\!Ordner!\" 2>nul  
        move "%%i" "%Ziel%\!Ordner!\!Name!.1"  
    ) else (
        md "!Ordner!" 2>nul  
        move "%%i" "!Ordner!\!Name!.jpg"  
    )
)
popd