Office 2010 Word Vorlage falsche Fusszeile

Const pathDocs = "C:\Docs"  
Const wdHeaderFooterEvenPages =  3 
Const wdHeaderFooterFirstPage =  2 
Const wdHeaderFooterPrimary = 1
Dim counter, strFailureDocs
counter = 0

Set fso = CreateObject("Scripting.FileSystemObject")  
Set objWord = CreateObject("Word.Application")  
'Wenn der Vorgang nicht sichtbar ausgeführt werden soll folgende Zeile auf 'False' setzen  
objWord.Visible = True
objWord.DisplayAlerts = False
For Each file In fso.GetFolder(pathDocs).Files
    If LCase(Right(file.Name, 4)) = "docx" Or LCase(Right(file.Name, 3)) = "doc" Or LCase(Right(file.Name, 3)) = "dot" Or LCase(Right(file.Name, 4)) = "dotx" Or LCase(Right(file.Name, 4)) = "dotm" Then  
    	
    	On Error Resume Next
    	'Öffne Dokument  
        Set doc = objWord.Documents.Open(file.Path)
        If Err.Number = 0 Then
                        'Zähle bearbeitete Dokumente  
                	counter = counter + 1
			For Each section In doc.Sections
		    	'leere alle Fußzeilen außer der auf der ersten Seite  
		    	section.Footers(wdHeaderFooterEvenPages).Range.Delete
		    	section.Footers(wdHeaderFooterPrimary).Range.Delete
		        
		    	'Setze den Inhalt der folgenden Fußzeilen gleich der Fußzeile der ersten Seite des Abschnitts  
		    	section.Footers(wdHeaderFooterFirstPage).Range.Copy
		    	section.Footers(wdHeaderFooterPrimary).Range.Paste
		         
			Next
			'keine unterschiedlichen Fußzeilen für gerade und ungerade Seiten  
		    doc.PageSetup.OddAndEvenPagesHeaderFooter = False
			
			'Speichere und schließe Dokument  
			doc.save
			doc.Close True
		Else
			strFailureDocs = strFailureDocs & file.Path & vbNewLine
			Err.Clear
		End If
    End If
Next
objWord.DisplayAlerts = False
objWord.Quit True
MsgBox counter & " Dokumente bearbeitet!"  
If strFailureDocs <> "" Then  
	MsgBox "Folgende Dokumente wurden wegen eines Fehlers beim Öffnen nicht bearbeitet: " & vbNewLine & strFailureDocs, vbExclamation  
End If