Sicherungs cmd mit Archivbitabfrage

set "Variable=Z:\dasi\PC1\test.doc"  
::
::
::
for /f "delims=" %%s in ("%Variable%") do echo %%~ds  
for /f "delims=" %%s in ("%Variable%") do echo %%~dps  
for /f "delims=" %%s in ("%Variable%") do echo %%~ns  
for /f "delims=" %%s in ("%Variable%") do echo %%~xs  
for /f "delims=" %%s in ("%Variable%") do echo %%~nxs  

Z:
Z:\dasi\PC1\
test
.doc
test.doc

for /f "delims=" %%f in ('dir /s /b /a:a "Pfad\Dateimaske" 2^>NUL') do ...

set te=%%f
echo %te%

set te=%%f 
echo %te%

echo %%f

@echo off & setlocal
set "Basis=Z:\dasi\"  
set "Datei=Z:\dasi\PC1\test.doc"  
call set "PfadRelativ=%%Datei:*%Basis%=%%"  
echo %PfadRelativ%

@echo off

setlocal


::Script zur Synchronisierung mehrerer Quellverzeichnisse mit einem Ziel-
::verzeichnis.

::Vor der Synchronisierung wird geprüft, ob die Datenträgerbezeichnung korrekt ist.
::So wird bei USB-Datenträgern als Ziellaufwerk sichergestellt, daß kein anderes
::USB-Laufwerk den gewählten Laufwerksbuchstaben zugewiesen bekommen hat.

::Dateien, die beim Synchronisieren gelöscht oder überschrieben werden, werden
::vorher in ein Sicherungsverzeichnis verschoben. So kann man immer wieder zu
::einem alten Backupstand zurückkehren.

::Bei allen Aktionen wird ein Eintrag in eine LogDatei erstellt, die nach Abschluß
::auf Fehlermeldungen untersucht wird. Falls Fehler aufgetreten sind, wird eine
::Meldung ausgegeben.

::Bei fehlerfreiem Ablauf gibt das Script in ERRORLEVEL 0 zurück, bei Fehlern
::ist ERRORLEVEL 1 und bei Benutzerabbruch 2.


::Quellverzeichnisse
::Wenn die Pfade Leerzeichen enthalten,
::MÜSSEN sie in Anführungszeichen eingeschlossen werden!!
set Source="D:\Archiv" "D:\ct" "D:\Script" "D:\Neu-Installation"  
set Source=%Source% "D:\Office-Dokumente" "D:\Sicherungen"  

::Ziellaufwerk und seine Datenträgerbezeichnung
::Beides OHNE Anführungszeichen!!
set DestDrv=P:
set DestDrvName=EXTERN

::Zielverzeichnis,
::OHNE Anführungszeichen!!
set Dest=%DestDrv%\D - DATEN

::Zielverzeichnis für alte Versionen
set oldVersions=%Dest%\Alte Versionen

::Zeitstempel
set Now=%DATE:~6,4%-%DATE:~3,2%-%DATE:~0,2%_%TIME:~0,2%-%TIME:~3,2%-%TIME:~6,2%

::Pfad und Name der Log-Datei
set Logfile=%Dest%\Backup-Logs\%Now%.log

::Text der Dialogbox, die angezeigt wird,
::wenn das richtige Ziellaufwerk nicht vorhanden ist.
::MIT Anführungszeichen!!
set WrongHDMsg="Falsche Festplatte angeschlossen!"  

::Text der Dialogbox, die angezeigt wird, wenn während
::der Synchronisierung ein Fehler aufgetreten ist.
::MIT Anführungszeichen!!
set ErrMsg="Während der Synchronisierung ist ein Fehler aufgetreten!|Die Log-Datei enthält weitere Informationen."  



::Prüfen, ob das richtige Ziellaufwerk angeschlossen ist
for /f "tokens=6" %%I in ('vol %DestDrv%') do (  
  set Volume=%%I
)

if "%Volume%" equ "%DestDrvName%" goto :DoBackup  

cscript /nologo "%~dp0MsgBox.vbs" %WrongHDMsg% OK "%~n0" Critical  
exit /B 1



:DoBackup
::Synchronisierung ausführen

::Header schreiben
> "%Logfile%" echo Daten-Backup %Now%  
>>"%Logfile%" echo ================================  
>>"%Logfile%" echo.  
>>"%Logfile%" echo.  


::Die Dateien ermitteln, die bei einer Synchronisierung gelöscht
::oder überschrieben werden. Im Unterprogramm werden diese Dateien
::in einen Sicherungsordner verschoben und entsprechende Einträge
::ins Log-File geschrieben.
for %%S in (%Source%) do (
  for /f "tokens=1,2*" %%F in ('call "%~dp0RoboCopy" "%%~S" "%Dest%\%%~nS" *.* /XD .svn /ZB /MIR /COPY:DAT /DCOPY:T /IT /FP /NDL /NP /L /NJH /NJS /NS ^| findstr /r /c:"\<\*EXTRA File\>" /c:"\<Newer\>" /c:"\<Older\>" /c:"\<Changed\>" /c:"\<Tweaked\>"') do (  
    if "%%F %%G" equ "*EXTRA File" (  
      set "oldFile=%%H"  
      call :SaveOldFile "NUR IM ZIEL"  
    ) else if "%%F" equ "Newer" (  
      set "oldFile=%%G %%H"  
      call :SaveOldFile "NEUER"  
    ) else if "%%F" equ "Older" (  
      set "oldFile=%%G %%H"  
      call :SaveOldFile "AELTER"  
    ) else if "%%F" equ "Changed" (  
      set "oldFile=%%G %%H"  
      call :SaveOldFile "VERAENDERT"  
    ) else if "%%F" equ "Tweaked" (  
      set "oldFile=%%G %%H"  
      call :SaveOldFile "ATTRIBUTE GEAENDERT"  
    )
  )
)


