84075
84075
Mar 10, 2010
view7092
view0
0
Goto Top

Admin-Batch für Windows 7

GermansolvedQuestionWindows 7Microsoft
Hallo!

habe eine Frage. Für WindowsXP habe ich ein "MachMichAdmin-Skript das super funktioniertface-smile Nun wollte ich das in Windows 7 testen doch habe immer das Problem das er mir beispielsweise den Arbeitsplatz und Systemsteuerung im iexplorer.exe anzeigen will. Er versucht zu starten im Internet Explorer doch endet dann mit der Meldung: Auf das angegebene Gerät bzw. den Pfad oder die Datei kann nicht zugegriffen werden. Sie verfügen nicht über ausreichende Rechte um auf das Element zugreifen zu können.

Ich habe mich als normaler User angemeldet und wollte nun Änderungen am System vornehmen die nur der Admin kann und benutze das Skript. Das Menu im CMD erscheint. Die Verwaltung sowie die DOS-Box kann ich öffnen da diese nicht mit dem IEXPLORER geöffnet werden. Ich denke das leigt an dem Registry Schlüssel in der admin_menu_config.txt oder???

hier mein machmichadmin.bat:
@echo off
rem ======================================================================
::  ADMIN MENU
rem ----------------------------------------------------------------------
::  v1.1  Lesen von sAdminGroup + sNetuserParam aus Config
rem ======================================================================

rem ----------------------------------------------------------------------
::	CONFIG
rem ----------------------------------------------------------------------

	set fConfig="admin_menu_config.txt"  


rem ----------------------------------------------------------------------
::	START
rem ----------------------------------------------------------------------

	cd /d %0\..
	if NOT EXIST %fConfig% goto errorNoConfig

	:: lese Variablen aus Config-Datei
    FOR /F "delims== tokens=1,2 " %%a IN ('findstr "^set\ sAdminUser=" %fConfig%') 	do set sAdminUser=%%b  
    FOR /F "delims== tokens=1,2 " %%a IN ('findstr "^set\ sAdminGroup=" %fConfig%') 	do set sAdminGroup=%%b  
    FOR /F "delims== tokens=1,2 " %%a IN ('findstr "^set\ sNetuserParam=" %fConfig%') 	do set sNetuserParam=%%b  

	net user "%USERNAME%" %sNetuserParam% 2> nul | find /i "*%sAdminGroup%" >nul  
	if %ERRORLEVEL%==0 goto menu


rem ----------------------------------------------------------------------
::	LOGON
rem ----------------------------------------------------------------------

	title LOGON erforderlich
    echo.
    echo --- LOGON ERFORDERLICH:
    echo.
    echo Sie (%USERNAME%) sind nicht in der Gruppe "%sAdminGroup%".  
    echo.

    if NOT "%sAdminUser%"=="" goto testAdmin  

    :enterAdmin
    set sAdminUser=
    set /p sAdminUser=Adminstrator-User (Ende mit leerer Eingabe):
    if "%sAdminUser%"=="" goto end  

    :testAdmin
	net user "%sAdminUser%" %sNetuserParam% 2> nul | find /i "*%sAdminGroup%" >nul  
    if %ERRORLEVEL%==0 goto runas
    echo Der Benutzer "%sAdminUser%" wurde nicht in der Gruppe "%sAdminGroup%" gefunden.  
    echo.
    goto enterAdmin

    :runas
    runas /user:%sAdminUser% %0
    if NOT %ERRORLEVEL%==0 pause
    goto end


rem ----------------------------------------------------------------------
::	MAIN
rem ----------------------------------------------------------------------

    :menu
	rem ------------------------------------------------------------
	::	show the menu
	rem ------------------------------------------------------------
    cls
    color cf && title ***** CAE Support ADMIN-MENU *****
    echo.
    echo ***** CAE Support ADMIN-MENU *****
    echo.
    echo Die folgenden Programme werden als Benutzer "%username%" gestartet:  
    echo.
    FOR /F "delims=: tokens=1,2 " %%a IN ('findstr "^[A-Za-z0-9].*: ^-:" %fConfig%') do echo.  %%a - %%b  
    echo.

	rem ------------------------------------------------------------
	::	wait for user input
	rem ------------------------------------------------------------
    set sMenu=
    set /p sMenu=Deine Auswahl und [Enter]; Ende mit leerer Eingabe:
    if "%sMenu%"=="" goto end  

	rem ------------------------------------------------------------
	::	start the program
	rem ------------------------------------------------------------
    echo.
    echo.
    set sProgram=
    FOR /F "delims=: tokens=1,2* " %%a IN ('findstr /i "^%sMenu%:" %fConfig%') do set sProgram=%%c  
    echo starte %sProgram%...
    echo.
    %COMSPEC% /c %sProgram%
	if NOT %ERRORLEVEL%==0 pause
    goto menu



	:errorNoConfig
	echo --- FEHLER:
	echo Die Konfigurationsdatei %fConfig% wurde nicht gefunden.
	echo Sie wude im folgenden Verzeichnis gesucht:
	cd
	echo.
	echo beliebige Taste zum Beenden.
	pause >nul
	goto end


rem ----------------------------------------------------------------------
::	END
rem ----------------------------------------------------------------------

	:end
	echo -- THE END.


rem ======================================================================
::  ENDE
rem ======================================================================

UND HIER MEINE admin_menu_config.txt:
# ======================================================================
#
# CONFIG FOR ADMIN_MENU
#
# ----------------------------------------------------------------------
# 2005-03-27
# 2006-02-02   2 neue Variablen: sAdminGroup + sNetuserParam
# ======================================================================


# ----------------------------------------------------------------------
# Fuer die Pruefung der Domaenenuser is /DOMAIN als Parameter anzugeben.
# Wenn man es leer laesst, werden lokale Benutzer geprueft.
# ----------------------------------------------------------------------
set sNetuserParam=

# ----------------------------------------------------------------------
# Name der Adminstrator-Gruppe (ohne Hochkomma)
# ----------------------------------------------------------------------
set sAdminGroup=Administratoren

# ----------------------------------------------------------------------
# Vorgabe des Adminstrator-Accounts (muss nicht vorgegeben werden)
# ----------------------------------------------------------------------
set sAdminUser=Administrator

# ----------------------------------------------------------------------
# Syntax
# keyword:Display:command
# ----------------------------------------------------------------------
1:Arbeitsplatz:""%ProgramFiles%\Internet Explorer\IEXPLORE.EXE"" ::{20D04FE0-3AEA-1069-A2D8-08002B30309D}  
# oder als Variante mit normalem Explorer:
# 1:Arbeitsplatz:explorer.exe ::{20D04FE0-3AEA-1069-A2D8-08002B30309D}
S:Systemsteuerung:""%ProgramFiles%\Internet Explorer\IEXPLORE.EXE"" ::{20D04FE0-3AEA-1069-A2D8-08002B30309D}\::{21EC2020-3AEA-1069-A2DD-08002B30309D}  
V:Verwaltung:%windir%\system32\mmc.exe /s %windir%\system32\compmgmt.msc
D:DOS-Eingabeaufforderung:%comspec%
-:- - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
M:Menu konfigurieren:notepad admin_menu_config.txt


# ----------------------------------------------------------------------
# EOF
# ----------------------------------------------------------------------
comment-contentCommentShareShare
Share on Facebook Share on Twitter Share on Reddit Share on Linkedin

Content-Key: 137909

Url: https://administrator.de/contentid/137909

Printed on: April 16, 2024 at 12:04 o'clock

GermansolvedQuestionWindows 7Microsoft