Excel bedingte Formatierung per Formel mit übernehmen

Option Explicit
Option Compare Text

Private Sub Worksheet_Activate()
    Dim objRegExp As Object, objMatch As Object, objCells As Range
    
    'Object Regular-Expression einbinden  
    Set objRegExp = CreateObject("VBScript.RegExp")  
    
    'Object Regular-Expression (Formel-Auswertung) initialisieren  
    'SubMatches(0) = Matrix-Zell-Adresse <Pizza> Ja/Nein (Beispiel: MATRIX!$C15)  
    'SubMatches(1) = Matrix-Zell-Adresse <Value> (Beispiel: MATRIX!D15)  
    With objRegExp
        .Global = False
        .IgnoreCase = True
        .Pattern = "matrix!\$?(\w+)=.*matrix!(\w+),"  
    End With
    
    'Alle Zellen im Anwendungsbereich nach Formeln durchsuchen  
    For Each objCells In ActiveSheet.UsedRange
        'Test ob Zelle eine Formel enthält  
        If Left(objCells.Formula, 1) = "=" Then  
            'Wenn Ja, Zell-Addressen ermitteln  
            Set objMatch = objRegExp.Execute(objCells.Formula)
            
            'Test ob Formel entsprechende Matrix-Zell-Bezüge enthält  
            If objMatch.Count Then
                With Sheets("Matrix")  
                    'Test ob Zelle den Wert <Pizza> enthält  
                    If .Range(objMatch(0).SubMatches(0)).Value Like "*pizza*" Then  
                        'Wenn Ja, dann Zellfarbe übernehmen  
                        objCells.Interior.Color = .Range(objMatch(0).SubMatches(1)).Interior.Color
                    Else
                        'Wenn Nein, dann Zellfarbe löschen  
                        objCells.Interior.Pattern = xlNone
                    End If
                End With
            End If
        End If
    Next
End Sub