öffentliche Ordner per Skript in Outlook hinzufügen

Hi!

ich hab ein Skript aus dem Internet vor einiger Zeit getestet und es funktioniert. allerdings bin ich mir nicht ganz sicher ob ein Teil davon nicht sinnlos ist.

hier meine gekürzte Version:

Const olPublicFoldersAllPublicFolders = 18
Dim olkApp, olkSes, olkFolder, foldersArr

Set olkApp = CreateObject("Outlook.Application")  
Set olkSes = olkApp.GetNameSpace("MAPI")  

Set foldersArr = CreateObject("System.Collections.ArrayList")  

'Change the profile name on the next line'  
olkSes.Logon olkApp.DefaultProfileName
On Error Resume Next

' public folders  
foldersArr.Add "Gemeinsame Kontakte"  

For Each folderStr In foldersArr
	'Add Public Folder to Favorites  

	'Public Folders  
	Set olkFolder = olkSes.GetDefaultFolder(olPublicFoldersAllPublicFolders)
	'SubFolders  
	arrFolders = Split(folderStr, "\")  
    For Each varFolder In arrFolders
		Set olkFolder = olkFolder.Folders(varFolder)
	Next
	
	olkFolder.AddToPFFavorites

Next

olkSes.Logoff
Set olkApp = Nothing
Set olkSes = Nothing
Set olkFolder = Nothing
WScript.Quit

das Skript funktioniert und die Ordner werden als Favoriten angezeigt. Einziger Nachteil, es dauert auf älteren Geräten etwas länger wenn es bei jedem Neustart ausgeführt wird, das liegt aber am OL start. (werde es in Zukunft nur einmal pro Monat laufen lassen).

hier ist das Originalskript (nicht ganz, aber die echte Quelle finde ich nicht mehr)
http://social.technet.microsoft.com/Forums/en-US/c1cc6690-049c-45d1-a16 ...

in diesem Skript gibt es noch die Funktion AddFavoriteFolder
die hat bei Outlook 2013 aber offensichtlich keine Funktion oder macht die irgendwas im "Hintergrund"? Mir wären bis jetzt noch keine offensichtlichen Probleme aufgefallen.

Sub AddFavoriteFolder(olkFolder)
    ' Purpose: Add a folder to Favorite Folders.'  
    ' Written: 5/2/2009'  
    ' Author:  BlueDevilFan'  
    ' Outlook: 2007'  
    Const olModuleMail = 0
    Const olFavoriteFoldersGroup = 4
        Dim olkPane, olkModule, olkGroup
    Set olkPane = olkApp.ActiveExplorer.NavigationPane
    Set olkModule = olkPane.Modules.GetNavigationModule(olModuleMail)
    Set olkGroup = olkModule.NavigationGroups.GetDefaultNavigationGroup(olFavoriteFoldersGroup)
    olkGroup.NavigationFolders.Add olkFolder
    Set olkPane = Nothing
    Set olkModule = Nothing
    Set olkGroup = Nothing
End Sub

eigentlich macht AddToPFFavorites [Adds a Microsoft Exchange public folder to the public folder's Favorites folder.] ja genau das?!

sg Dirm

Please also mark the comments that contributed to the solution of the article

Content-Key: 231055

Url: https://administrator.de/contentid/231055

Printed on: April 23, 2024 at 14:04 o'clock

2 Comments

Latest comment

Hallo Dirm,
also das sind zwei unterschiedliche paar Schuhe. Das obere Script fügt die Ordner zu den PublicFolderFavorites hinzu, also unter den Favoriten im Public-Folder Knoten wenn man in Outlook in die Ordneransicht wechselt(http://social.microsoft.com/Forums/getfile/28628/), wohingegen das letzte Script einen Ordner der Favoriten-Gruppe hinzufügt, welche in der Mail-Ansicht ganz oben zu sehen ist(http://social.microsoft.com/Forums/getfile/28629/).

Grüße Uwe