In einer batch-Datei einen Befehl mit timeout aufrufen?

Hallo,

gibts eine Möglichkeit, einen beliebigen Befehl mit einem timeout zu starten? Also, wenn der Befehl z.B. nach 10 Sekunden nicht fertig ist, dann soll er abgebrochen werden.

Ganz einfaches Beispiel:
echo Anfang
dir c:\
echo Ende

Wenn der dir-Befehl, aus welchem Grund auch immer, hängen bleibt, wird die batch nie beendet werden, deshalb würde ich ihn gerne so starten, daß er nach 10 Sekunden aufgibt und die batch weiter abgearbeitet wird.

Gibt´s sowas?

Danke
Martin

Please also mark the comments that contributed to the solution of the article

Content-Key: 231487

Url: https://administrator.de/contentid/231487

Printed on: April 19, 2024 at 14:04 o'clock

4 Comments

Latest comment

Hallo Martin,

man kann so etwas von einem parallel aufgerufenen Prozess aus machen. Wie genau, richtet sich aber danach, was genau dabei überwacht werden soll. Sollte es sich bei dem Befehl um ein eigenständiges Programm handeln, wird über TASKLIST relativ einfach festzustellen sein, ob das Programm nach 10s noch läuft. Für CMD-interne Befehle (wie DIR) wird das etwas komplizierter und man müsste ein Workaround bauen, das sich nicht mit deinen Ansprüchen beißt.

Gib einfach mal ein paar Informationen mehr, bzw. erzähl am besten um was es dir konkret geht.

Grüße
rubberman

Zitat von @rubberman:

Hallo Martin,

man kann so etwas von einem parallel aufgerufenen Prozess aus machen. Wie genau, richtet sich aber danach, was genau dabei
überwacht werden soll. Sollte es sich bei dem Befehl um ein eigenständiges Programm handeln, wird über TASKLIST
relativ einfach festzustellen sein, ob das Programm nach 10s noch läuft. Für CMD-interne Befehle (wie DIR) wird das
etwas komplizierter und man müsste ein Workaround bauen, das sich nicht mit deinen Ansprüchen beißt.

Gib einfach mal ein paar Informationen mehr, bzw. erzähl am besten um was es dir konkret geht.

Es hat mich allgemein interessiert, ob sowas möglich ist. Als konkreten Fall hätte ich aber trotzdem folgendes:
In einer batch werden in einer Schleife mehrere PC´s hintereinander mit psinfo abgefragt. Da kann ich aber nicht über einen parallel aufgerufenen Prozess prüfen, ob nach 10s psinfo noch läuft, weil dann ja vielleicht schon die psinfo-Abfrage für den nächsten oder übernächsten PC durchgeführt wird. Ich müßte also die PID irgendwie mitbekommen. Oder ich kille den Hilfprozess immer zu Beginn der Schleife. Ungefähr so:

call :BeginnSchleife PC1 PC2 PC3
goto :eof
:BeginnSchleife
Hilfsprozess killen
Hilfsprozess starten
psinfo %1
SHIFT
if not (%1) == () goto :BeginnSchleife
Hilfsprozess killen

Geht´s eleganter?
Gruß
Martin

Hallo Martin

OK, etwas allgemeingültig, nämlich für separate Programme mit einem eindeutigen Teil in der Kommandozeile des Programms, könnte wie folgt aussehen:

killtimeout.bat

@echo off &setlocal
set "ProcName=%~1"  
set "CmdLnPart=%~2"  
set "processid="  

>nul timeout /t 10 /nobreak

for /f %%i in (
  '2^>nul wmic process where "name='%ProcName%' and commandline like '%%%CmdLnPart%%%'" get processid /value'  
) do for /f %%j in ("%%i") do set "%%j"  

if defined processid >nul 2>&1 taskkill /f /pid %processid%

worker.bat

@echo off &setlocal

start "" /b "cmd.exe" /c ""%~dp0killtimeout.bat" "notepad.exe" "killtimeout""  
notepad.exe killtimeout.bat

pause

Beide Batchdateien liegen im gleichen Verzeichnis.

"worker.bat" wird per Doppelklick gestartet.

Von dort wird zunächst "killtimeout.bat" asynchron mit 2 Parametern gestartet. Der erste Parameter ist der Prozessname des zu überwachenden Programms (hier notepad.exe, stellvertretend für psinfo.exe bei dir). Der zweite Parameter ist ein eindeutiger Teil der Kommandozeile des Programms (hier ist es das Wort "killtimeout", stellvertretend für den PC Name bei dir).
Danach wird notepad.exe mit dem Parameter killtimeout.bat aufgerufen. Zum Verständnis: Das Wort "killtimeout" ist somit Teil der Kommandozeile des Aufrufs von Notepad. (Bei dir wäre es dann PsInfo.exe, wobei der Computername Teil der Kommandozeile wäre.)

Was passiert in der "killtimeout.bat"?

10 s warten
WMIC prüft, ob ein Prozess mit dem entsprechenden Name und dem angegebenen Teil der Kommandozeile existiert und gibt die Prozess ID aus.
Sollte eine PID ermittelt worden sein, wird der Prozess per TASKKILL beendet.

Ist also nicht besonders kompliziert, oder? Ob es nun elegant ist, liegt im Auge des Betrachters