MAC-Adressen mit Host-Namen im LAN ermitteln

@echo off & setlocal

:: ----- Config ------
set "IPNet=172.50.1"  
set "HostStart=1"  
set "HostEnd=3"  
set "NumPings=1"  
set "WaitMs=100"  
set "OutFile=Protokoll.txt"  
:: --- Config End ----


:: ----- Init, don't touch! ----- 
set "Host="  
set "MAC="  
set "NotFound="  
:: ---------- Init End ----------

type NUL > "%OutFile%"  

for /l %%i in (%HostStart%, 1, %HostEnd%) do (
  call :DoPing "%IPNet%.%%i"  
)

exit /b 0



:DoPing
  for /f "tokens=1* delims=:" %%a in ('ping /n %NumPings% /w %WaitMs% /a %~1 ^| findstr /n "^"') do (  
    if "%%a" equ "2" (  
      for /f "tokens=5" %%c in ("%%b") do (  
        set "Host=%%c"  
      )

    ) else if "%%a" equ "3" (  
      set "NotFound="  
      
      echo "%%b" | find /i "Zeitüberschreitung der Anforderung" > NUL && (  
        set "NotFound=1"  
      ) || (
        echo "%%b" | find /i "Zielhost nicht erreichbar" > NUL && (  
          set "NotFound=1"  
        )
      )

    ) else if not defined NotFound (
      echo "%%b" | find /i "% Verlust" | find /i /v "100% Verlust" > NUL && (  
        call :DoARP "%~1" && (  
          call :WriteData
        )
      )
    )
  )
exit /b 0


:DoARP
  for /f "skip=3 tokens=2" %%d in ('arp -a %~1') do (  
    set "MAC=%%d"  
  )
if "MAC" neq "" (exit /b 0) else (exit /b 1)  


:WriteData
  >>"%OutFile%" echo %Host%;%MAC%  
  set "Host="  
  set "MAC="  
exit /b 0