Probleme beim Ordner und Dateien mit Umlauten umbenennen mit Skript

'RenameSpecialR.vbs  
Const sProtokoll = "o:\skript"  
Const sSonder = "o:\skript\SonderzeichenErsetzung.txt"  

If WScript.Arguments.Count = 0 Then
    WScript.Echo "Ordner mit umzubenennenden Dateien als Parameter uebergeben!"  
    WScript.Quit(1)
End If
Set fso = CreateObject("Scripting.FileSystemObject")  
sFolder = WScript.Arguments(0)
If Not fso.FolderExists(sFolder) Then
    WScript.Echo sFolder & " ist keine gueltige Ordnerangabe!"  
    WScript.Quit(1)
End If

If Not fso.FileExists(sSonder) Then
    WScript.Echo "Sonderzeichendaten " & sSonder & " nicht gefunden."  
    WScript.Quit(1)
End If
Set oSonder = fso.OpenTextFile(sSonder, 1,False, True)
If Not oSonder.AtEndOfStream Then 
    aSonder = Split(oSonder.ReadAll, vbCrLF)
Else
    oSonder.Close
    WScript.Echo "Sonderzeichendatei " & sSonder & " enthält keine Daten!"  
    WScript.Quit(1)
End If
oSonder.Close

If Right(LCase(WScript.FullName), 11) = "cscript.exe" Then  
    bConsole = True
Else
    bConsole = False
End If

Set oProtokoll = fso.OpenTextFile(sProtokoll & "\" & Replace(Replace(sFolder, ":", ""), "\", "_") & "-Doppelt.txt", 2, True)  
ProcessFolder(fso.GetFolder(sFolder))
oProtokoll.Close

Sub ProcessFolder(oFolder)
sNameOld = oFolder.Name
If bConsole Then WScript.Echo "Bearbeite: " & oFolder.Path  

sNameNew = ReplaceSpecialChars(sNameOld)
If Not fso.FolderExists(oFolder.ParentFolder & "\" & sNameNew) Then  
    oFolder.Name = sNameNew
Else
    If sNameOld <> sNameNew Then oProtokoll.WriteLine oFolder.Path
End If

For Each oFile In oFolder.Files
    sNameOld = fso.GetBaseName(ofile.Name )
    sType = fso.GetExtensionName(ofile.Name)
    If bConsole Then WScript.Echo "Bearbeite: " & oFile.Path  
	
    sNameNew = ReplaceSpecialChars(sNameOld)
    If Not fso.FileExists(oFile.ParentFolder & "\" & sNameNew & "." & sType) Then  
        oFile.Name = sNameNew & "." & sType 'umbenennen auf NameNeu + . + Endung  
    Else
        If sNameOld <> sNameNew Then oProtokoll.WriteLine oFile.Path
    End If
Next

For Each oSubFolder In oFolder.SubFolders
    ProcessFolder(oSubFolder)
Next
End Sub

Function ReplaceSpecialChars(sOld)
sTemp = sOld
For Each sLine In aSonder
    aChars = Split(sLine, ",")  
    For i = 1 To UBound(aChars)
        sTemp = Replace(sTemp, aChars(i), aChars(0))
    Next
Next
ReplaceSpecialChars = sTemp
End Function