Batch Datei schreiben die Filenamen Ausliest und kürzel mit Namen ersetzt

@echo off & setlocal
set "Filterdatei=E:\abrevation.txt"  
set "Ausgabe=E:\Percusions.csv"  
set "TempoS=1-70:slow"  
set "TempoM=71-110:Mid Tempo"  
set "TempoF=111-180:Uptempo"  
:begin
if "%~1" == "" (pushD "%~dp0") else pushD "%~1"  
for %%h in ("%cd%") do (  
	for %%i in (*) do for /f "tokens=* delims=1234567890" %%j in ("%%~ni") do if not "%%~ni" == "%%j" (  
		set "Name=%%j"  
		setlocal enabledelayedexpansion
		for /f "tokens=1* delims=:0" %%k in ("!Name:~0,3!:!Name:~3,3!") do (  
			endlocal
			for /f "usebackq tokens=1,2 delims=:" %%m in ("%Filterdatei%") do if "%%n" == "%%~k" (  
				for %%o in ("%tempoS%" "%tempoM%" "%tempoF%") do for /f "tokens=1,2* delims=-:" %%p in ("%%~o") do if %%p leq %%l if %%q geq %%l (  
					for %%u in ("::%%~nxh:%%r") do (  
						if defined %%~u (
							setlocal enabledelayedexpansion
							for /f "tokens=1* delims==" %%s in ('set "::%%~nxh:%%r"') do (  
								echo "%%~t"|find "%%m" >nul && endlocal || (endlocal&set "::%%~nxh:%%r=%%~t,%%m")  
						)	) else set "::%%~nxh:%%r=%%m"  
)	)	)	)	)	)	
popD
if not "%~2" == "" shift & goto :begin  
(
for /f "tokens=1,2,3 delims=:=" %%k in ('set :: 2^>nul') do (  
	echo %%k;%%m;%%l
	set "::%%k:%%l="  
)
)>"%Ausgabe%"  

Mixes mix
wird zu:
Mixes:mix

Backing bac
wird zu:
Backing:bac

....usw

Electric Bass bse, bsl
wird zu:
Electric Bass:bse
Electric Bass:bsl

....usw

set "Filterdatei=D:\abrevation.txt"

@echo off & setlocal
:: Anzupassende Variablen
:: Hauptordner=Hier kommt der Komplette Pfad des Ordners hin, welcher die vielen Ordner beinhaltet.
:: Filterdatei=Hier kommt der komplette Pfad  der abrevations - Filter - Datei hinein
:: Ausgabe=Hier kommt der komplette Pfad der Ausgabe csv Datei rein
set "HauptOrdner=D:\Cmd befehle\Abrevtest"  
set "Filterdatei=D:\abrevation.txt"  
set "Ausgabe=D:\Percusions.csv"  
set "TempoS=1-70:slow"  
set "TempoM=71-110:Mid Tempo"  
set "TempoF=111-180:Uptempo"  
if "%~1" == "" echo Syntaxfehler! & goto :eof  
if "%~1" == "/?" (echo Syntax:&echo.  
echo %~n0 Ordner1 [Ordner2 ...]
echo                 Die Datei "%Ausgabe%" wird fortgesetzt und  
echo                  einzelne Zeilen erneuert. Wobei die Aeltere Zeile ersetzt wird.
echo.
echo %~n0 "%Hauptordner%"  
echo                Die Datei "%Ausgabe%" wird geloescht und  
echo                 komplett neu geschrieben.
goto :eof
)

if /i not  "%~1" == "%Hauptordner%" (set "Alle="  
set "Raus=findstr /v /b "%%k;.*;%%l" "%Ausgabe%" "  
set "Trennen=|sort"  
goto :begin
)
type nul >"%Ausgabe%"  
set "Alle=\*"  

