chris22
Goto Top

Tool zum Bilder von Cam ziehen für ABSOLUTE Anfänger

So, jetzt ist es passiert, meine Tante, im leicht fortgeschrittenen Alter und mit fast NULL Computerkenntnissen (es sei ihr gegönnt, hilft aber nicht),
hat nun eine Digicam bekommen. Sogar der simple integrierte Windows Dialog zum Ziehen der Fotos scheint bereits zu schwer zu sein.
Bevor ich jetzt irgendwas skripte, worauf es aber wohl hinauslaufen wird, eine Frage an Leidgenossen:

Habt ihr kleine Tools für Digicam Starter die wirklich so einfach zu bedienen sind, dass sie nur 1-3 Sachen machen, die dafür Narrensicher?

Content-Key: 135608

Url: https://administrator.de/contentid/135608

Ausgedruckt am: 28.03.2024 um 23:03 Uhr

Mitglied: TheDarkLord
TheDarkLord 10.02.2010 um 10:44:55 Uhr
Goto Top
Hallo face-smile

Für eine Kundin mit ähnlichen "Kenntnissen" habe ich mal ein Batch Script geschrieben, welches nur ausgeführt wird und dann automatisch alle Bilder auf der Kamera in einen bei der Einrichtung (von einem etwas erfahreneren Nutzer vorher) festgelegten Ordner in Unterordner mit aktuellem Datum kopiert.
Hilft Dir das weiter?
Bei Bedarf kann ich es Dir gerne mal posten! Meld Dich einfach...

Gruß Dark
Mitglied: Chris22
Chris22 10.02.2010 um 10:48:21 Uhr
Goto Top
Ja, poste mal, Ich würde es auf jedem Fall gerne mal testen. Vielen Dank.
Mitglied: TheDarkLord
TheDarkLord 10.02.2010 um 11:07:55 Uhr
Goto Top
Hallo face-smile

Folgendes einfach in eine Batch speichern, diese in einen Ordner packen, z.B. "C:\Programme\Autocopy\Autocopy.bat", verknüpfung dazu auf den Desktop und fertig ;)
Beim ersten Aufruf startet automatisch die Konfiguration, wo Du das Zielverzeichnis festlegst, wo die Datums-Unterordner erstellt werden sollen, also z.B. "[... ]Eigene Dateien\Fotos", die Art von Daten, welche kopiert werden sollen, also z.B. "*.jpg, *.JPG, *.bmp, *.BMP" etc, welche Laufwerksbuchstaben abgearbeitet werden sollen und welche Laufwerkstypen in Bearbeitung sein sollen. Schau Dir einfach die Hilfe an, Menüpunkt im Programm vorhanden und die erklärt eigentlich den Rest.

Wenn jetzt die Dame den Fotoapperat an den PC stöpselt und dann die Batch mit der Desktop-Verknüpfung ausführt, braucht sie einfach nur noch 1 - Enter drücken und es wird automatisch alles kopiert.
Zur Not kann ich Dir auch einrichten, dass es beim ausführen gleich von alleine losgeht, dann muss man die Konfig eben manuell in der INI ändern, falls man was bearbeiten will. So kann man im Menü auch den Punkt "Konfig ändern" wählen ;)

Gruß Dark

@echo off & setlocal 

:START
for /f "delims== tokens=1,2" %%i in ('findstr "ZIELVERZEICHNIS" config.ini') do @set ZIELVERZEICHNIS=%%j  
cls
for /f "delims== tokens=1,2" %%i in ('findstr "DATEN" config.ini') do @set DATEN=%%j  
cls
for /f "delims== tokens=1,2" %%i in ('findstr "LAUFWERKE" config.ini') do @set LAUFWERKE=%%j  
cls
for /f "delims== tokens=1,2" %%i in ('findstr "TYP" config.ini') do @set TYP=%%j  
cls

IF "%ZIELVERZEICHNIS%"=="" goto SETUP  
IF "%DATEN%"=="" goto SETUP  
IF "%LAUFWERKE%"=="" goto SETUP  
IF "%TYP%"=="" goto SETUP  

