mic82
Aug 16, 2020
view8955
view11
0
Goto Top

Windows Insider Programm verlassen ohne Neuinstallation

GermanQuestionWindows 10Microsoft
Hallo zusammen,

gibt es eine Möglichkeit, das Windows Insider Programm zu verlassen, ohne eine Neuinstallation durchführen zu müssen?

Bei, Umstieg auf Windows 10 2004 ist es mir nicht gelungen, auch wenn ich den Schalter "Erhalt von Vorabversionen beenden" aktiviert hatte.

Gruß

Mic82
comment-contentCommentShareShare
Share on Facebook Share on Twitter Share on Reddit Share on Linkedin

Content-Key: 596966

Url: https://administrator.de/contentid/596966

Printed on: April 28, 2024 at 08:04 o'clock

11 Comments
Latest comment
Goto Top
Member: GrueneSosseMitSpeck
GrueneSosseMitSpeck Aug 16, 2020 at 11:37:39 (UTC)
Goto Top
was ist eigentlich dein Problem?

Über das Insiderpgrogramm gab es die 2004-er Version schon im April, und die ist als Zwangsupdate konzipiert, das man nicht mehr loswird.
Member: Birkuli
Birkuli Aug 16, 2020 at 11:45:05 (UTC)
Goto Top
Hier eine Batch von Abbodi1406, die X Variante auswählen dann sind Insider auf off,
ab hier den text in eine Batch speichern und als Admin ausführen.
__________________________________________________________________________________
@echo off

::Borrowed from @abbodi1406's scripts
for /f "tokens=6 delims=. " %%i in ('ver') do set build=%%i

if %build% LSS 17763 (
echo =============================================================
echo This script is compatible only with Windows 10 RS5 and later.
echo =============================================================
echo.
pause
goto :EOF
)

REG QUERY HKU\S-1-5-19\Environment >NUL 2>&1
IF %ERRORLEVEL% EQU 0 goto :START_SCRIPT

echo =====================================================
echo This script needs to be executed as an administrator.
echo =====================================================
echo.
pause
goto :EOF

:START_SCRIPT
set "scriptver=1.1.0"
set "FlightSigningEnabled=0"
bcdedit /enum {current} | findstr /I /R /C:"^flightsigning *Yes$" >NUL 2>&1
IF %ERRORLEVEL% EQU 0 set "FlightSigningEnabled=1"

:CHOICE_MENU
cls
set "choice="
echo OfflineInsiderEnroll v%scriptver%
echo.
echo R - Enroll to Release Preview ring
echo S - Enroll to Insider Slow ring
echo F - Enroll to Insider Fast ring
echo.
echo X - Stop receiving Insider Preview builds
echo Q - Quit without making any changes
echo.
set /p choice="Choice: "
echo.
if /I "[%choice%]"=="[r]" goto :ENROLL_RP
if /I "[%choice%]"=="[s]" goto :ENROLL_SLOW
if /I "[%choice%]"=="[f]" goto :ENROLL_FAST
if /I "[%choice%]"=="[x]" goto :STOP_INSIDER
if /I "[%choice%]"=="[q]" goto :EOF
goto :CHOICE_MENU

:ENROLL_RP
set "SLS=RingPreview"
set "Ring=RP"
set "Content=Current"
set "FancyRing=Release Preview"
goto :ENROLL

:ENROLL_SLOW
set "SLS=RingInsiderSlow"
set "Ring=WIS"
set "Content=Active"
set "FancyRing=Windows Insider Slow"
goto :ENROLL

:ENROLL_FAST
set "SLS=RingInsiderFast"
set "Ring=WIF"
set "Content=Active"
set "FancyRing=Windows Insider Fast"
goto :ENROLL

:RESET_INSIDER_CONFIG
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost" /f >NUL 2>&1
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate\SLS\Programs\WUMUDCat" /f >NUL 2>&1
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate\SLS\Programs\RingPreview" /f >NUL 2>&1
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate\SLS\Programs\RingInsiderSlow" /f >NUL 2>&1
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate\SLS\Programs\RingInsiderFast" /f >NUL 2>&1
goto :EOF

