117553
Aug 24, 2014, updated at 20:42:26 (UTC)
3189
7
0
Batch dir und Html Link ausgabe
Hallo zusammen,
folgendes Problem, ich möchte eine Batch mit folgender function
dir Ordner plus Unterordner durchsuchen ausgabe ohne Kopfzeile.... klar dir /b /s
einzelnes Ergebniss in Variable speichern ausgabe html datei mit links zu den einzelnen dateien (nur PDF) *.pdf
Also dachte in etwa so:
hab die Suche wirklich benutzt und lange probiert nur steig leider nicht dahinter...
mfg Markus
folgendes Problem, ich möchte eine Batch mit folgender function
dir Ordner plus Unterordner durchsuchen ausgabe ohne Kopfzeile.... klar dir /b /s
einzelnes Ergebniss in Variable speichern ausgabe html datei mit links zu den einzelnen dateien (nur PDF) *.pdf
Also dachte in etwa so:
@echo off
for /f %%i (' dir "C:\test\*.pdf" /b /s ') do set verz=%%i
echo ^<a href=" %verz% ^</a^> >>Link.html
:eofhab die Suche wirklich benutzt und lange probiert nur steig leider nicht dahinter...
mfg Markus
Share on Facebook
Share on Twitter
Share on Reddit
Share on LinkedinPlease also mark the comments that contributed to the solution of the article
Content-Key: 247326
Url: https://administrator.de/contentid/247326
Printed on: April 19, 2024 at 22:04 o'clock
7 Comments
Latest comment
Hallo Markus, willkommen im Forum.
Da kommen gleich mehrere Probleme zusammen.
Um diese Probleme zu lösen könntest du eine kombinierte Datei aus Batch und JScript schreiben (um die encodeURI Funktion nutzen zu können), sowie statt der HTML eine HTA Datei kreieren.
*.bat
Grüße
rubberman
EDIT: Support für Dateinamen mit Ausrufezeichen ergänzt.
EDIT2: Überflüssigen Slash entfernt
Da kommen gleich mehrere Probleme zusammen.
- Für lokale Pfade brauchst du eine File-URL
- Backslashes sind in URLs Slashes
- In URLs sind nur bestimmte Zeichen erlaubt. Zeichen (wie bspw. Leerzeichen) müssen kodiert werden
- Dein Browser wird vermutlich nicht auf lokale Dateien zugreifen dürfen
Um diese Probleme zu lösen könntest du eine kombinierte Datei aus Batch und JScript schreiben (um die encodeURI Funktion nutzen zu können), sowie statt der HTML eine HTA Datei kreieren.
*.bat
@if (@X)==(@Y) @end /* Hybrid Zeile, die einen JScript Kommentar einleitet
:: Batch Part:
@echo off &setlocal
set "htafile=Link.hta"
>"%htafile%" echo ^<html^>^<head^>^<HTA:APPLICATION WINDOWSTATE="maximize"^>^<title^>PDF Links^</title^>^</head^>^<body^>
set begin=^<a href=^"file:///&set middle=^"^>&set end=^</a^>^<br^>
>>"%htafile%" (
for /f "delims=" %%i in ('dir /a-d /b /s "*.pdf"') do (
set "file=%%i"
for /f "delims=" %%j in ('cscript //e:jscript //nologo "%~f0"') do (
set "url=%%j"
setlocal EnableDelayedExpansion
echo !begin!!url!!middle!!file!!end!
endlocal
)
)
)
>>"%htafile%" echo ^</body^>^</html^>
pause
exit /b
:: JScript Part: */
WScript.Stdout.WriteLine(
encodeURI(
WScript.CreateObject("WScript.Shell").Environment("PROCESS")("file").replace(/\\/g, "/")
)
);Grüße
rubberman
EDIT: Support für Dateinamen mit Ausrufezeichen ergänzt.
EDIT2: Überflüssigen Slash entfernt
1
oh mein Gott, ich war grad dabei es mit dem Teil aus dem Tutorial zu versuchen
"Die Variante zur Erzeugung von Zahlenfolgen, FOR /L mit setlocal enabledelayedexpansion " als mein Kopf auf die Tastatur knallte.... hab ich deine Nachricht gelesen und ausprobiert.... häng jetz seit einer Woche auf arbeit und zuhause dran und nu... weiß nicht was ich sagen sollen ausser HERZLICHSTEN DANK!
"Die Variante zur Erzeugung von Zahlenfolgen, FOR /L mit setlocal enabledelayedexpansion " als mein Kopf auf die Tastatur knallte.... hab ich deine Nachricht gelesen und ausprobiert.... häng jetz seit einer Woche auf arbeit und zuhause dran und nu... weiß nicht was ich sagen sollen ausser HERZLICHSTEN DANK!
Hallo Markus,
gern geschehen
Ich habe den Code oben noch einmal leicht verändert, um auch Dateinamen mit Ausrufezeichen vernünftig verarbeiten zu können.
Grüße
rubberman
gern geschehen
Ich habe den Code oben noch einmal leicht verändert, um auch Dateinamen mit Ausrufezeichen vernünftig verarbeiten zu können.
Grüße
rubberman
moin moin rubberman,
danke nochmal! ein Problem hab ich jetzt noch....
Umlaute bekomm ich doch mit "chcp 1252" richtiggestellt aber irgendwie klappt das nicht so richtig
der macht mir trotzdem sowas "Rüstenl" in den Link und dann funktioniert er natürlich auch nicht... leider
danke nochmal! ein Problem hab ich jetzt noch....
Umlaute bekomm ich doch mit "chcp 1252" richtiggestellt aber irgendwie klappt das nicht so richtig
der macht mir trotzdem sowas "Rüstenl" in den Link und dann funktioniert er natürlich auch nicht... leider
also da mit chcp is ja auch quatsch weil die Darstellung passt ja nur er übernimmt diese nicht so via Link in den Explorer..
Versuch mit Utf-8 scheiterte auch ebenso wie die Einstellungen des Explorers zu ändern....
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1" />
Versuch mit Utf-8 scheiterte auch ebenso wie die Einstellungen des Explorers zu ändern....
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1" />
Hallo Markus,
da siehst du wie kompliziert Encoding sein kann
Ich versuchs mal
Das sollte theoretisch den gewünschten Effekt erzielen ...
Grüße
rubberman
da siehst du wie kompliziert Encoding sein kann
Ich versuchs mal
- escape statt encodeURI
- Charset der HTA auf CP850
@if (@X)==(@Y) @end /* Hybrid Zeile, die einen JScript Kommentar einleitet
:: Batch Part:
@echo off &setlocal
set "htafile=Link.hta"
>"%htafile%" echo ^<html^>^<head^>^<meta charset="cp850"^>^<HTA:APPLICATION WINDOWSTATE="maximize"^>^<title^>PDF Links^</title^>^</head^>^<body^>
set begin=^<a href=^"file:///&set middle=^"^>&set end=^</a^>^<br^>
>>"%htafile%" (
for /f "delims=" %%i in ('dir /a-d /b /s "C:\test\*.pdf"') do (
set "file=%%i"
for /f "delims=" %%j in ('cscript //e:jscript //nologo "%~f0"') do (
set "url=%%j"
setlocal EnableDelayedExpansion
echo !begin!!url!!middle!!file!!end!
endlocal
)
)
)
>>"%htafile%" echo ^</body^>^</html^>
pause
exit /b
:: JScript Part: */
WScript.Stdout.WriteLine(
escape(
WScript.CreateObject("WScript.Shell").Environment("PROCESS")("file").replace(/\\/g, "/")
)
);Grüße
rubberman
1
ohje definitiv unterschätzt!! rubber, fühl dich ganz herzlich gedrückt! besten Dank!
funktioniert exzellente
funktioniert exzellente
