26705
26705
Jun 25, 2007, updated at 13:43:16 (UTC)
view8492
view6
0
Goto Top

Einzelne Zeichen und Strings aus Datei auslesen

GermanQuestionVB for ApplicationsDevelopment
Moin!

Ich habe hier ein kleines Problem, liegt wohl hauptsächlich in meiner fehlenden Erfahrung unter VB & co.

Ich muss verschiedene Dateien innerhalb eines Ordners auslesen und die gewünschten Teile möglichst Excel-kompatibel (ist aber nicht so wichtig) in eine einzige neue Datei schreiben.

Die Dateien sind ca. so aufgebaut:

Steuerzeichenzeichezeichenzeichen123 nochmehrzeichen
name1 text
name2 text
name3 text
name4 text
name5 text
name6 text
name7 text
name8 text
name9 text

usw...

Das fettgedruckte soll ich nun auslesen und in eine andere Datei schreiben.

In der ersten Zeile sind die Zeichen immer an der gleichen Stelle, es sind immer 6 Zeichen.
Darauf folgen ca. 40 - 60 Zeilen, je nach Inhalt ist die Anzahl und somit die Zeilennummer dynamisch.

Dort sollen jetzt noch 5-6 Strings aus verschiedenen Zeilen ausgelesen werden, jeweils ein String pro Zeile.
Allerdings nur, wenn diese Zeile auch vorhanden ist.
Die Zeilen sind immer nach folgendem Schema:
Variablenname1 Wunschstring1
Variablenname2 Wunschstring2


Mein größtes Problem bei der Sache ist, das dieser komplette Block in einigen Datein nur ein Mal vorkommt,
in einigen Dateien aber auch mehrfach vorkommen kann.
Ein solcher Block fängt allerdings immer mit den gleichen fünf Steuerzeichen an.

Ich hoffe ich konnte mein Problem einigermaßen verständlich schildern.
Bin für jede Hilfe und jeden Denkanstoß dankbar.

Gruß,
Seppel
comment-contentCommentShareShare
Share on Facebook Share on Twitter Share on Reddit Share on Linkedin

Content-Key: 62244

Url: https://administrator.de/contentid/62244

Printed on: April 16, 2024 at 04:04 o'clock

6 Comments
Latest comment
Goto Top
Member: bastla
bastla Jun 25, 2007 at 11:40:52 (UTC)
Goto Top
Hallo SeppelCeh!

Verstehe ich das zur ersten Zeile richtig: Aus den ersten 11 Zeichen, von denen die ersten 5 feststehen, werden diese (demnach ohnehin immer Gleichen) und die Zeichen 9 bis 11 benötigt?
Wenn Du "Block" schreibst, meinst Du dann , dass etwa der text nach name1 nur (einmal) interessiert, wenn bereits vorher die Steuerzeichen gefunden wurden, also daraus ein Datensatz für den Excel-Import werden soll?

Falls ja: Soll der Aufbau dieses Satzes etwa so aussehen: Steuerzeichen;123;text;text;...

Grüße
bastla
Mitglied: 26705
26705 Jun 25, 2007 at 11:59:07 (UTC)
Goto Top
Zur ersten Zeile:
Ja, die erste Zeile ist immer nach dem gleichen Schema aufgebaut.
Und ja, ich benötige immer die gleichen Zeichen aus der ersten Zeile, in der Datei sind es die Zeichen 25 bis 30, die Steuerzeichen benötige ich nicht.
Ein "Block" besteht immer aus der Zeile mit den Steuerzeichen usw. und darauf folgen dann halt die anderen Zeilen mit den verschiedenen Variablen. Der nächste "Block" beginnt dann wieder mit der Steuerzeile, auf die all die anderen Zeilen folgen.
Die Zeilen mit den Variablen sind identisch aufgebaut.
Sie beginnt mit einem festen und eindeutigen Variablennamen, Leerzeichen, Test.

Falls ja: Soll der Aufbau dieses Satzes etwa so aussehen: Steuerzeichen;123;text;text;...

Ja, jeweils ein "Block" ist ein Datensatz bzw. eine Zeile für die Ausgabedatei.
Member: bastla
bastla Jun 25, 2007 at 12:03:39 (UTC)
Goto Top
Hallo SeppelCeh!

Noch zu den übrigen Zeilen: Ist deren Reihenfolge (oder sogar deren Zeilenabstand) und Anzahl fix, gibt es also immer name1, name2, name4, ... (ev sogar als auf die "Steuerzeile" folgende Zeilen 1, 2, 4 etc)?

Grüße
bastla
Mitglied: 26705
26705 Jun 25, 2007 at 12:15:41 (UTC)
Goto Top
Die Zeilen sind leider nicht immer vorhanden, sie sind nur vorhanden wenn sie auch benötigt werden, sie folgen auch nicht direkt aufeinander.

