stoner
Goto Top

Textdatei mit leeren Feldern umwandeln

Hallo zusammen,

ich möchte eine Textdatei (Gebührendatensätze aus einer TK Anlage) per batch umwandeln damit ich sie in eine Firebird Datenbank einlesen kann. Mit Hilfe dieses Forums habe ich schon einiges gelöst, leider komme ich nun nicht mehr weiter:

Die ursprüngliche Datei hat als Trennzeichen Semikolon, mein Problem ist nun, daß einige Felder (je nach Art der Verbindung) manchmal gefüllt sind und manchmal nicht:

10.08.06;08:40:09;1;11;;00:01:14;0943211234;;2;;;0;1;
10.08.06;08:45:36;1;11;00:06;00:02:48;;;1;;;;;
usw.

mit:

FOR /F "tokens=1-13 delims=;" %%a IN (%1) DO echo '%%a','%%b',%%c,%%d,%%e,%%f,%%g,%%h,%%i,%%j,%%k,%%l,%%m >> temp.txt

werden nun die leeren Felder übersprungen, und je nach Verbindungsart verschiebt sich das Ganze.
Weis hier jemand eine Lösungsmöglichkeit?

Besten Dank schon mal,


Frank

Content-Key: 37984

Url: https://administrator.de/contentid/37984

Ausgedruckt am: 29.03.2024 um 15:03 Uhr

Mitglied: miniversum
miniversum 14.08.2006 um 21:13:28 Uhr
Goto Top
Ich verstehs nicht ganz tut mir leid. Was soll den als Ergebnis rauskommen bzw. in der Datei stehen?
miniversum
Mitglied: stoner
stoner 14.08.2006 um 21:20:45 Uhr
Goto Top
Hi miniversum,

voerst sollen die Daten nur in das richtige Format, Trennzeichen Komma und einige Felder mit Hochkomma eingegrenzt.
Am Ende sollen dann die Daten per Batch komplett in die Datenbank eingelesen werden.

Frank
Mitglied: miniversum
miniversum 14.08.2006 um 21:34:42 Uhr
Goto Top
Na das Funktioniert doch?
Also bei mir kommt nach deiner Forschleife folgendes raus:

'10.08.06','08:40:09',1,11,00:01:14,0943211234,2,0,1,,,,
'10.08.06','08:45:36',1,11,00:06,00:02:48,1,,,,,,

Soll das Ergebnis den anders aussehen?
Wenn ja mach mal ein Beispiel.

miniversum
Mitglied: stoner
stoner 14.08.2006 um 21:51:14 Uhr
Goto Top
genau hier ist das Problem, es gehen alle leeren Felder verloren, und somit kann ich keine Zuordnung zu den felder der Firebird db mehr machen.
Ich bräuchte in jeder Zeile immer alle Felder (kommagetrennt) damit ich eine feste Zuordnung machen kann.

'10.08.06','08:40:09',1,11,,'00:01:14',0943211234,,2,,,0,1,
'10.08.06','08:45:36',1,11,'00:06','00:02:48',,,1,,,,,

Edit: anscheinend wird das Format ein bischen durcheinandergewürfelt

Frank
Mitglied: Biber
Biber 14.08.2006 um 23:15:00 Uhr
Goto Top
Moin stoner,

auch dafür gibt es eine Strategie...

wenn Deine Zeile so aussieht:
10.08.06;08:45:36;1;11;00:06;00:02:48;;;1;;;;;

und Du diese Zeile in eine Variable packst:
set zeile=10.08.06;08:45:36;1;11;00:06;00:02:48;;;1;;;;;
...dann ersetze alle aufeinanderfolgenden Trennzeichen (z.B.";") durch Trennzeichen-Dummy-Trennzeichen.
Wobei "Dummy" ein Zeichen ist, dass NIE (oder eigentlich nie *gg) in einer Zeile vorkommt, z.B. ein "@".

Auf bätschisch also
..
set zeile=10.08.06;08:45:36;1;11;00:06;00:02:48;;;1;;;;;
set zeile=%zeile:;;=;@;%
REM %zeile% ist jetzt "10.08.06;08:45:36;1;11;00:06;00:02:48;@;;1;@;;@;;" , da nicht alle ";;" ersetzt wurden.  
REM Warum, das leuchtet beim kurzen Nachdenken aber ein...
REM ...also machen wir das dreimal:
set zeile=%zeile:;;=;@;%
set zeile=%zeile:;;=;@;%
...