::Die Synchronisierung ausführen. Es wird ein exaktes Abbild der Quelldateien
::und -verzeichnisse erstellt (inkl. Zeitstempel und Dateiattribute).
for %%S in (%Source%) do (
  >>"%Logfile%" "%~d0%~p0RoboCopy" "%%~S" "%Dest%\%%~nS" *.* /XD .svn /ZB /MIR /COPY:DAT /DCOPY:T /IT /FP /NDL /NP 2>>&1  
  >>"%Logfile%" echo.  
  >>"%Logfile%" echo.  
  >>"%Logfile%" echo.  
)



::In der Log-Datei nach Fehlermeldungen suchen
::Falls Fehlermeldungen vorhanden sind, Meldung ausgeben,
findstr "\<ERROR\>" "%Logfile%" > NUL  

if %ERRORLEVEL% equ 0 (
   cscript /nologo "%~dp0MsgBox.vbs" %ErrMsg% OK "%~n0" Critical  
   exit /b 1
)


::Fehlerfreier Ablauf -> Rückgabewert 0
exit /b 0



:SaveOldFile
setlocal
  ::Leerzeichen am Ende des Dateinamens abschneiden.
  ::Kann durch die FOR-Schleife im Hauptprogramm entstehen
  if "%oldFile:~-1%" equ " " set "oldFile=%oldFile:~0,-1%"  

  ::Wenn der Dateipfad auf das Ziellaufwerk verweist,
  ::wurde die Datei in der Quelle gelöscht
  if /i "%oldFile:~0,2%" equ "%DestDrv%" goto :SaveDeletedFile  

  ::Für in der Quelle geänderte Dateien den
  ::Dateipfad auf ein einheitliches Format bringen
  :SaveUpdatedFile
  set "oldFile=%Dest%%oldFile:~2%"  

  ::Pfad zum Backupverzeichnis entfernen und durch den
  ::Pfad zum Verzeichnis für alte Versionen ersetzen
  :SaveDeletedFile
  call set "newPath=%%oldFile:*%Dest%=%%"  
  set "newPath=%oldVersions%\%Now%%newPath%"  

  ::Eintrag in die Logdatei schreiben
  (echo %~1
   set /p "=%oldFile%" <NUL & echo.  
   echo verschoben nach
   set /p "=%newPath%" <NUL & echo.) >>"%Logfile%"  

  ::Im Verzeichnis für alte Versionen die Verzeichnisstruktur anlegen,
  ::unter der die Datei im Quell- und im Backupverzeichnis abgelegt ist
  ::und die Datei verschieben
  for /f "delims=" %%P in ("%newPath%") do (mkdir "%%~dpP" 2>NUL)  
  move "%oldFile%" "%newPath%" 2>>"%Logfile%"  

  ::Zwei Leerzeilen in die Logdatei schreiben
  (echo.&echo.)>>"%Logfile%"  
endlocal
exit /b

Dim listArgs, strMessage, strButtons, strTitle, strIcon, strDefaultButton
Dim intButtons, intResult

Set listArgs=WScript.Arguments

If listArgs.Count >= 1 Then
   strMessage = listArgs(0)

   If listArgs.Count >= 2 Then strButtons       = UCase(listArgs(1))
   If listArgs.Count >= 3 Then strTitle         = listArgs(2)
   If listArgs.Count >= 4 Then strIcon          = UCase(listArgs(3))
   If listArgs.Count >= 5 Then strDefaultButton = listArgs(4)
   
   intButtons = 0
   
   If strButtons       = "OKCANCEL"         Then intButtons = intButtons + vbOKCancel  
   If strButtons       = "ABORTRETRYIGNORE" Then intButtons = intButtons + vbAbortRetryIgnore  
   If strButtons       = "YESNOCANCEL"      Then intButtons = intButtons + vbYesNoCancel  
   If strButtons       = "YESNO"            Then intButtons = intButtons + vbYesNo  
   If strButtons       = "RETRYCANCEL"      Then intButtons = intButtons + vbRetryCancel  

   If strIcon          = "CRITICAL"         Then intButtons = intButtons + vbCritical  
   If strIcon          = "QUESTION"         Then intButtons = intButtons + vbQuestion  
   If strIcon          = "EXCLAMATION"      Then intButtons = intButtons + vbExclamation  
   If strIcon          = "INFORMATION"      Then intButtons = intButtons + vbInformation  
   
   If strDefaultButton = "2"                Then intButtons = intButtons + vbDefaultButton2  
   If strDefaultButton = "3"                Then intButtons = intButtons + vbDefaultButton3  

   strMessage = Replace(strMessage, "|", vbCrLf)  
   intResult  = Msgbox(strMessage, intButtons, strTitle)

   WScript.Quit intResult
Else
   WScript.Quit 0
End If

    set "Datei=%%i"  
    setlocal enabledelayedexpansion    
    set "PfadRelativ=!Datei:*%Basis%=!"  
    echo Machwas mit "!PfadRelativ!"  
    endlocal

set "Pfad=%%~dpi"