Die Reihenfolge ist immer die gleiche, allerdings gibt es nicht immer alle Zeilen.
Es sind je nach Bedarf ca. 40-60 Zeilen, können auch mal mehr sein, pro "Block" wohlgemerkt.
Aus den Zeilen benötige ich dann immer die Werte zu den gewünschten 5-6 Variablen, sofern sie denn vorhanden sind.
Member: bastla
bastla Jun 25, 2007 at 13:27:19 (UTC)
Goto Top
Hallo SeppelCeh!

Da Du in Deinen Angaben wenig konkret warst, musste ich auch das Script eher allgemein halten:
strOutFile = "D:\Import.txt"  
strCtrl = "S" & "t" & "e" & "u" & "Z"  
intNumberFrom = 25
intNumberTo = 30
aKeys = Array("name1", "name2", "name4", "name6", "name7", "name9")  
strDelim = ";"  

' Ab hier (hoffentlich) keine Änderungen erforderlich ...  
intNoOfKeys = UBound(aKeys)
Dim aKeysLen(), aValues()
ReDim aKeysLen(intNoOfKeys)
For i = 1 To intNoOfKeys
	aKeysLen(i) = Len(aKeys(i))
Next
intCtrlLen = Len(strCtrl)
intNumberLen = intNumberTo - intNumberFrom + 1
If intNumberLen < 1 Then
	WScript.Echo "Bereich für Nummer aus erster Zeile nicht korrekt!"  
	WScript.Quit(1)
End If

If WScript.Arguments.Count < 1 Then
    WScript.Echo "Bitte eine Datei als Argument übergeben!"  
    WScript.Quit(1)
Else
	strInFile = WScript.Arguments(0)
End If
Set fso = CreateObject("Scripting.FileSystemObject")  
If Not fso.FileExists(strInFile) Then
    WScript.Echo "Die Datei " & strInFile & " wurde nicht gefunden!"  
    WScript.Quit(1)
End If

aLines = Split(fso.OpenTextFile(strInFile, 1).ReadAll, vbCrLF)
Set objOutFile = fso.OpenTextFile(strOutFile, 8, True)
blnFound = False
For i = 0 to UBound(aLines)
	strThisLine = aLines(i)
	If blnFound Then
		If Left(strThisLine, intCtrlLen) = strCtrl Then
			blnFound = False
			strLine = strNumber
			For j = 1 To intNoOfKeys
				strLine = strLine & strDelim & aValues(j)
			Next
			objOutFile.WriteLine strLine
		End If
		For j = 1 To intNoOfKeys
			If Left(strThisLine, aKeysLen(j)) = aKeys(j) Then
				aValues(j) = Mid(strThisLine, aKeysLen(j) + 2)
				Exit For
			End If
		Next
	End If
	If Not blnFound Then
		If Left(strThisLine, intCtrlLen) = strCtrl Then
			blnFound = True
			strNumber = Mid(strThisLine, intNumberFrom, intNumberLen)
			ReDim aValues(intNoOfKeys)
		End If
	End If
Next
If blnFound Then
	strLine = strNumber
	For j = 1 To intNoOfKeys
		strLine = strLine & strDelim & aValues(j)
	Next
	objOutFile.WriteLine strLine
End If
objOutFile.Close
WScript.Echo "Done: " & strInFile
Die Werte am Anfang des Scripts (Zieldatei, die einzelnen Steuerzeichen - ev als Chr(x) geschrieben, die Positionsangaben zur "Nummer" - von mir so bezeichnet, weil Du im ersten Beispiel "123" verwendet hast - aus der Steuerzeile, die konstanten face-wink "Variablen" - ich nenne sie "Keys" - und das Trennzeichen für den Import) musst Du natürlich anpassen.

Als Wert des einzelnen "Keys" wird jeweils der Rest der Zeile (nach dem Leerzeichen) verwendet.

Wurde ein "Key" nicht gefunden, wird in der Datenzeile der Platz dafür frei gelassen (es folgen dann 2 Trennzeichen aufeinander - damit bleibt der Satzaufbau erhalten). Gefunden wird ein "Key" nur bei exakt gleicher Schreibweise (Groß-/Kleinschreibung) - lässt sich natürlich ändern.

Um damit verschiedene Quelldateien bearbeiten zu können, erwartet das Script die jeweilige Ausgangsdatei als Argument - damit wird zB auch eine Kommandozeileneingabe der Art
for %i in (D:\Testdaten\Test*.txt) do @cscript //nologo Script.vbs "%i"
sowie die Übergabe per Drag & Drop aus dem Explorer möglich.

Grüße
bastla
Mitglied: 26705
26705 Jun 25, 2007 at 13:43:13 (UTC)
Goto Top
Oha, ich bin ja schwer begeistert!
Mit einem kompletten Script habe ich absolut nicht gerechnet eher mit Denkanstößen. ^^

Wegen der schwammigen Angaben tut es mir leid, ich habe selbst bisher auch nur Testdateien zur Verfügung, sind halt noch keine fertigen Versionen.
Die Keys kenne ich auch noch nicht, auch die gewünschten Ausgaben nicht.
Werde das Script gleich mal meinen Testdateien anpassen und ausprobieren.

Besten Danke auch!!!

Gruß,
Seppel
GermanQuestionVB for ApplicationsDevelopment