Batch-Datei erstellen

Hallo liebe Gemeinde!

Ich bin dabei eine Batch-Datei zu schreiben welche folgendes tun soll:

Die Batch soll alle auf dem PC befindenden W-Lan-Netzwerke anzeigen, das funktioniert auch:

[CODE]
FOR /F "tokens=6 skip=3 delims= " %%i IN ('netsh wlan show profiles') DO (


)
[/CODE]


Nun möchte ich aber die Auswahl nicht einfach per "Tippen" des W-Lannamens löschen sondern durch drücken einer Zahl:


[CODE]
@echo off
cls
set z=1
FOR /F "tokens=6 skip=3 delims= " %%i IN ('netsh wlan show profiles') DO (

echo Gefundene Netzwerke:
echo %%z% = %%i
set /a z += 1
etc pp
)


[/CODE]

Nur kann das ja nicht funktionieren da "z" sich ja beim nächsten Schleifendurchgang zu "2" ändert und damit ..naja der Rest ist klar.
Irgendwie hab ich da einen Denkfehler drinne und bitte um Hilfe


Vielen Dank!

Dominic

@echo off & setlocal enabledelayedexpansion
set /a cnt=1
for /f "tokens=2 delims=:" %%a in ('netsh wlan show profiles ^| findstr /i /c:" : "') DO @(  
	set "pname=%%a" &set "pname=!pname:~1!"  
	set "profile!cnt!=!pname!"  
	echo [!cnt!] !pname!
	set /a cnt+=1
)
echo.
set /p num=Bitte das Profil mit der Zahl waehlen:
echo.
set /p delete=Wollen sie das Profil  "!profile%num%!" wirklich entfernen [j/n]?  
if /i "%delete%" NEQ "j" goto :eof  
:: Profil entfernen
netsh wlan delete profile name="!profile%num%!"