USB-Stick mit Batch Datei erkennen

@echo off

:: config
REM hier den Buchstaben des CD-R-Laufwerks eintragen
set buchstabe=e

:: skript für diskpart erzeugen
 >skript.txt echo list volume
>>skript.txt echo exit

:: Wechseldatenträger liste erzeugen
>liste.txt diskpart /s skript.txt

:: liste auswerten
for /f "tokens=3" %%d in ('find liste.txt "Wechsel"') do (  
	set buchstabe=%%d
)
REM buchstabe ist jetzt das letzte Wechseldatenträger-Laufwerk
REM oder falls keins gefunden, immernoch das CD-R-Laufwerk

:: laufwerk prüfen
REM hier fehlt noch Code zur Fallunterscheidung
 REM Fehlerfall
  REM echo Es konnte kein Datenträger gefunden werden!
  REM goto aufraumen
 REM Erfolgsfall
  REM goto kopieren

:kopieren
REM hier muss angepasst und/oder ergänzt werden
echo Kopieren auf Laufwerk %buchstabe%:
echo copy *.txt %buchstabe%:\
goto aufraumen

:aufraumen
if exist skript.txt del skript.txt
if exist liste.txt del liste.txt
goto ende

:ende

@echo off &setlocal EnableDelayedExpansion

REM Auswerfbare Datenträger suchen
set "removable="  
for /f "tokens=2 delims==" %%i in ('2^>nul wmic logicaldisk where "DriveType=2" get DeviceID /value') do for /f %%j in ("%%i") do (  
  set "drive=%%j"  
  set "removable=!removable!!drive:~,1! "  
)

REM CD Laufwerke suchen
set "compactdisk="  
for /f "tokens=2 delims==" %%i in ('2^>nul wmic logicaldisk where "DriveType=5" get DeviceID /value') do for /f %%j in ("%%i") do (  
  set "drive=%%j"  
  set "compactdisk=!compactdisk!!drive:~,1! "  
)

REM Auswahl in Abhängigkeit von den gefundenen Laufwerken
set "disk="  
set "n=0"  
if defined removable (
  echo Removable Disk(s^):
  for %%i in (!removable!) do (set /a "n+=1" &echo %%i)  
  set "list=!removable: =!"  
  call :inp
) else if defined compactdisk (
  echo Compact Disk(s^):
  for %%i in (!compactdisk!) do (set /a "n+=1" &echo %%i)  
  set "list=!compactdisk: =!"  
  call :inp
) else (
  echo No Suitable Disk Found.
  pause
  exit /b
)

REM mach irgendwas mit Variable !disk! ...
echo(
echo Disk !disk! chosen.
pause

REM Hauptprogramm beenden
exit /b


REM Subroutine für die Eingabe
:inp
set "map= !list!"  
choice /c "!list!" /n /m "Enter the drive letter: "  
for /l %%i in (!n! -1 1) do if errorlevel %%i if not defined disk set "disk=!map:~%%i,1!:"  
exit /b