:WELCOME
cls
echo\
echo D A R K S O F T  A U T O C O P Y
echo --------------------------------
echo\
echo [1] Kopiervorgang starten
echo [2] Konfiguration aendern
echo [3] Hilfe anzeigen
echo  Programm beenden
echo\
set /P AUSWAHL=Bitte Auswahl treffen [1/2/3/0]:
IF /I "%AUSWAHL%"=="0" goto EXIT  
IF /I "%AUSWAHL%"=="1" goto START2  
IF /I "%AUSWAHL%"=="2" goto SETUP  
IF /I "%AUSWAHL%"=="3" goto HILFE  


:START2
set "ABFRAGE=abfrage"  
set "DATUM=%date:~-4%-%date:~-7,2%-%date:~-10,2%"   
set "GDL=%temp%\GetDriveLetters.vbs"  

IF /I "%TYP:~0,-1%"=="2" goto RUN2   

:RUN1
>%GDL% echo Set fso=CreateObject("Scripting.FileSystemObject"):For Each D In fso.Drives:If D.DriveType=1 Then:If D.IsReady Then:WScript.Echo D.DriveLetter:End If:End If:Next  
goto HAUPTPROGRAMM

:RUN2
>%GDL% echo Set fso=CreateObject("Scripting.FileSystemObject"):For Each D In fso.Drives:If D.DriveType^<=4 Then:If D.IsReady Then:WScript.Echo D.DriveLetter:End If:End If:Next  

:HAUPTPROGRAMM
for /f %%i in ('cscript //nologo %GDL%') do (  
    echo "%LAUFWERKE:~0,-1%"|findstr /i %%i >nul && (  
        dir /a-d "%%i:\%ABFRAGE%">nul 2>&1 || (  
            pushd %%i:\
            for /f "delims=" %%a in ('dir /s /b /a-d %DATEN:~0,-1%') do (  
                echo %%a
                xcopy /dy "%%a" "%ZIELVERZEICHNIS:~0,-1%\%DATUM%\">nul  
            )
        )
        popd
    )
)

dir "%ZIELVERZEICHNIS:~0,-1%\%DATUM%"  
IF errorlevel 1 goto FEHLER
cls

set ANZAHL=0
for %%i in ("%ZIELVERZEICHNIS:~0,-1%\%DATUM%\*") do set /a ANZAHL+=1  
goto ERFOLG

:SETUP
cls
echo\
echo S E T U P
echo\
echo Hinweis:
echo Das Setup startet bei nicht gesetzter Konfiguartion automatisch!
echo\
echo [1] Konfiguration starten
echo [2] Setup abbrechen
echo [3] Hilfe anzeigen
echo  Autocopy beenden
echo\
set /P AUSWAHL=Bitte Auswahl treffen [1/2/0]:
IF /I "%AUSWAHL%"=="1" goto EINGABE  
IF /I "%AUSWAHL%"=="2" goto START  
IF /I "%AUSWAHL%"=="3" goto HILFE  
IF /I "%AUSWAHL%"=="0" goto EXIT  

:EINGABE
cls
echo\
echo [1] Standardeinstellungen verwenden
echo [2] Benutzerdefiniert
echo [3] Hilfe anzeigen
echo  Setup abbrechen
echo\
echo Standardeinstellungen sind:
echo Zielverzeichnis: %USERPROFILE%\Eigene Dateien\Bilder
echo Dateitypen: *.jpg *.bmp *.3gp *.avi *.mpg
echo Laufwerke: EFGHIJK
echo Datentraegertyp 1 (Infos dazu in der Hilfe)
echo\
set /P AUSWAHL=Bitte Auswahl treffen [1/2/0]:
IF /I "%AUSWAHL%"=="1" goto STANDARDEINSTELLUNGEN  
IF /I "%AUSWAHL%"=="2" goto BENUTZERDEFINIERT  
IF /I "%AUSWAHL%"=="3" goto HILFE  
IF /I "%AUSWAHL%"=="0" goto START  