:ENROLL
echo Applying changes...
call :RESET_INSIDER_CONFIG
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate\Orchestrator" /t REG_DWORD /v EnableUUPScan /d 1 /f >NUL 2>&1
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate\SLS\Programs\%SLS%" /t REG_DWORD /v Enabled /d 1 /f >NUL 2>&1
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate\SLS\Programs\WUMUDCat" /t REG_DWORD /v WUMUDCATEnabled /d 1 /f >NUL 2>&1
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\Applicability" /t REG_DWORD /v EnablePreviewBuilds /d 1 /f >NUL 2>&1
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\Applicability" /t REG_DWORD /v IsBuildFlightingEnabled /d 1 /f >NUL 2>&1
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\Applicability" /t REG_DWORD /v TestFlags /d 32 /f >NUL 2>&1
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\Applicability" /t REG_SZ /v ContentType /d "%Content%" /f >NUL 2>&1
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\Applicability" /t REG_SZ /v BranchName /d "external" /f >NUL 2>&1
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\Applicability" /t REG_SZ /v Ring /d "%Ring%" /f >NUL 2>&1
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\UI\Strings" /t REG_SZ /v StickyXaml /d "<StackPanel xmlns="^""http://schemas.microsoft.com/winfx/2006/xaml/presentation"^""><TextBlock Style="^""{StaticResource BodyTextBlockStyle }"^"">This device has been enrolled to the Windows Insider program using OfflineInsiderEnroll v%scriptver%. If you want to change settings of the enrollment or stop receiving Insider Preview builds, please use the script. <Hyperlink NavigateUri="^""https://github.com/whatever127/offlineinsiderenroll/blob/master/readme.md"^"" TextDecorations="^""None"^"">Learn more</Hyperlink></TextBlock><TextBlock Text="^""Applied configuration"^"" Margin="^""0,20,0,10"^"" Style="^""{StaticResource SubtitleTextBlockStyle}"^"" /><TextBlock Style="^""{StaticResource BodyTextBlockStyle }"^"" Margin="^""0,0,0,5"^""><Run FontFamily="^""Segoe MDL2 Assets"^"">&#xECA7;</Run> <Span FontWeight="^""SemiBold"^"">%FancyRing%</Span></TextBlock><TextBlock Text="^""Ring: %Ring%"^"" Style="^""{StaticResource BodyTextBlockStyle }"^"" /><TextBlock Text="^""Content: %Content%"^"" Style="^""{StaticResource BodyTextBlockStyle }"^"" /><TextBlock Text="^""Telemetry settings notice"^"" Margin="^""0,20,0,10"^"" Style="^""{StaticResource SubtitleTextBlockStyle}"^"" /><TextBlock Style="^""{StaticResource BodyTextBlockStyle }"^"">Windows Insider Program requires your diagnostic data collection settings to be set to <Span FontWeight="^""SemiBold"^"">Full</Span>. You can verify or modify your current settings in <Span FontWeight="^""SemiBold"^"">Diagnostics &amp; feedback</Span>.</TextBlock><Button Command="^""{StaticResource ActivateUriCommand}"^"" CommandParameter="^""ms-settings:privacy-feedback"^"" Margin="^""0,10,0,0"^""><TextBlock Margin="^""5,0,5,0"^"">Open Diagnostics &amp; feedback</TextBlock></Button></StackPanel>" /f >NUL 2>&1
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\UI\Visibility" /t REG_DWORD /v UIHiddenElements /d 65535 /f >NUL 2>&1
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\UI\Visibility" /t REG_DWORD /v UIDisabledElements /d 65535 /f >NUL 2>&1
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\UI\Visibility" /t REG_DWORD /v UIServiceDrivenElementVisibility /d 0 /f >NUL 2>&1
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\UI\Visibility" /t REG_DWORD /v UIErrorMessageVisibility /d 192 /f >NUL 2>&1

bcdedit /set {current} flightsigning yes >NUL 2>&1
echo Done.

echo.
IF %FlightSigningEnabled% NEQ 1 goto :ASK_FOR_REBOOT
pause
goto :EOF