Und jetzt das Ganze in Deinem Batch:
.. -------- ungetesteSkizze.bat
REM ..hier bedeutet Parameter 1 (%1) noch: NameDerInputdatei.xyz
...
FOR /F "delims=" %%a IN (%1) DO call :NormalizeIt %%a  
goto :eof

:normalizeIt [parameter 1 ist die ´komplette Zeile]
set zeile=%1 
set zeile=%zeile:;;=;@;%
REM ...machen wir das dreimal:
set zeile=%zeile:;;=;@;%
set zeile=%zeile:;;=;@;%
FOR /F "tokens=1-13 delims=;" %%a IN (%1) DO echo '%%a','%%b',%%c,%%d,%%e,%%f,%%g,%%h,%%i,%%j,%%k,%%l,%%m >> temp.txt  
goto :eof

Hope That Helps
Biber
Mitglied: stoner
stoner 15.08.2006 um 02:27:14 Uhr
Goto Top
Hallo Biber,

erstmal besten Dank für die Antwort, aber irgentwie komm ich nicht ganz klar damit:

@echo off
FOR /F "delims=" %%a IN (%1) DO goto normalize %%a
goto :eof

:normalize
set zeile=%1
set zeile=%zeile:;;=;0;%
set zeile=%zeile:;;=;0;%
set zeile=%zeile:;;=;0;%
FOR /F "tokens=1-13 delims=;" %%a IN (%1) DO echo '%%a','%%b','%%c','%%d','%%e','%%f','%%g','%%h','%%i','%%j','%%k','%%l','%%m' >> gezout.txt
goto :eof

ergibt das gleiche wie ohne normalize. Ich habe das ganze von hinten bis vorne durchgespielt, aber irgentwo ha ich nen hänger, es ergibt alles immer das gleiche:

'13.08.06','18:31:00','1','11','00:18','00:00:00','099221123410','2','0','1','','',''
'14.08.06','09:28:52','1','11','00:07','00:00:00','099211239410#','2','0','1','','',''
'14.08.06','10:19:15','1','11','00:07','00:03:02','1','','','','','',''

Es sollten alle Felder in Hochkomma stehen, und leere Felder sollten mit '0' gefüllt werden.
Besten Dank schon mal für eure Hilfe,

n8 Frank
Mitglied: Biber
Biber 15.08.2006 um 19:48:21 Uhr
Goto Top
Moin stoner,

dann versuchs hiermit:
[Inputdate heißt bei mir Stoner.In; Outputdatei stoner.Out]
::---------stoner.bat parameter1=Inputdatei
@echo off & setlocal
del stoner.out >nul
%JustADebugLine% echo Input %: & type %1
FOR /F "delims=" %%a IN (%1) DO call :normalize %%a  
%JustADebugLine% echo Output : & type stoner.Out 
goto :eof
:normalize
set "zeile=%*"  
set zeile=%zeile:;;=;0;%
set zeile=%zeile:;;=;0;%
set zeile=%zeile:;;=;0;%
FOR /F "tokens=1-13 delims=;" %%a IN ("%zeile%") DO (   
 echo '%%a','%%b','%%c','%%d','%%e','%%f','%%g','%%h','%%i','%%j','%%k','%%l','%%m'>>stoner.Out  
 )
goto :eof
Demo am CMD-Prompt:
$cmd$stoner stoner.In
Input stoner.In:
10.08.06;08:40:09;1;11;;00:01:14;0943211234;;2;;;0;1;
10.08.06;08:45:36;1;11;00:06;00:02:48;;;1;;;;;
Output:
'10.08.06','08:40:09','1','11','0','00:01:14','0943211234','0','2','0','0','0','1'  
'10.08.06','08:45:36','1','11','00:06','00:02:48','0','0','1','0','0','0','0'  

Gruß
Biber
Mitglied: stoner
stoner 18.08.2006 um 20:07:22 Uhr
Goto Top
Hi Biber,

sorry, hatte die letzten Tage Stress aber - es klappt!
Besten Dank, 100% das was ich brauche, Thx.


Ciao, Frank
Mitglied: Biber
Biber 18.08.2006 um 20:12:37 Uhr
Goto Top
Moin stoner,

dann setz ich den Beitrag auf "Gelöst" und mache ihn dicht.
Rechtzeitig vor dem Wochenende.

Ciao dito
Frank