:BENUTZERDEFINIERT
cls
echo\
echo Bitte Zielverzeichnis ohne Anfuehrungszeichen eingeben:
echo (Beispiel: "C:\Bilder" oder "D:\Eigene Dateien\Bilder")  
set /p TEMPZIELVERZEICHNIS=
echo\
dir "%TEMPZIELVERZEICHNIS%"  
IF errorlevel 1 goto FRAGE
goto WEITER

:FRAGE
cls
echo\
echo "%TEMPZIELVERZEICHNIS%" existiert nicht!  
set /P AUSWAHL=Soll das Verzeichnis erstellt werden? [j/n]:
IF /I "%AUSWAHL%"=="j" goto ERSTELLEN  
IF /I "%AUSWAHL%"=="n" goto BENUTZERDEFINIERT  
echo\

:ERSTELLEN
cls
mkdir "%TEMPZIELVERZEICHNIS%"  

:WEITER
cls
echo\
echo Bitte Dateitypen ohne Anfuehrungszeichen eingeben:
echo (Beispiel: "*.jpg" oder "*.bmp *.avi *.mpg *.3gp")  
set /p TEMPDATEN=
echo\
cls
echo\
echo Bitte Laufwerksbuchstaben ohne Anfuehrungszeichen eingeben:
echo (Beispiel: "E" oder "EFGHIJK")  
set /p TEMPLAUFWERKE=
echo\
cls
echo\
echo Datenträgertyp:
echo [1] Nur Wechseldatentraeger wie USB-Sticks und Speicherkarten
echo [2] Alle Datentraeger (Wechseldatentraeger, CD-ROM/s, Festplatte/n)
echo\
set /P AUSWAHL=Bitte Auswahl treffen [1/2]:
IF /I "%AUSWAHL%"=="1" goto TYP1  
IF /I "%AUSWAHL%"=="2" goto TYP2   

:TYP1
set "TEMPTYP=1"  
goto SETCONFIG

:TYP2
set "TEMPTYP=2"  

:SETCONFIG
echo ZIELVERZEICHNIS=%TEMPZIELVERZEICHNIS% > config.ini
echo DATEN=%TEMPDATEN% >> config.ini
echo LAUFWERKE=%TEMPLAUFWERKE% >> config.ini
echo TYP=%TEMPTYP% >> config.ini
goto WELCOME

:STANDARDEINSTELLUNGEN
echo ZIELVERZEICHNIS=%USERPROFILE%\Eigene Dateien\Bilder > config.ini
echo DATEN=*.jpg *.bmp *.3gp *.avi *.mpg >> config.ini
echo LAUFWERKE=EFGHIJK >> config.ini
echo TYP=1 >> config.ini
goto WELCOME

:ERFOLG
cls
echo\
echo E R F O L G R E I C H
echo\
echo %ANZAHL% Datei(en) nach %ZIELVERZEICHNIS:~0,-1%\%DATUM% kopiert!
echo\
echo [1] Autocopy beenden Zielordner öffnen
echo  Autocopy nur beenden
echo\
set /P AUSWAHL=Bitte Auswahl treffen [1/2]:
IF /I "%AUSWAHL%"=="1" goto OPENEXIT  
IF /I "%AUSWAHL%"=="0" goto EXIT   
exit

:FEHLER
cls
echo\
echo F E H L E R
echo\
echo Keine Speicherkarte oder keine Dateien zum kopieren gefunden!
echo\
pause
exit

