Hilfe beim Batch Skript

@echo off

:: Product
for /f "tokens=1,2,*" %%i in ('reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v ProductName') do (  
	set ProductName=%%k
)

::Release
for /f "tokens=1,2,*" %%i in ('reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v ReleaseId') do (  
	set Release=%%k
)

:: Build
for /f "tokens=4-6 delims=.] " %%i in ('ver') do (  
	set MajorVersion=%%i
	set MinorVersion=%%j
	set Build=%%k
)
for /f "tokens=3" %%i in ('reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v UBR') do (  
	set /a UpdateBuildRevision=%%i
)
set BuildComplete=%MajorVersion%.%MinorVersion%.%Build%.%UpdateBuildRevision%

:: Architecture
for /f %%i in ('wmic os get OSArchitecture ^| find "bit"') do (  
	set Architecture=%%i
)

:: UI-Language
for /f "tokens=3" %%i in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sLanguage') do (  
	set UILanguage=%%i
)

:: OS-Language
for /f %%i in ('wmic os get OSLanguage') do (  
	REM https://www.autoitscript.com/autoit3/docs/appendix/OSLangCodes.htm
	if "%%i" == "1031" set OSLanguage=deu.  
	if "%%i" == "1033" set OSLanguage=eng.  
)
REM oder
for /f "tokens=3" %%i in ('powershell [CultureInfo]::InstalledUICulture') do (  
	set OSLanguage=%%i
)
set OSLanguage=%OSLanguage:~0,3%.

:: Output
REM goto output2
:output1
echo(
echo ProductName        : %ProductName%
echo Release            : %Release%
echo MajorVersion       : %MajorVersion%
echo MinorVersion       : %MinorVersion%
echo Build              : %Build%
echo UpdateBuildRevision: %UpdateBuildRevision%
echo BuildComplete      : %BuildComplete%
echo Architecture       : %Architecture%
echo UILanguage         : %UILanguage%
echo OSLanguage         : %OSLanguage%
echo(

:output2
echo %ProductName% %Architecture% ^(%OSLanguage%/%UILanguage%^), %Release% ^(%BuildComplete%^)

ProductName        : Windows 10 Pro
Release            : 1703
MajorVersion       : 10
MinorVersion       : 0
Build              : 15063
UpdateBuildRevision: 332
BuildComplete      : 10.0.15063.332
Architecture       : 64-bit
UILanguage         : DEU
OSLanguage         : Eng.

Windows 10 Pro 64-bit (Eng./DEU), 1703 (10.0.15063.332)