Outlook 2007 Bei start von outlook alle vorher geöffneten emails automatisch öffnen

Dim WithEvents objExplorer As Explorer

Private Sub objExplorer_Activate()
    SaveSession
End Sub

Private Sub Application_Startup()
    Set objExplorer = ActiveExplorer
    RestoreSession
End Sub

Sub SaveSession()
    On Error Resume Next
    Dim ins As Inspector, strPath As String, fso As Object, f As Object
    strPath = Environ("Temp") & "\last_session_state.txt"  
    Set fso = CreateObject("Scripting.FileSystemObject")  
    If Application.Inspectors.Count > 0 Then
        Set f = fso.OpenTextFile(strPath, 2, True)
        For Each ins In Inspectors
            f.WriteLine (ins.CurrentItem.EntryID)
        Next
        f.Close
    Else
        fso.OpenTextFile(strPath, 2, True).Write ""  
    End If
    Set fso = Nothing
End Sub
Sub RestoreSession()
    On Error Resume Next
    Dim fso As Object, strPath As String, itm As Object
    Set fso = CreateObject("Scripting.FileSystemObject")  
    strPath = Environ("Temp") & "\last_session_state.txt"  
    
    If fso.FileExists(strPath) Then
        For Each strEntryID In Split(fso.OpenTextFile(strPath, 1).ReadAll, vbNewLine)
            If strEntryID <> "" Then  
                Set itm = Application.Session.GetItemFromID(strEntryID)
                If Not itm Is Nothing Then itm.Display
            End If
        Next
    End If
    Set fso = Nothing
End Sub