Inputbox abbrechen mit wsh

Hallo,

ich versuche die ganze zeit, das wenn der user auf Abbrechen klickt das es auch schließt und bei keiner Eingabe das der Vorgang wiederholt wird. Hätte da einer eine Idee??

Das wäre meine Inputbox,

	rechnernummer = CStr(InputBox("Rechnernummer bitte ohne Domain eingeben:" & Chr(13) & CHr(13) & "", msgTitel, "Rechnername eingeben (ohne Backlashe)"))  

	if rechnernummer = cancel Then
		wscript.quit
	End if

	if rechnernummer = "" Then  
		MsgBox "Sie haben leider keine Rechnernummer eingegeben."& Chr(13) & CHr(13) &"Klicken Sie auf - OK - und wiederholen Sie diesen Vorgang!",,msgTitel  
		rechnernummer = CStr(InputBox("Rechnernummer bitte ohne Domain eingeben:" & Chr(13) & CHr(13) & "", msgTitel, "Rechnername eingeben (ohne Backlashe)"))  
	End if

Würde mich sehr über eine weitere Hilfe freuen.

Gruß,
m0nstar

Please also mark the comments that contributed to the solution of the article

Content-Key: 120963

Url: https://administrator.de/contentid/120963

Printed on: April 19, 2024 at 04:04 o'clock

7 Comments

Latest comment

Hallo m0nstar!

Wenn in der Input-Box Abbrechen oder Schließen betätigt wird oder Leer und OK, dann gibt die Input-Box einen Leerstring zurück ("").

Gruß Dieter

Hallo m0nstar!

Wie didi1954 schon erklärt hat, lässt sich nicht unterscheiden, ob "Abbrechen" gewählt oder einfach ein Leerstring eingegeben wurde - um allerdings ein irrtümliches "Enter" bzw einem vorzeitigen Klick auf "OK" zu erkennen, kannst Du einfach der InputBox einen Defaultwert mitgeben (was Du ja offensichtlich ohnehin vorhattest) und die Eingabe darauf hin untersuchen, also etwa:

Default = "Rechnername eingeben (ohne Backlashes)"  
Do
    OK = True
    
    rechnernummer = InputBox("Rechnernummer bitte ohne Domain eingeben:" & Chr(13) & CHr(13), msgTitel, Default)  

    if rechnernummer = "" Then  
	    wscript.quit
    End if

    if InStr(rechnernummer, Default) > 0 Then
	    MsgBox "Sie haben leider keine Rechnernummer eingegeben."& Chr(13) & CHr(13) &"Klicken Sie auf - OK - und wiederholen Sie diesen Vorgang!",,msgTitel  
        OK = False
    End if
    
Loop Until OK
WScript.Echo rechnernummer

Die Konstruktion mit dem Schalter "OK" erlaubt Dir, ggf noch weitere Ausschlussbedingungen zu formulieren (dann jeweils wieder "OK" auf "False" setzen - "True" darf nur am Beginn der Schleife vergeben werden).

Grüße
bastla

Als Ergänzung (aufgrund der per PM gestellten Zusatzfrage, wie ein irrtümliches Beenden durch eine Rückfrage verhindert werden kann):

Ersetze die Zeilen 7 bis 9 durch

if rechnernummer = "" Then  
    OK = False
    Answer = MsgBox("Wollen Sie wirklich das Programm beenden?", VbYesNo, "Programm beenden?")  
    if not Answer = vbNo Then wscript.quit
End if

Hier wird die MsgBox als Function verwendet und liefert daher einen Rückgabewert, der ausgewertet werden kann. Wenn "Nein" gewählt wurde, sorgt der oben schon erwähnte Schalter "OK" dafür, dass die Eingabe wiederholt werden kann.

Grüße
bastla

Hallo bastla!

Zitat von @bastla:
Als Ergänzung (aufgrund der per PM gestellten Zusatzfrage, wie
ein irrtümliches Beenden durch eine Rückfrage verhindert
werden kann):

Dann doch eher die andere Variante?

Wenn Str = Vorgabe-Str, Dann MsgBox, Sonst abbrechen

Ich persönlich bin ziemlich genervt , wenn ich z.B. auf Abbrechen oder Schließen klicke und dann nochmal gefragt werde, ob ich denn nun auch wirklich abbrechen möchte

Aber, das ist wohl Ansichtssache!

Dein Urlaub war aber kurz

Gruß Dieter

@76109

Ich persönlich bin ziemlich genervt , wenn ich z.B. auf Abbrechen oder Schließen klicke und dann nochmal gefragt werde, ob ich denn nun auch wirklich abbrechen möchte

Da bin ich völlig bei Dir (Rückfragen der Art "Wollen Sie tatsächlich dieses Super-Duper-Über-Drüber-Programm ohne Angabe eines Entschuldigungsgrundes jetzt schon beenden?" stören mich auch sehr) - war aber so gewünscht ...

Dein Urlaub war aber kurz

'Tschuldigung, dass ich schon wieder da bin ...