.xlsx-file per VBScript automatisch drucken

Hallo,

Ich bin ein IT-Lehrling im ersten Lehrjahr und muss mich zur Zeit mit VBScript befassen.
Wir haben im Unternehmen jede Woche einen Schichtplan zu drucken, das hab ich soweit auch hinbekommen per Skript:

[code]
MyPath= "\\server\XXX\XXX\XXX\Schichtplaene 2014"

Set fso = CreateObject("Scripting.FileSystemObject")
Set folder = fso.GetFolder(MyPath)

for each file in folder.Files
filedate = file.datelastmodified
if filedate > predate then
Dateiname=file.path
predate=filedate
end if
next

Set appXLS = CreateObject("Excel.Application")
Set wbkXLS = appXLS.Workbooks.Open(Dateiname,,True)

wbkXLS.sheets("Tabelle1").PrintOut
wbkXLS.Close

Dim fso, MeineDatei
Set fso = CreateObject("Scripting.FileSystemObject")
Set MeineDatei = fso.OpenTextFile("\\server\XXX\XXX\XXX\Log\SchichtplanLog.txt", 8)
MeineDatei.WriteLine "Der Schichtplan wurde gedruckt am: " & Date()
MeineDatei.WriteLine
MeineDatei.Close
[/code]

Das Problem ist, dass das Skript jetzt noch 2 Schönheitsfehler hat.
1. Es ist so das sich das Skript immer die neueste Datei im Ordner sucht und diese druckt, das funktioniert aber nur wenn die neueste Datei auch eine .xlsx-Datei ist. Jetzt möchte ich das auch wenn eine andere Datei (bspw. eine .txt-Datei) neuer ist, sich das Skript trotzdem nur die neueste .xlsx-Datei raussucht und diese druckt.
2. Ein weiteres Problem sind die Umlaute, wie schaffe ich es das wenn im Pfad ein "ä" auftaucht das das Skript den Pfad auch verfolgen kann, bis jetzt musste ich das "ä" durch ein "ae" ersetzen, und da dachte ich mir das das bestimmt auch schöner geht.

MfG
Niklas

If LCase(fso.GetExtensionName(file.Path)) = "xlsx" Then  
....
End if

appXLS.Quit
set appXLS = Nothing

Dim predate, Dateiname, fso, file, folder, MyPath, appXLS, wbkXLS, MeineDatei
MyPath = "\\server\XXX\XXX\XXX\Schichtplaene 2014"  

Set fso = CreateObject("Scripting.FileSystemObject")  
Set folder = fso.GetFolder(MyPath)

for each file in folder.Files
	If LCase(fso.GetExtensionName(file.Path)) = "xlsx" Then   
		filedate = file.datelastmodified
		if filedate > predate then
			Dateiname=file.path
			predate=filedate
		end If
	End If
next

if fso.FileExists(Dateiname) then
  Set appXLS = CreateObject("Excel.Application")  
  appXLS.DisplayAlerts = False
  Set wbkXLS = appXLS.Workbooks.Open(Dateiname,,True,,,,,,,,True)

  wbkXLS.sheets("Tabelle1").PrintOut  
  wbkXLS.Close
  appXLS.DisplayAlerts = True
  appXLS.Quit

  Set MeineDatei = fso.OpenTextFile("\\server\XXX\XXX\XXX\Log\SchichtplanLog.txt", 8)  
  MeineDatei.WriteLine "Der Schichtplan wurde gedruckt am: " & Date()  
  MeineDatei.WriteLine
  MeineDatei.Close
end if

Set wbkXLS = Nothing
Set appXLS = Nothing
Set fso = Nothing
Set MeineDatei = Nothing