Problem beim Umbenennen von Dateinamen (if - else)

Hallo zusammen,

ganz frisch als Newbee angemeldet

Ich habe festgestellt, das es hier doch einige großartige Cracks gibt, die mir
(hoffentlich) weiterhelfen können.

Ich bin selbst nicht gerade der ungekrönte König bezgl. Batch Programmierung,
aber so zum Hausgebrauch gehts schon.

Hier komme ich aber nicht wirklich weiter:

Ich möchte einen Batch schreiben, bei dem sich die daraufgezogene Datei
umbenennt in z.B. "Dateiname.zip_"

Hintergrund ist, dass ich manchmal mehrere Dateien (meistens 2) mit demselben Namen
habe (bzw. erzeugen muss).
Die "alte" Datei möchte ich dazu kurz mal umbenennen, eben von "Dateiname.zip" in "Dateiname.zip_"

Das funktioniert mit u.a. Batch ja schon ganz nett.
Problem ist das Rück- Umbenennen. Ich krieg zwar festgestellt das der Dateiname mit nem Underbar
endet, aber als Vergleich in der IF - ELSE Geschichte funktioniert das net. Kann es sein, das IF beim
Zeichenkettenvergleich keine Wildcards zulässt oder was mach ich falsch.

##########################################################################

 ::
:: 09.12.2007 / 20:20:00
::
:: Dateien mittels Kontextmenü schnell umbenennen
:: Aus z.B. Diesesprogramm.exe wird Diesesprogramm.exe_
::
:: Ist die Datei auf diese Weise schon umbenannt wird sie 
:: wieder zurückbenannt

@echo on & setlocal enableDelayedExpansion

:: Erst mal den kompletten Dateinamen nebst Pfad setzen
Set Dateiname=%1

:: Hier den Pfad (sPATH) und den Dateinamen (sFILE) und die
:: Extension (sPart2) setzen

for %%i in (%Dateiname%) do set sPATH=%%~di%%~pi
for %%i in (%Dateiname%) do set sFILE=%%~ni%%~xi
for /F "delims=. tokens=2" %%i in ("%Dateiname%") do set sPart2=%%i  

:: Hier testen ob die Datei schon umbenannt ist
set ende="*_"  
if %sPart2%==%ende% (
goto FilenameOld
) Else (
goto Umbenennen
)

::############### Sprungziele ########################

:Umbenennen
:: Dem Dateinamen ein Underbar dranhaengen
Set DateinameNeu=%sFile%_

:: In den Pfad wechseln
cd /d %sPath%

:: und Umbenennen
ren "%sFile%" "%DateinameNeu%"  
exit 0

:FilenameOld
:: Den Underbar am Ende abschneiden
set OriName=%sFile:~0,-1%

:: In den Pfad wechseln
cd /d %sPath%

:: und Umbenennen
ren "%sFile%" "%OriName%"  
exit 0

########################################################################

Kann mir da jemand behilflich sein?

Dank & Grüße

Werner

PS: Ich weiss das es Kontextmenü Utilities gibt like rjhextension o.ä.
aber so mit einem Klick funktionieren die eben auch nicht

Ups... nochmal PS:

Betriebssystem Windows XP SP2
Intel 2,8 GHZ HT, 2 GB RAM

[Edit Biber] Code in ebensolche Tags gesetzt. Welcome auch von mir. [/Edit]

Please also mark the comments that contributed to the solution of the article

Content-Key: 75931

Url: https://administrator.de/contentid/75931

Printed on: April 23, 2024 at 18:04 o'clock

3 Comments

Latest comment

Hallo qwertzy und willkommen im Forum!

Da Du das letzte Zeichen der Extension (damit also eigentlich das letzte Zeichen von sFILE - dies besonders auch, wenn eine Datei keine Extension oder auch einen oder mehrere "." im Namen hat) vergleichen willst, musst Du dies auch entsprechend angeben:

