IP Adressen aus Textdatei mit Hostnamen auflösen.

@ECHO off & setlocal
title Find IP-Adressen
REM   find_IP Version 2.0 veh 2013-03-29
cd /D %~dp0

	REM Standard-Vorgabe:
	SET "ping_anzahl_A=1"  
	SET "ping_wartezeit_A=200"  
	SET "Anzahl_Logfiles=40"  

REM == Aktuelles Datum und Uhrzeit werden formatiert und Variablen zugewiesen ==
FOR /F "tokens=1-3 delims=/. " %%a in ('date/T') do set CDATE=%%c-%%b-%%a  
FOR /F "tokens=1-2 delims=/: " %%a in ('time/T') do set CTime=%%a-%%b  
if exist "ip_adressen.txt" ren "ip_adressen.txt" "ip_adressen_%CDATE% %CTime%.txt"  

ECHO.
ECHO     Aktuelles Netz:
ECHO     ---------------
ipconfig
ECHO.
ECHO.
ECHO.
ECHO     Finde IP-Adressen:
ECHO     ------------------
ECHO.
ECHO     Es wird eine Textdatei mit IP-Adressen im gleichen Verzeichnis angelegt.
ECHO.
ECHO     Bitte geben Sie den ERSTEN TEIL des IP-Netzwerkes ein:
ECHO.
ECHO     Den OEFFENTLICHEN TEIL angeben:
ECHO     z.Bsp.:  192.168.178.  (inkl. letztem Punkt!)
ECHO.
ECHO.
ECHO Eingabe und Enter:
set /p ip=
Echo.

ECHO.>> ip_adressen.txt
Echo Startzeit: %DATE% - %time%>> ip_adressen.txt
ECHO.>> ip_adressen.txt

:wh
ECHO ANZAHL DER PING-VERSUCHE eingeben und Enter- oder
ECHO Enter = Standard = "%ping_anzahl_A%"  
ECHO Eingabe:
set /p ping_anzahl=

ECHO MAX. ANTWORT-WARTEZEIT auf Ping eingeben und Enter - oder
ECHO Enter = Standard = "%ping_wartezeit_A% ms"  
ECHO Eingabe:
set /p ping_wartezeit=

ECHO DAUERTEST? (laeuft bis zum manuellem Abbruch)
ECHO Enter = NEIN       1 und Enter für Dauertest
ECHO Eingabe:
set /p Dauertest=

ECHO ===================================================>> ip_adressen.txt
ECHO      EIGENE IP-ADRESSE(N):>> ip_adressen.txt
ECHO ===================================================>> ip_adressen.txt
ipconfig /all>> ip_adressen.txt
ECHO.>> ip_adressen.txt && (ECHO.>> ip_adressen.txt)
ECHO.

:wh2
ECHO.
if "%ping_anzahl%"=="" set ping_anzahl=%ping_anzahl_A%  
if "%ping_wartezeit%"=="" set ping_wartezeit=%ping_wartezeit_A%  
set "wh="  
if exist ip_temp.txt del ip_temp.txt >nul
if exist ip_temp2.txt del ip_temp2.txt >nul

ECHO ===================================================>> ip_adressen.txt
ECHO      ERKANNTE IP-ADRESSE(N):>> ip_adressen.txt
ECHO ===================================================>> ip_adressen.txt
ECHO.>> ip_adressen.txt
ECHO Ping Anzahl=%ping_anzahl% >> ip_adressen.txt
ECHO Ping Wartezeit=%ping_wartezeit% >> ip_adressen.txt
ECHO.>> ip_adressen.txt

ECHO Starte Scan: && ECHO ----------- && ECHO.

for /L %%N IN (1, 1, 255) DO (
        ECHO IP: %ip%%%N wird angepingt.
		REM -n Ping n-mal; -w Warte max. Mili-Sekunden auf Antwort.
        ping %ip%%%N -n %ping_anzahl% -w %ping_wartezeit% | find "TTL">> ip_temp2.txt && ECHO %ip%%%N>> ip_temp.txt && ECHO IP: %ip%%%N erkannt.  
        Rem   ping %ip%%%N -n 1 | find "TTL" && ECHO %ip%%%N>> ip_temp.txt  
)
rem type ip_temp.txt>> ip_adressen.txt
rem ECHO.>> ip_adressen.txt
type ip_temp2.txt>> ip_adressen.txt
ECHO.

ECHO.>> ip_adressen.txt
ECHO ===================================================>> ip_adressen.txt
ECHO      ERKANNTE Hostnamen: (nslookup)>> ip_adressen.txt
ECHO ===================================================>> ip_adressen.txt
ECHO.>> ip_adressen.txt

ECHO.
for /f %%i in (ip_temp.txt) do call :ProcessIP %%i
goto next1
goto :eof

:ProcessIP
set "Host="  
for /f "tokens=2" %%a in ('nslookup %1^|findstr /b "Name:"') do echo %1: %%a>> ip_adressen.txt  
goto :eof

:next1

ECHO.>> ip_adressen.txt
ECHO ***************************************************>> ip_adressen.txt
ECHO.>> ip_adressen.txt
ECHO    Fertig - Endzeit: %DATE% - %time%>> ip_adressen.txt
ECHO.>> ip_adressen.txt

cls
type ip_adressen.txt

if "%Dauertest%"=="1" ECHO.>> ip_adressen.txt && ECHO.>> ip_adressen.txt && (ECHO *** DAUERTEST ***>> ip_adressen.txt) && ECHO.>> ip_adressen.txt  
if "%Dauertest%"=="1" ECHO. && ECHO. && (ECHO *** DAUERTEST ***) && ECHO. && ECHO. && (goto wh2)  

ECHO. && ECHO. && ECHO.
ECHO   Wiederhole IP-Scan im selben Netz?
ECHO ---------------------------------
ECHO   Taste 1 und Enter = Wiederhole Scan.
ECHO.
ECHO   Enter = IP-Liste mit Datum speichern und Beenden.
ECHO.
set /p wh=
if "%wh%"=="1" ECHO. && (ECHO     Wiederhole IP-Scan) && ECHO. && (ECHO    *** WIEDERHOLE SCAN: ***>> ip_adressen.txt) && (ECHO.>> ip_adressen.txt) && (ECHO.>> ip_adressen.txt) && goto wh  
if "%wh%"=="" goto End  

:End
ren "ip_adressen.txt" "ip_adressen_%CDATE% %CTime%.txt"  
ECHO.

REM Lösche alte ip_adressen Dateien, lasse Anzahl n neueste stehen.
FOR /f "skip=%Anzahl_Logfiles% delims=" %%i IN ('dir "ip_adressen*.txt" /a-d /b /o-d') DO (  
del "%%~i"  
)
if exist ip_temp.txt del ip_temp.txt >nul
if exist ip_temp2.txt del ip_temp2.txt >nul
EXIT