:HILFE
cls
echo\
echo Beschreibung
echo ------------
echo\
echo Autocopy kopiert automatisch bestimmte Dateitypen von
echo ausgewaehlten Laufwerkstypen in ein im "Setup" festgelegtes  
echo Zielverzeichnis, in dem jedes mal bei einem Kopiervorgang
echo ein Unterordner mit aktuellem Datum als Name angelegt wird.
echo\
pause
cls
echo\
echo Installation/Einrichtung
echo ------------------------
echo\
echo Es gibt ein internes Setup, um das Programm zu konfigurieren.
echo Dieses erstellt eine Konfigurationsdatei im Programmordner,
echo dieser ist momentan "%cd%".  
echo Dort werden die wichtigen Parameter gespeichert.
echo Das sind: Zielverzeichnis, Dateityp, Laufwerksbuchstaben und
echo Laufwerkstyp, also alle Laufwerke oder nur USB und CardReader.
echo\
echo Wenn das Setup einmal abgeschlossen ist, startet Autocopy
echo im Hauptmenue, wo man den Kopiervorgang starten, die
echo Konfiguration aendern, die Hilfe oeffnen oder das Programm
echo beenden kann.
echo\
pause
cls
echo\
echo Aenderung der Konfiguration
echo --------------------------
echo\
echo Einfach aus dem Hauptmenue den Punkt "Konfiguration aendern"  
echo ausfuehren und den Anweisungen folgen.
echo\
pause
cls
echo\
echo Erklaerung zu den Parametern
echo ---------------------------
echo\
echo Zielverzeichnis
echo In diesem Verzeichnis wird der Unterordner erstellt.
echo\
echo Dateityp
echo Zu kopierende Dateien wie *.jpg, *.bmp, *.avi etc.
echo\
echo Laufwerksbuchstaben
echo Gibt an, welche Laufwerke durchsucht werden sollen.
echo\
echo Laufwerkstyp
echo Typ1: Nur USB-Sticks, Card Reader
echo Typ2: Alle Datentraegerarten (Typ1, Festplatten, CD-ROMs)
echo\
pause
cls
goto START

:OPENEXIT
start "C:\Windows\explorer.exe" "%ZIELVERZEICHNIS:~0,-1%\%DATUM%"  
exit

:EXIT
exit
Mitglied: chainsaw
chainsaw 10.02.2010 um 14:22:06 Uhr
Goto Top
Hi Cris

ich hab mir für diese Zwecke mal folgende Batch zusammengezimmert:

@echo off & setlocal enabledelayedexpansion

set /p newstr=Was wurde fotografiert?:

:start
for /f "tokens=2 delims==#" %%h in ('findstr "Pfade=" rename.ini') do set var1=%%h  
for /f "tokens=3 delims==#" %%j in ('findstr "Pfade=" rename.ini') do set var2=%%j  
for /f "tokens=4 delims==#" %%k in ('findstr "Pfade=" rename.ini') do set var3=%%k  
for /f "tokens=5 delims==#" %%l in ('findstr "Pfade=" rename.ini') do set var4=%%l  

mkdir %var2%:\%var3%\%date%
for /r %var1%:\ %%i in (*.jpg) do call :process "%%i"  
goto :ren

:process
xcopy /y %1 %var2%:\%var3%\%date%

:ren 
cd /d %var2%:\%var3%\%date%
for %%s in (*%var4%*.*) do set x=%%s&ren "%%s" "!x:%var4%=%newstr%!"   

Damit das funktioniert, mußt du noch eine "rename.ini" erzeugen, in der folgendes stehen muß:

Pfade=G#C#Temp\input#IMG

Hier definierst du den Laufwerksbuchstaben der Speicherkarte (G)
Den Laufwerksbuchstaben der Festplatte (C)
Den Verzeichnisnamen (temp\input)
und die Dateierweiterung (img)

Wenn du den Batch startest, wird auf der Karte alles runterkopiert (inclusive aller Unterordner)
und umbenannt. Das ganze legt er dann in dein Zeilverzeichnis ab und legt aber vorher noch
einen Unterordner an mit aktuellem Datum.
Das IMG wird durch deine Eingabe ersetzt, die Bildnummer bleibt stehen.
Also aus IMG_1234.jpg wird dann BlaBla_1234.jpg

Schöne Grüße
Chainsaw
Mitglied: Korrn
Korrn 10.02.2010 um 14:27:03 Uhr
Goto Top
Ich bin mir nicht sicher, ob ich Dir damit helfen kann, aber wenn es um das Ausdrucken geht, dann funktionieren einige Kameras und Drucker von Canon auch ganz ohne Computer.