:begin
set "Hauptordner=%~1"  
setlocal enabledelayedexpansion
for /f "usebackq tokens=1,2 delims=:" %%i in ("%Filterdatei%") do for %%k in (%%j) do echo "!..%%i!"|findstr "%%k" >nul || set "..%%i=!..%%i!%%k "  
(
for /f "tokens=1,2 delims=.=" %%i in ('set ..') do echo %%i: %%j  
)>"%temp%\tmp"  
type "%temp%\tmp">"%Filterdatei%"  
(
for /d %%h in ("%Hauptordner%%Alle%") do (  
	echo Durchsuche %%~nxh
	set "Ordner="  
	for %%i in ("%%~h\*") do for /f "tokens=* delims=1234567890" %%j in ("%%~ni") do if not "%%~ni" == "%%j" (  
		set "Name=%%j"  
		for /f "tokens=* delims=0" %%k in ("!Name:~3,3!:!Name:~0,3!;!Ordner!") do set "Ordner=%%k"  
	)
	for /f "usebackq tokens=1* delims=:" %%i in ("%Filterdatei%") do for %%w in (!Ordner!) do for /f "tokens=1,2 delims=:" %%l in ("%%~w") do echo "%%m"|findstr "%%j" >nul && (  
		for %%o in ("%tempoS%" "%tempoM%" "%tempoF%") do for /f "tokens=1,2* delims=-:" %%p in ("%%~o") do if %%p leq %%l if %%q geq %%l (  
			for %%u in ("::%%~nxh:%%r") do (  
				if defined %%~u (
					for /f "tokens=1* delims==" %%s in ('set "Vergleich:%%r"') do (  
						echo "%%~t"|find "%%m" >nul || (set "Vergleich:%%r=%%~t,%%j"  
							for /f "tokens=1* delims==" %%u in ('set "::%%~nxh:%%r"') do set "::%%~nxh:%%r=%%~v,%%i"  
					)	)
				) else (set "Vergleich:%%r=%%j"&set "::%%~nxh:%%r=%%i")  
	)	)	)
	for /f "tokens=1,2,3 delims=:=" %%k in ('set :: 2^>nul') do (  
		echo %%k;%%m;%%l
		set "::%%k:%%l="  
		set "Vergleich:%%l="  
	)>&3
	
)
) 3>>"%Ausgabe%"  
endlocal
if not "%~2" == "" shift & goto :begin  
if defined alle goto :eof
setlocal enabledelayedexpansion
move "%Ausgabe%" "%temp%\tmp" >nul  
::@echo on
for /f "usebackq tokens=1-3 delims=;" %%i in ("%temp%\tmp") do (  
	for /f "tokens=* delims=:" %%m in ('findstr /b "%%i;.*;%%k" "%temp%\tmp"') do set "Line=%%m"  
	set "Opt="  
	findstr /b "%%i;.*;%%k" "%Ausgabe%" >nul 2>nul || set "Opt=1"  
	if defined Opt echo !Line!>>"%Ausgabe%"  
)