:STOP_INSIDER
echo Applying changes...
call :RESET_INSIDER_CONFIG
bcdedit /deletevalue {current} flightsigning >NUL 2>&1
echo Done.

echo.
IF %FlightSigningEnabled% NEQ 0 goto :ASK_FOR_REBOOT
pause
goto :EOF

:ASK_FOR_REBOOT
set "choice="
echo A reboot is required to finish applying changes.
set /p choice="Would you like to reboot your PC? (y/N) "
if /I "[%choice%]"=="[y]" shutdown -r -t 0
goto :EOF
_______________________________________________________________
Batch Ende.
Member: c0d3.r3d
c0d3.r3d Aug 17, 2020 at 09:16:06 (UTC)
Goto Top
Hallo @Birkuli,

Kannst du den Inhalt der Batch bitte noch in einen Code-Tag packen, sodass die Batch "Lesbar" sowie kopierbar mit Zeilenumbrüchen wird?
Member: Birkuli
Birkuli Aug 17, 2020 at 09:18:59 (UTC)
Goto Top
@echo off

::Borrowed from @abbodi1406's scripts 
for /f "tokens=6 delims=. " %%i in ('ver') do set build=%%i  

if %build% LSS 17763 (
    echo =============================================================
    echo This script is compatible only with Windows 10 RS5 and later.
    echo =============================================================
    echo.
    pause
    goto :EOF
)

REG QUERY HKU\S-1-5-19\Environment >NUL 2>&1
IF %ERRORLEVEL% EQU 0 goto :START_SCRIPT

echo =====================================================
echo This script needs to be executed as an administrator.
echo =====================================================
echo.
pause
goto :EOF

:START_SCRIPT
set "scriptver=1.1.0"  
set "FlightSigningEnabled=0"  
bcdedit /enum {current} | findstr /I /R /C:"^flightsigning *Yes$" >NUL 2>&1  
IF %ERRORLEVEL% EQU 0 set "FlightSigningEnabled=1"  

:CHOICE_MENU
cls
set "choice="  
echo OfflineInsiderEnroll v%scriptver%
echo.
echo R - Enroll to Release Preview ring
echo S - Enroll to Insider Slow ring
echo F - Enroll to Insider Fast ring
echo.
echo X - Stop receiving Insider Preview builds
echo Q - Quit without making any changes
echo.
set /p choice="Choice: "  
echo.
if /I "[%choice%]"=="[r]" goto :ENROLL_RP  
if /I "[%choice%]"=="[s]" goto :ENROLL_SLOW  
if /I "[%choice%]"=="[f]" goto :ENROLL_FAST  
if /I "[%choice%]"=="[x]" goto :STOP_INSIDER  
if /I "[%choice%]"=="[q]" goto :EOF  
goto :CHOICE_MENU

:ENROLL_RP
set "SLS=RingPreview"  
set "Ring=RP"  
set "Content=Current"  
set "FancyRing=Release Preview"  
goto :ENROLL

:ENROLL_SLOW
set "SLS=RingInsiderSlow"  
set "Ring=WIS"  
set "Content=Active"  
set "FancyRing=Windows Insider Slow"  
goto :ENROLL

:ENROLL_FAST
set "SLS=RingInsiderFast"  
set "Ring=WIF"  
set "Content=Active"  
set "FancyRing=Windows Insider Fast"  
goto :ENROLL

:RESET_INSIDER_CONFIG
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost" /f >NUL 2>&1  
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate\SLS\Programs\WUMUDCat" /f >NUL 2>&1  
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate\SLS\Programs\RingPreview" /f >NUL 2>&1  
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate\SLS\Programs\RingInsiderSlow" /f >NUL 2>&1  
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate\SLS\Programs\RingInsiderFast" /f >NUL 2>&1  
goto :EOF

