Probleme Im Batch Menü

@echo off &setlocal

:: *** BENUTZERDEFINIERTE EINSTELLUNGEN ***
:: Menütitel
set "headline=SYSTEM-PROGRAMME"  

:: Menüpunkte, in Anführungszeichen und kommagetrennt:
set items="Eingabeaufforderung","Editor","Rechner","Windows-Explorer","Zeichentabelle"  

:: Menüzeile, die beim Start markiert sein soll
set /a "c=1"  

:: Farbkombination für die Markierung der Menüpunkte
set "col=4e"  

:: Tasten zum Navigieren nach oben und unten
set "up=W"  
set "down=S"  

::~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
:: *** ASSOZIATIVES ARRAY ANLEGEN ***
set /a "n=0"  
for %%i in (%items%) do (
  set /a "n+=1"  
  setlocal EnableDelayedExpansion
  for %%j in (!n!) do (
    endlocal
    set "menitem_%%j= %%~i "  
  )
)

:: *** VARIABLE UND DATEI FÜR FARBIGE AUSGABE ANLEGEN ***
call :initColorPrint

:: *** HAUPTSCHLEIFE FÜR DAS ANZEIGEN DES MENÜS ***
:loop
cls
echo(&echo    *** %headline% ***&echo(
echo   nach oben: [%up%]   nach unten: [%down%]   bestaetigen: [Enter]
echo(&echo(
setlocal EnableDelayedExpansion
for /l %%i in (1 1 %n%) do (
  if %c%==%%i (call :colorPrintVar %col% menitem_%%i&echo() else echo !menitem_%%i!
)
endlocal
call :getchoice "%up%%down%"  
set "ret=%errorlevel%"  
if %ret%==2 (
  if %c%==%n% (set /a "c=1") else set /a "c+=1"  
  goto loop
) else if %ret%==1 (
  if %c%==1 (set /a "c=n") else set /a "c-=1"  
  goto loop
)

:: *** TEMPORÄRE DATEI LÖSCHEN ***
call :cleanupColorPrint
echo(

:: *** SUBROUTINE MIT DEM INDEX DES AUSGEWÄHLTEN MENÜPUNKTS AUFRUFEN ***
call :choice_%c%

:: *** PROGRAMM ENDE ***
exit /b

:: *** INTERNE SUBROUTINEN ***
:: Routine für ein CHOICE-ähnliches Verhalten
:getchoice ByVal_Choices
setlocal DisableDelayedExpansion
set "n=0" &set "c=" &set "e=" &set "map=%~1"  
for /f "eol=1 delims=" %%i in ('xcopy /lwq "%~f0" :\') do set "c=%%i"  
set "c=%c:~-1%"  
if defined c (
  for /f delims^=^ eol^= %%i in ('cmd /von /u /c "echo(!map!"^|find /v ""^|findstr .') do (  
    set /a "n += 1" &set "e=%%i"  
    setlocal EnableDelayedExpansion
    if /i "!e!"=="!c!" (  
      for /f %%j in ("!n!") do endlocal &endlocal &exit /b %%j  
    )
    endlocal
  )
) else endlocal &exit /b 0
endlocal &goto getchoice

:: Routinen für farbige Ausgabe von Text
:initColorPrint
for /F "tokens=1,2 delims=#" %%a in ('"prompt $H# &for %%b in (1) do rem"') do set "DEL=%%a"  
<nul >"%temp%\x" set /p "=%DEL%%DEL%%DEL%%DEL%%DEL%%DEL%.%DEL%"  
exit /b

:colorPrintVar ByVal_Color ByRef_StrVar
if not defined %~2 exit /b
setlocal enableDelayedExpansion
set "str=a%DEL%!%~2:\=a%DEL%\..\%DEL%%DEL%%DEL%!"  
set "str=!str:/=a%DEL%/..\%DEL%%DEL%%DEL%!"  
set "str=!str:"=\"!"  
pushd "%temp%"  
findstr /p /A:%1 "." "!str!\..\x" nul  
popd
exit /b

:cleanupColorPrint
del "%temp%\x"  
exit /b
::~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

:: *** BENUTZERDEFINIERTE SUBROUTINEN choice_1 BIS choice_n (MIT n = ANZAHL MENÜPUNKTE) ***
:choice_1
start "" "%comspec%"  
exit /b

:choice_2
start "" "%SystemRoot%\system32\notepad.exe"  
exit /b

:choice_3
start "" "%SystemRoot%\system32\calc.exe"  
exit /b

:choice_4
start "" /max "%SystemRoot%\explorer.exe" /n,/e,::{20D04FE0-3AEA-1069-A2D8-08002B30309D}  
exit /b

:choice_5
start "" "%SystemRoot%\system32\charmap.exe"  
exit /b