move "%Ausgabe%" "%temp%\tmp" >nul &sort < "%temp%\tmp" > "%Ausgabe%"

	for %%i in ("%%~h\*") do for /f "tokens=* delims=1234567890" %%j in ("%%~ni") do if not "%%~ni" == "%%j" (

for /d %%h in ("%Hauptordner%%Alle%") do (

for /d %%A in ("%Hauptordner%%Alle%") do for /d %%B in ("%%A\*") do for /d %%h in ("%%B\*") do (

	for %%i in ("%%~h\*") do for /f "tokens=* delims=1234567890_" %%j in ("%%~ni") do if not "%%~ni" == "%%j" (

	for /r %%i in ("%%~h\*.wav") do for /f "tokens=* delims=1234567890_" %%j in ("%%~ni") do if not "%%~ni" == "%%j" (

dir /s /b Z:\*.wav>"%temp%\Dir"&echo.&&@for /f "delims=:" %j in ('findstr /n "^" "%temp%\Dir" ^|find /c ":"') do @for /f %k in ('set /a "Lines=%j-5"') do @if %k gtr 0 @(more +%k "%temp%\Dir") else type "%temp%\Dir"  

dir /s /b z:\*.wav>"%temp%\Dir"&echo.&&@for /f "delims=:" %j in ('findstr /n "^" "%temp%\Dir" ^|find /c ":"') do @for /f %k in ('set /a "Lines=%j-5"') do @(if %k gtr 0 @(more +%k "%temp%\Dir">"%userprofile%\Desktop\5-Zeilen.txt") else move /y"%temp%\Dir" "%userprofile%\Desktop\5-Zeilen.txt">nul)&&"%userprofile%\Desktop\5-Zeilen.txt"&&ping -n 1 localhost >nul&del "%userprofile%\Desktop\5-Zeilen.txt"  

for /d %%A in ("%Hauptordner%%Alle%") do for /d %%h in ("%%~A\*") do (  
	echo Durchsuche %%~nxh
	set "Ordner="  
	for /f "delims=" %%i in ('dir /s /b "%%~h\*.wav"') do for /f "tokens=* delims=1234567890_" %%j in ("%%~ni") do if not "%%~ni" == "%%j" (  

C:\Users\Pieh-Ejdsch-AD>tree "T:\Neue Server Struktur - Ordner 3.1.2011"
Auflistung der Ordnerpfade für Volume 10GBFAT32
Volumeseriennummer : 00740053 B819:0B5D
T:\NEUE SERVER STRUKTUR - ORDNER 3.1.2011
├───5069_jiggy_Pop
│   ├───5069-0001_Breaking_Dawn
│   │   └───1
│   ├───5069-0002_Butterflies
│   │   └───1
│   ├───5069-0003_Dry_Up_Your_Tears
│   │   └───3
│   ├───5069-0004_Early_Morning
│   │   └───2
│   └───5069-0005_Feeling_You
│       └───3
└───5076_hardcore_Ballads
    ├───5076-0008_Life_Is_Nothing
    │   └───2
    ├───5076-0010_Not_Ashamed
    │   └───2
    ├───5076-0012_Playas_Get_Lonely_Too
    │   └───3
    └───5076-0014_See_Everything
        └───3
C:\Users\Pieh-Ejdsch-AD>dir /b /s "T:\Neue Server Struktur - Ordner 3.1.2011\*.wav"
T:\Neue Server Struktur - Ordner 3.1.2011\5069_jiggy_Pop\5069-0001_Breaking_Dawn\1\1_025bac089_extra.wav
T:\Neue Server Struktur - Ordner 3.1.2011\5069_jiggy_Pop\5069-0001_Breaking_Dawn\1\1_025bsa089_extra.wav
T:\Neue Server Struktur - Ordner 3.1.2011\5069_jiggy_Pop\5069-0001_Breaking_Dawn\1\1_025bse089_extra.wav
T:\Neue Server Struktur - Ordner 3.1.2011\5069_jiggy_Pop\5069-0001_Breaking_Dawn\1\1_025bsl089_extra.wav
T:\Neue Server Struktur - Ordner 3.1.2011\5069_jiggy_Pop\5069-0001_Breaking_Dawn\1\1_025bss089_extra.wav
T:\Neue Server Struktur - Ordner 3.1.2011\5069_jiggy_Pop\5069-0001_Breaking_Dawn\1\1_025ino089_extra.wav
T:\Neue Server Struktur - Ordner 3.1.2011\5069_jiggy_Pop\5069-0001_Breaking_Dawn\1\1_025itr089_extra.wav
T:\Neue Server Struktur - Ordner 3.1.2011\5069_jiggy_Pop\5069-0001_Breaking_Dawn\1\1_025mix089_extra.wav
T:\Neue Server Struktur - Ordner 3.1.2011\5069_jiggy_Pop\5069-0001_Breaking_Dawn\1\1_025out089_extra.wav
T:\Neue Server Struktur - Ordner 3.1.2011\5069_jiggy_Pop\5069-0001_Breaking_Dawn\1\1_025sub089_extra.wav
T:\Neue Server Struktur - Ordner 3.1.2011\5069_jiggy_Pop\5069-0001_Breaking_Dawn\1\1_025var089_extra.wav
T:\Neue Server Struktur - Ordner 3.1.2011\5069_jiggy_Pop\5069-0002_Butterflies\1\1_025bac089_extra.wav
T:\Neue Server Struktur - Ordner 3.1.2011\5069_jiggy_Pop\5069-0002_Butterflies\1\1_025bsa089_extra.wav

set "HauptOrdner=T:\Neue Server Struktur - Ordner 3.1.2011"

@echo off & setlocal
:: Anzupassende Variablen
:: Hauptordner=Hier kommt der Komplette Pfad des Ordners hin, welcher die vielen Ordner beinhaltet.
:: Filterdatei=Hier kommt der komplette Pfad  der abrevations - Filter - Datei hinein
:: Ausgabe=Hier kommt der komplette Pfad der Ausgabe csv Datei rein
set "HauptOrdner=T:\Neue Server Struktur - Ordner 3.1.2011"  

:: gemmessen vom Ordner des Relevanten Namens bis zur Datei -> gezählt in Backslashes vom Backslash vor dem Ordner bis zur Datei
set "NameOrdnerTiefeZurDatei=3"  
set "Filterdatei=T:\Neuer Ordner\abrevations.txt"  
set "Ausgabe=T:\Percusions.csv"  
set "TempoS=1-70:slow"  
set "TempoM=71-110:Mid Tempo"  
set "TempoF=111-180:Uptempo"  
if "%~1" == "" echo Syntaxfehler! & goto :eof  
if "%~1" == "/?" (echo Syntax:&echo.  
echo %~n0 Ordner1 [Ordner2 ...]
echo                 Die Datei "%Ausgabe%" wird fortgesetzt und  
echo                  einzelne Zeilen erneuert. Wobei die Aeltere Zeile ersetzt wird.
echo.
echo %~n0 "%Hauptordner%"  
echo                Die Datei "%Ausgabe%" wird geloescht und  
echo                 komplett neu geschrieben.
goto :eof
)
setlocal enabledelayedexpansion
for /f "usebackq tokens=1,2 delims=:" %%i in ("%Filterdatei%") do @for %%k in (%%j) do @echo "!..%%i!"|findstr "%%k" >nul || set "..%%i=!..%%i!%%k "  
(
for /f "tokens=1,2 delims=.=" %%i in ('set ..') do @echo %%i: %%j  
)>"%temp%\tmp"  
type "%temp%\tmp">"%Filterdatei%"  
endlocal
if /i not  "%~1" == "%Hauptordner%" (set "Alle="  
goto :begin
)
type nul >"%Ausgabe%"  
set "Alle=1"  
:begin
if not exist "%~1\" goto :sort  
if not "!OS!" == "%OS%" setlocal enabledelayedexpansion  
(
for /f "tokens=* delims=" %%i in ('dir /s /b "%~1\*.wav"^&echo.L+a.s-t\line\xyz') do (  
	set "Name=%%i"  
	set "Token=0"  
	for %%j in ("!Name:\=" "!") do set /a Token+=1  
	set /a Token = Token - NameOrdnerTiefeZurDatei
	for /l %%j in (1,1,!Token!) do set "Name=!Name:*\=!"  
	for /f "tokens=1 delims=\" %%j in ("!Name!") do (  
		if not "!AltOrdner!"=="%%j" (  
			if not "L+a.s-t" == "%%j" echo Dursuche %%j  
			set "NewLine="  
			for /f "delims=0" %%l in ("!AltTempo!") do for %%m in ("%tempoS%" "%tempoM%" "%tempoF%") do for /f "tokens=1,2* delims=-:" %%n in ("%%~m") do if %%n leq %%~l if %%o geq %%~l (  
				for /f "tokens=1* delims=:" %%q in ('findstr "!AltName!" "%Filterdatei%"') do echo "%%r" |findstr "!AltName!">nul 2>nul&&set "NewLine=!NewLine!,%%q"  
				set "NewLine=!NewLine:~1!"  
				set "AltName="  
				>&3 echo !AltOrdner!;!NewLine!;%%p
			)
		)
		set "AltOrdner=%%j"  
		for /f "tokens=* delims=1234567890_" %%k in ("%%~ni") do (  
			set "Name=%%k"  
			set "AltTempo=!Name:~3,3!"  
			echo "!AltName!"|find "!Name:~0,3!" >nul 2>nul ||set "AltName=!AltName! !Name:~0,3!"  
)	)	)
)3>>"%Ausgabe%"  
endlocal
:sort
if not "%~2" == "" shift & goto :begin  
if defined alle goto :eof
setlocal enabledelayedexpansion
move "%Ausgabe%" "%temp%\tmp" >nul  
echo.&echo loesche Alte Eintraege aus "%Ausgabe%"  
for /f "usebackq tokens=1-3 delims=;" %%i in ("%temp%\tmp") do (  
	for /f "tokens=* delims=:" %%m in ('findstr /b "%%i;.*;%%k" "%temp%\tmp"') do set "Line=%%m"  
	set "Opt="  
	findstr /b "%%i;.*;%%k" "%Ausgabe%" >nul 2>nul || set "Opt=1"  
	if defined Opt @echo !Line!>>"%Ausgabe%"  
)