:ENROLL
echo Applying changes...
call :RESET_INSIDER_CONFIG
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate\Orchestrator" /t REG_DWORD /v EnableUUPScan /d 1 /f >NUL 2>&1  
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate\SLS\Programs\%SLS%" /t REG_DWORD /v Enabled /d 1 /f >NUL 2>&1  
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate\SLS\Programs\WUMUDCat" /t REG_DWORD /v WUMUDCATEnabled /d 1 /f >NUL 2>&1  
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\Applicability" /t REG_DWORD /v EnablePreviewBuilds /d 1 /f >NUL 2>&1  
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\Applicability" /t REG_DWORD /v IsBuildFlightingEnabled /d 1 /f >NUL 2>&1  
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\Applicability" /t REG_DWORD /v TestFlags /d 32 /f >NUL 2>&1  
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\Applicability" /t REG_SZ /v ContentType /d "%Content%" /f >NUL 2>&1  
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\Applicability" /t REG_SZ /v BranchName /d "external" /f >NUL 2>&1  
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\Applicability" /t REG_SZ /v Ring /d "%Ring%" /f >NUL 2>&1  
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\UI\Strings" /t REG_SZ /v StickyXaml /d "<StackPanel xmlns="^""http://schemas.microsoft.com/winfx/2006/xaml/presentation"^""><TextBlock Style="^""{StaticResource BodyTextBlockStyle }"^"">This device has been enrolled to the Windows Insider program using OfflineInsiderEnroll v%scriptver%. If you want to change settings of the enrollment or stop receiving Insider Preview builds, please use the script. <Hyperlink NavigateUri="^""https://github.com/whatever127/offlineinsiderenroll/blob/master/readme.md"^"" TextDecorations="^""None"^"">Learn more</Hyperlink></TextBlock><TextBlock Text="^""Applied configuration"^"" Margin="^""0,20,0,10"^"" Style="^""{StaticResource SubtitleTextBlockStyle}"^"" /><TextBlock Style="^""{StaticResource BodyTextBlockStyle }"^"" Margin="^""0,0,0,5"^""><Run FontFamily="^""Segoe MDL2 Assets"^"">&#xECA7;</Run> <Span FontWeight="^""SemiBold"^"">%FancyRing%</Span></TextBlock><TextBlock Text="^""Ring: %Ring%"^"" Style="^""{StaticResource BodyTextBlockStyle }"^"" /><TextBlock Text="^""Content: %Content%"^"" Style="^""{StaticResource BodyTextBlockStyle }"^"" /><TextBlock Text="^""Telemetry settings notice"^"" Margin="^""0,20,0,10"^"" Style="^""{StaticResource SubtitleTextBlockStyle}"^"" /><TextBlock Style="^""{StaticResource BodyTextBlockStyle }"^"">Windows Insider Program requires your diagnostic data collection settings to be set to <Span FontWeight="^""SemiBold"^"">Full</Span>. You can verify or modify your current settings in <Span FontWeight="^""SemiBold"^"">Diagnostics &amp; feedback</Span>.</TextBlock><Button Command="^""{StaticResource ActivateUriCommand}"^"" CommandParameter="^""ms-settings:privacy-feedback"^"" Margin="^""0,10,0,0"^""><TextBlock Margin="^""5,0,5,0"^"">Open Diagnostics &amp; feedback</TextBlock></Button></StackPanel>" /f >NUL 2>&1  
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\UI\Visibility" /t REG_DWORD /v UIHiddenElements /d 65535 /f >NUL 2>&1  
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\UI\Visibility" /t REG_DWORD /v UIDisabledElements /d 65535 /f >NUL 2>&1  
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\UI\Visibility" /t REG_DWORD /v UIServiceDrivenElementVisibility /d 0 /f >NUL 2>&1  
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\UI\Visibility" /t REG_DWORD /v UIErrorMessageVisibility /d 192 /f >NUL 2>&1  

bcdedit /set {current} flightsigning yes >NUL 2>&1
echo Done.

echo.
IF %FlightSigningEnabled% NEQ 1 goto :ASK_FOR_REBOOT
pause
goto :EOF

:STOP_INSIDER
echo Applying changes...
call :RESET_INSIDER_CONFIG
bcdedit /deletevalue {current} flightsigning >NUL 2>&1
echo Done.

echo.
IF %FlightSigningEnabled% NEQ 0 goto :ASK_FOR_REBOOT
pause
goto :EOF