set ende=_
if "%sFILE:~-1%"=="%ende%" (  

Anmerkung dazu: Die Setzung der Anführungszeichen für %ende% erst in der "if"-Zeile finde ich (hier) übersichtlicher.

Und da ich nun schon mal dabei bin:
"enabledelayedexpansion" ist in Deiner Version nicht erforderlich und sollte daher auch nicht verwendet werden, da es ansonsten Probleme bei Dateinamen/Pfaden mit enthaltenen "!" gibt (diese werden dann nämlich weg gelassen).

Auch die Zerlegung des Dateinamens in Einzelbestandteile ist (für den von Dir geschilderten Zweck) nicht nötig - gebraucht wird zum Umbenennen nur Name+Extension.

Ein gestraffte Fassung würde dann etwa so aussehen:

::
:: 09.12.2007 / 21:20:00
::
:: Dateien mittels Kontextmenü schnell umbenennen
:: Aus z.B. Diesesprogramm.exe wird Diesesprogramm.exe_
::
:: Ist die Datei auf diese Weise schon umbenannt wird sie
:: wieder zurückbenannt

@echo off & setlocal
:: Hier den Dateinamen (sFILE) setzen
for %%i in (%1) do set sFILE=%%~nxi

:: Hier testen ob die Datei schon umbenannt ist
set ende=_
if "%sFILE:~-1%"=="%ende%" (  
goto FilenameOld
) Else (
goto Umbenennen
)

::############### Sprungziele ########################

:Umbenennen
ren %1 *.*%ende%
goto :eof

:FilenameOld
:: Den Underbar am Ende abschneiden
set OriName=%sFile:~0,-1%

:: und Umbenennen
ren %1 "%OriName%"  

Noch zur Verwendung von "exit": Wenn Du nicht vorhast, damit einen Errorlevel an einen aufrufenden Batch zurückzugeben, solltest Du es durch "goto :eof" ersetzen - der Vorteil ist besonders beim Testen von der Kommandozeile ersichtlich.

Grüße
bastla

[Edit] Da schon mal die Variable %ende% verwendet wird, diese auch konsequenter Weise beim Umbenennen einsetzen ...

Ansonsten (zugegebener Maßen etwas weniger ausführlich

@echo off & setlocal
set sFILE=%~nx1
if "%sFILE:~-1%"=="_" (ren %1 "%sFile:~0,-1%") Else ren %1 *.*_  

[/Edit]

Hallo qwertzy und willkommen im Forum!

Danke

Da Du das letzte Zeichen der Extension
(damit also eigentlich das letzte Zeichen von
sFILE - dies besonders auch, wenn eine Datei
keine Extension oder auch einen oder mehrere
"." im Namen hat) vergleichen
willst, musst Du dies auch entsprechend
angeben:

set ende=_
> if
> "%sFILE:~-1%"=="%ende%"  
> (
> 

Anmerkung dazu: Die Setzung der
Anführungszeichen für %ende% erst
in der "if"-Zeile finde ich (hier)
übersichtlicher.

Ja, Ja, stimmt schon, aber so im Verlauf des Rumexperimentierens hat die
Struktur (und auch ein bissle mein Blutdruck

) gelitten.

Und da ich nun schon mal dabei bin:
"enabledelayedexpansion" ist in
Deiner Version nicht erforderlich und sollte
daher auch nicht verwendet werden, da es
ansonsten Probleme bei Dateinamen/Pfaden mit
enthaltenen "!" gibt (diese werden
dann nämlich weg gelassen).

Da haste unbestritten recht

Auch die Zerlegung des Dateinamens in
Einzelbestandteile ist (für den von Dir
geschilderten Zweck) nicht nötig -
gebraucht wird zum Umbenennen nur
Name+Extension.

Ich war schon froh, dass ich im I-Net so ne entsprechende FOR Kiste gefunden habe
Mit diesem FOR Gedöns steh ich nämlich erheblich aufm Kriegsfuss, so rein verständnis-
halber gesehen

Noch zur Verwendung von
"exit": Wenn Du nicht vorhast,
damit einen Errorlevel an einen aufrufenden
Batch zurückzugeben, solltest Du es
durch "goto :eof" ersetzen - der
Vorteil ist besonders beim Testen von der
Kommandozeile ersichtlich.

Grüße
bastla

Stimmt!

Habs mal probiert...
und es funktionuckelt prächtlings

Vielen, vielen Dank
Wenn ich mal wieder Bauchschmerzen habe komme ich gerne wieder

Grüße
Werner