Batch-Dateien unter Start - Zuletzt verwendet anzeigen lassen (batfile .bat)

Batchlink "%~f0" %*

@echo off
setlocal disabledelayedexpansion
if "%~1" equ "" echo Syntaxfehler. >&2 & exit /b 1  
if "%~1" equ "/?" echo Erzeugt Batch Verknuepfungen.^  
 &echo(&<nul set /p "=%~n0 " &echo Datei [Args] [Link] [/Description:"..."] [/WorkingDir:ArbeitsPfad]^  
 &echo(&echo  Datei  	Ziel der Verknuepfung.^
 &echo  Args   	Argumente die dem Ziel uebergeben werden.^
 &echo  Link   	Vollerstaendiger Name der Verknuepfung mit der Endung .LNK^
 &echo 		ohne Linkangabe wird ein Link im definierten Ordner angelegt.^
 &echo 		 wird die Variable: ExtRecentFolder Vordefiniert,^
 &echo 		 werden die Verknuepfungen in diesen Ordner gelegt.^
 &echo  /Description:  Angabe einer Beschreibung der Verknuepfung.^
 &echo  /WorkingDir:   Angabe eines Arbeitspfades des Zieles der Verknuepfung.^
 &exit /b 0
for %%i in ( Create NCreate TargetPath Desc Work PWork Args ExtRecentList ) do set "%%i="  

set "ExtRecentList=15"  
 rem Dieser Ordner zeigt in einer neu angelegten Symbolleiste die neuesten x Verknuepfungen
if defined ExtRecentFolder goto :LinkFolder
set "ExtRecentFolder=D:\Letzte Batches"  

:LinkFolder
if defined ExtRecentList set "ExtRecentList=+%ExtRecentList%"  
:in
set IN=%1
if not defined IN goto :out
setlocal enabledelayedexpansion
set "IN=!IN:"=!"  
if /i "!IN:~,13!" equ "/Description:" for /f delims^= %%i in ("!IN:~13!" ) do endlocal &set "Desc=%%~i" &shift &goto :in  
if /i "!IN:~,12!" equ "/WorkingDir:"  for /f delims^= %%i in ("!IN:~12!" ) do endlocal &set "Work=%%~i" &shift &goto :in  
if /i "%~x1" equ ".lnk" endlocal &set "Create=%~1" &shift &goto :in  
for %%x in (.cmd .bat ) do if exist "%~dpn1%%x" endlocal &set "TargetPath=%~f1" &set "PWork=%~dp1" &set "NCreate=%~nx1" &shift &goto :in  
set Args=!Args!%1 
for /f delims^= %%i in ("!Args!" ) do endlocal &set Args=%%i &shift &goto :in  

:out
setlocal enabledelayedexpansion
if not defined PWork >&2 echo Fehler Keine Quelle angegeben. &exit /b 1

 rem Fuer einen eigens angelegten Ordner zB. in einer "neue Symbolleiste"  
if not defined Create set "Create=%ExtRecentFolder%\!NCreate!.LNK"  
if not defined Create >&2 echo Fehler Keine Verknuepfung angegeben. &exit /b2
if not defined Work set "work=!PWork!"  
 rem Link richtig löschen für Aktualisierung des Dateisystemes mit Verzögerung
md "%ExtRecentFolder%" 2>nul ||if exist "!Create!" echo Aktualisierung ... &&del /s "!Create!" >nul &&ping localhost -n 2 1>nul  
for /f "tokens=3 delims=. " %%i in ('chcp' ) do set "CP=%%i"  
chcp 1252 >nul
(
>&4 echo Set objShell=WScript.CreateObject^("Wscript.Shell"^)  
>&4 echo Set objShortcut=objShell.CreateShortcut^("!Create!"^)  
>&4 echo objShortcut.TargetPath="!TargetPath!"  
>&4 echo objShortcut.Description="!Desc!"  
>&4 echo objShortcut.WorkingDirectory="!Work!"  
>&4 echo objShortcut.Arguments = "!Args!"  
>&4 >nul echo objShortcut.IconLocation=""  
>&4 echo objShortcut.Save
) 4>"%temp%\MakeShortCut.vbs"  
cscript //nologo %temp%\MakeShortCut.vbs
del "%temp%\MakeShortCut.vbs"  

pushD "%ExtRecentFolder%" ||chcp %CP% >nul &&exit /b 1  
if defined ExtRecentList for /f delims^= %%i in ('dir /b /o-d *.lnk ^|more %ExtRecentList% ^|find /v "" ' ) do del "%%~i"  
popD
chcp %CP% >nul
exit /b 0

call Batchlink.bat "%~f0" %*

start "Erstelle Link" Batchlink.bat "%~f0" %*

start "Erstelle Link" /wait cmd /c Batchlink.bat "%~f0" %*