:ASK_FOR_REBOOT
set "choice="  
echo A reboot is required to finish applying changes.
set /p choice="Would you like to reboot your PC? (y/N) "  
if /I "[%choice%]"=="[y]" shutdown -r -t 0  
goto :EOF
heart1
Member: Birkuli
Birkuli Aug 17, 2020 at 09:20:30 (UTC)
Goto Top
sollte jetzt erledigt sein, sorry...
heart1
Member: mic82
mic82 Aug 17, 2020 at 14:49:33 (UTC)
Goto Top
Hallo Birkuli,

ich schaffe es nicht, das Script auszuführen, weder als bat noch als ps1, nicht in der PowerShell und auch nicht in der Eingabeaufforderung.
Vielleicht mache ich aber auch was falsch ......

Gruß

Mic82
Member: Birkuli
Birkuli Aug 17, 2020 updated at 15:19:34 (UTC)
Goto Top
Hallo @mic82,
das Skript von Zeile 1 bis Zeile 123 komplett kopieren, dann "Neu, Neues Textdokument.txt" z.B. auf dem Desktop anlegen, den kopierten Text in die Textdatei kopieren und speichern, die Datei dann umbenennen in "Insider.cmd" und abspeichern.
Die Insider.cmd mit der rechten Maustaste anklicken und als Administrator ausführen anwählen, nun sollte sich das Skript ausführen und eine Auswahl der Optionen möglich sein.
Member: mic82
mic82 Aug 17, 2020 at 16:10:24 (UTC)
Goto Top
Hallo Birkuli,

das Skript konnte ich ausführen, vielen Dank dafür, doch leider läuft immer noch das Insider Preview, welches ich ja loswerden wollte.

Gibt es noch weitere Ideen, wie ich das InsiderPreview Programm verlassen kann ohne Neuinstallation?

2020-08-17 18_07_25-info

Gruß

Mic82
Member: Birkuli
Birkuli Aug 17, 2020 at 16:33:07 (UTC)
Goto Top
Hallo @mic82,
deine Version ist eine 21H2 Iron Insider Version, die gibt es nicht ohne Insider!
Ich dachte es wäre eine 20H1Vibranium (19041.xxx), dort wäre es möglich gewesen, wenn die 10 Tage seit dem Update noch nicht um sind kann man evtl. auf die vorherige Version zurück wenn es eine 19041.XXX war, sonst hilft nur Neu Installieren.
Member: mic82
mic82 Aug 18, 2020 at 07:49:53 (UTC)
Goto Top
Hallo Birkuli,

wann ist denn der richtige Zeitpunkt, das Insider Programm zu verlassen und auf eine "normale" Installation umzusteigen?
Hilft mir das Skript dann auch weiter?

Gruß

Mic82
Member: Birkuli
Birkuli Aug 18, 2020 at 10:21:30 (UTC)
Goto Top
Hallo @mic82,
wann genau der Richtige Zeitpunkt zum Aussteigen aus dem Insider Programm ist, muss jeder selbst entscheiden, immer wenn eine neue Insider ansteht und man im Dev-Kanal der z.B. 19041.450 ist, wird auf diese upgedatet, auf die z.Z. 20190.1000 stand heute, bei release Preview Kanal oder Beta-Kanal wird das Update erst später angeboten.
Heute wurde das Media Creation Tool (MCT) aktualisiert und bringt nun die 19041.450 als Iso, die kannst du zum clean Installieren nehmen und wenn du in den Insider gehst, nicht den Dev-Kanal nehmen da sonst sofort auf die 20190.1000 geupdatet wird, sollte das versehentlich passieren, so hat man 10 Tage Zeit auf die vorherige Version zurück zu gehen (Update & Sicherheit/Wiederherstellung), aber nur wenn das System nicht bereinigt wird.
Wer nur gelegentlich Insider sein möchte und lieber stabile Versionen vorzieht ist mit dem Beta-Kanal gut bedient.
GermanQuestionWindows 10Microsoft
Hotly discussed
admtechDeveloper diary: Release 6.1admtechDaniEnd of availability for classic Teams clientDani