Oct 09, 2008, updated at Oct 18, 2012 (UTC)

17001

Per Batch alle Laufwerkbuchstaben auslesen aber Netzlaufwerke und CD-ROM ignorieren

Hallo erstmal. Das ist mein erster Beitrag in diesem Forum, habe hier schon sehr viele nützliche Tipps gefunden und bin mittlerweile so verzweifelt das ich mich jetzt selber angemeldet habe ;)

Mein Problem ist folgendes:
Ich möchte gerne für meine Firma ein Programm schreiben, welches einem normalen User es ermöglicht bestimmte Dinge ohne großen Support zu erledigen. Dieses Programm ist in mehrere Module geteilt und komplett in Batch geschrieben.
Ein Modul heist "Driver-Check" und soll alle Laufwerke auf Fehler überprüfen. Dabei sollen aber alle Netz- und CDROM-Laufwerke ignoriert werden. Ich hatte das Script auch schon so weit das er alles gemacht hat, bis eben CD-ROM Laufwerke ignorieren.. Hab dann so lange drann rumgeschusstert bis jetzt letztendlich garnichts mehr geht.. Deshalb hier erstmal der nicht funktionierende Code:

@echo off
for %%a in (A C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
fsutil fsinfo volumeinfo %%a:\ >nul
ECHO %ERRORLEVEL% 1
IF NOT ERRORLEVEL 1 for /f "Tokens=3* delims=\ " %%i in ('fsutil fsinfo volumeinfo %%a:\^|find "Volumename"') do (  
	
ECHO "%%a"  
net use | find /i "%%a:" >nul  
ECHO %ERRORLEVEL% 2
IF errorlevel 1 IF %%i! NEQ ! (
fsutil fsinfo drivetype %%a|findstr /c:"Eingebautes Laufwerk"  
ECHO %ERRORLEVEL% 3
IF NOT ERRORLEVEL 1	(
IF %%a==C (
ECHO                    %%a: Windows
) else (
ECHO                    %%a: %%i
)
)
) else (
fsutil fsinfo drivetype %%a|findstr /c:"Austauschbares Laufwerk"  
ECHO %ERRORLEVEL% 4
IF NOT ERRORLEVEL 1 (
ECHO                    %%a: %%i
)
)
											
											
ECHO %ERRORLEVEL% 5
IF errorlevel 1 IF %%i!==! ECHO                    %%a: Keine Bezeichnung
)
)
pause

Leider übernimmt das hier nicht ganz meine Formatierung.. Ich schau mal das ichs noch anders hinbekomm ;)
Wenn ihr meine Fehler findet wäre ich euch echt dankbar wenn ihr sie mir auch mitteilt. Danke schon mal!

PS: Ach ja, hier der noch funktionierende Code.

for %%a in (A C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
	fsutil fsinfo volumeinfo %%a:\ >nul
	IF ERRORLEVEL 0 for /f "Tokens=3* delims=\ " %%i in ('fsutil fsinfo volumeinfo %%a:\^|find "Volumename"') do (  
			IF %%a==C ECHO                    %%a: Windows
			IF %%a NEQ C net use | find /i "%%a:" >NUL  
			IF errorlevel 1 IF %%i! NEQ ! ECHO                    %%a: %%i
			IF errorlevel 1 IF %%i!==! ECHO                    %%a: Keine Bezeichnung
		)
	)

Please also mark the comments that contributed to the solution of the article

Content-Key: 98837

Url: https://administrator.de/contentid/98837

Printed on: April 20, 2024 at 00:04 o'clock

27 Comments

Latest comment

Hallo TheUntouchable,

deinen Code möchte ich nicht weiter auseinandernehmen, dich aber auf meinen Beitrag in
diesem Thread hinweisen.

cu paulepank

Hi,

Du kannst (falls es sich um XP SP2 handelt) von der Eingabeaufforderung aus mit:

wmic logicaldisk where "description like 'Local Fixed Disk'" get caption

die Laufwerksbuchstaben ermitteln.

Gruß
Stefan

Danke für den Tipp paulepank!

Leider bekomm ich die for Schleife nicht so hin das es funktionieren würde..

for /f "skip=1 Tokens=1,2 delims=:" %%i in ('wmic logicaldisk get caption,description^|find "Lokale Festplatte"') do ECHO %%i  

Fehlermeldung:
Ungültiger GET-Ausdruck.

Führe ich den Befehl ausserhalb der for Schleife aus gibt er aber alles richtig aus..

EDIT: Danke dem Beitrag unten von stbewo weis ich nun wies richtig geht ;)

for /f "skip=1 Tokens=1" %%i in ('wmic logicaldisk where "description like 'Lokale Festplatte'" get caption') do ECHO %%i  

Mein eigentliches Problem war das ich auch USB Sticks zur Auswahl haben wollte.. Wobei ich da glaub ich jetzt drauf verzichten werde, weil die USB Sticks unserer Anwender ja nicht defragmentiert werden sollten :P

Danke für die Hilfe!

Leider bekomme ich bei einem PC mit SP3 die Fehlermeldung:
"Keine Instanzen verfügbar."

Edit:
So gehts ;)
wmic logicaldisk where "description like 'Lokale Festplatte" get caption
anstatt
wmic logicaldisk where "description like 'Local Fixed Disk'" get caption

Danke für den Tipp!

Genau.

Ich wollte noch schreiben, dass es natürlich von der Sprachversion abhängt.
Du hast das Rätsel gelöst

Gruß
Stefan

So sieht letztendlich meine Lösung jetzt aus:

for /f "skip=1 Tokens=1" %%a in ('wmic logicaldisk where "description like 'Lokale Festplatte'" get caption') do (  

for /f "Tokens=3* delims=\ " %%i in ('fsutil fsinfo volumeinfo %%a\^|find "Volumename"') do (  

IF %%a==C: ECHO %%a Windows
IF %%a NEQ C: IF %%i! NEQ ! ECHO %%a %%i
IF %%a NEQ C: IF %%i!==! ECHO %%a Keine Bezeichnung
																							
)
)

Es wird erst anch dem Laufwerkbuchstaben gesucht der eine Lokale Festplatte ist. Anschließend wird für diesen die Bezeichnung herrausgesucht. Ist es das Laufwerk C: wird ihm die Bezeichnung "Windows" zugeteilt. Ist es ein Laufwerk ohne Bezeichnung, wird ihm "Keine Bezeichnung" zugeteilt. Hat das Laufwerk eine Bezeichnung wird diese ausgegeben.

Danke nochmals für die Hilfe ;)

Jetzt hätte ich noch eine andere Frage:
Ich würde gerne bei der Ausgabe vor die Laufwerke eine Nummerierung setzten, das es zb so aussieht:

1. C: Windows
2. D: Daten
3. E: Backup

Wie müsste ich das in meine Schleifen einbauen? Das mit dem Zählen hab ich noch nicht ganz gecheckt..

Hallo TheUntouchable,

1. Stefans Lösung ist eleganter.

2. um den Ansatz

for /f "skip=1 Tokens=1,2 delims=:" %%i in ('wmic logicaldisk get caption,description^|find "Lokale Festplatte"') do ECHO %%i  

zu korrigieren, muß es heißen:

for /f "delims= " %%i in ('wmic logicaldisk get caption^,description^|findstr /i "lokale festplatte"') do echo %%i  

3. ist es nicht sehr günstig in einem Thread wieder ein neues Problem anzusprechen, dafür würde sich ein neuer Thread gut machen

cu paulepank

Da Du mit FSUTIL nach dem Volumenamen suchst, kannst Du das ganze aber auch so machen.

wmic logicaldisk where "description like 'Lokale Festplatte'" get name, caption,volumename

Gruß
Stefan

Funktioniert leider nicht:

for /f "skip=1 Tokens=1" %%a in ('wmic logicaldisk where "description like 'Lokale Festplatte'" get name, caption,volumename ) do echo %%a  

Bekomme wieder den schönen Fehler:
Ungültiger GET-Ausdruck.

Gebe ich aber den ins cmd ein funktionierts. Kanns sein das es daran liegt das das Laufwerk C: keinen Volumennamen hat?

Hallo,

wenn du dir meine Korrektur angesehen hättest, sollte dir zumindest die Maskierung des Komma aufgefallen sein.

cu paulepank

Danke für den Hinweis paulepank.

Habe das ganze jetzt wieder umgeschrieben, leider funktioniert diese Variante nicht ganz so wie ichs gern hätte.. Er gibt zwar den Laufwerkbuchstaben C: aus aber nicht den Text Windows.

@echo off
for /f "skip=1 Tokens=1,2 delims= " %%a in ('wmic logicaldisk where "description like 'Lokale Festplatte'" get caption^,volumename') do (  
IF %%b!==! (
	IF %%a==C: (
		         ECHO %%a Windows
		        )else (
		        ECHO %%a Keine Bezeichnung
		        )
	) else (
	echo %%a %%b
	)
)
pause

Das Problem ist das %%b anscheinend nicht leer ist obwohl er nichts gefunden hat.. Wenn ichs mit Echo ausgeben lasse ist es aber leer.. Ich kapiers nich =(

Bei mir funktioniert es damit.

@echo off
for /F "tokens=1,2,3 skip=1" %%a in ('wmic logicaldisk where "description like 'Lokale Festplatte'" get Name^,VolumeName') do (
IF /I "%%a"=="C:" (
ECHO %%a = Windows Laufwerk VolumeName = %%b
)else (
ECHO %%a = Weiteres Laufwerk VolumeName = %%b)
pause

Gruß Stefan

Hallo TheUntouchable,

dein Code funktioniert bei mir. Siehe hier das Ergebnis

C: WinXP
D: Daten
E: TestXP

cu paulepank

Das liegt daran das du dein Laufwerk C: umbenannt hast. Es heist nicht mehr Lokaler Datenträger wie bei einer Neuinstallation. Wird dieser Name nicht geändert sieht das ganze so aus:

wmic logicaldisk where "description like 'Lokale Festplatte'" get caption^,volumename

Caption VolumeName
C:

Deshalb war auch die Abfrage mit dem IF %%b!==! da, aber diese klappt irgendwie nicht..

EDIT: Ole ole ole.. Ich habs anders geschaft =)

Einfach die Zeile:
IF %%b!==! (

Durch diese hier ersetzen:
IF not defined %%b (

Und es funktioniert :D Bitte testen!

Danke für den Vorschlag Stefan,
leider wird in dieser Variante nicht die Bezeichnung vom Laufwerk übernommen wenn eine vorhanden ist.. Und das ist sehr wichtig damit die User wissen um welches Laufwerk es sich handelt.

Hallo,

für weitere Batchexkurse:
leere Parameter werden so gestestet.

ja es funktioniert, aber muß auf c zwangsläufig Windows sein ?
EDIT: nein es funktioniert nicht

cu paulepank

Danke Paulepank, diese Seite kenn ich schon =)

Ja bei uns in der Firma sind alle Laufwerke C: mit Windows installiert.

Was funktioniert denn jetzt nicht?

EDIT: Okey.. Die IF DEFINED Abfrage funktioniert nicht *seufz* langsam mag ich nich mehr =(

Moin,

meint ihr es so?

:: ----snipp GetLocicalDrives.bat
@echo off
for /f "skip=1 Tokens=1,2" %%a in ('wmic logicaldisk where "DriveType=3" get name^, volumename') do (  
IF "%%a"=="%SystemDrive%" (  
    ECHO %%a Windows
) else (
    IF [%%b]== (ECHO %%a Keine Bezeichnung)   else  echo %%a %%b
)
)
pause

Anmerkungen:

"DriveType=3" als WMIC-Bedingung finde ich sinnvoller als eine "Beschreibung LIKE 'bla'
IF Laufwerk == %SystemDrive% ist besser als IF Laufwerk == C:
und die Variable %%b lässt sich nicht mit DEFINED prüfen, weil es ja ohnehin keine Defined/Statische Variable ist.

Grüße
Biber

Moin Biber,

ich antworte mal, obwohl es nicht mein Thread ist.

meint ihr es so ?

nö

zum einen wird bei c: immer Windows angezeigt, auch wenn das Volume einen Namen hat.
zum anderen wird bei anderen Volumes ohne Namen nichts statt "Keine Bezeichnung" angezeigt.

cu paulepank

Moin paulepank,

dass beim SystemDrive immer nur "Windows" angezeigt wird habe ich von oben übernommen.
Würde ich auch nicht so machen.
Den zweiten Punkt kann ich nicht bestätigen. [Edit]...weil ich ihn nicht getestet habe, siehe unten...[/Edit]

Kompromissvorschlag:

@echo off
for /f "skip=1 Tokens=1,2" %%a in ('wmic logicaldisk where "Drivetype=3" get name^, volumename') do (  
IF "%%a"=="%SystemDrive%" (  
    ECHO %%a %%b ^(Windows^)
) else (
    IF [%%b]== (ECHO %%a Keine Bezeichnung)   else  echo %%a %%b
)
)
pause

Output:

(=20:20:03  D:\temp=)
>e:\schnipsel\Logicaldrives.bat
C: System (Windows)
D: Daten

["System" und "Daten" sind die kreativen Bezeichnungen meiner C:/D:-Laufwerke]

Grüße
Biber

moin Biber,

zum 2. Punkt:

nenne doch mal kreativ D: um. Sprich: lösche die Bezeichnung "Daten".
Dann soll in der Auflistung "keine Bezeichnung" als Volumename stehen.
Das hast du bis jetzt nicht getestest.

cu paulepank

Mein Gott, paulepank,

Du kannst aber auch stur sein...

Aber Recht hast Du - in diesem Fall (kein Volumename-Parameter %%b geht raus) scheint M$ wieder mal die Output-Zeile nicht mit CRLF abzuschließen, sondern nur mit LF.
Oder nur mit CR. Oder mit CRCRLF Irgend so ein Praktikantenpfusch halt.
Das bringt immer den FOR/F Befehl durcheinander, kenn ich schon vom FsUtil-Befehl.

Anyhow, dann halt so.

::--- LogicalDrives.bat v03.
@echo off
for /f "skip=1 Tokens=1,2" %%a in (  
 'wmic logicaldisk where "Drivetype=3" get name^, volumename') do (  
        call :displayIt %%a %%b "Keine Bezeichnung")  
pause
goto :eof

:displayIt 
IF "%1"=="%SystemDrive%" (  
    ECHO %1 %~2 ^(Windows^)
) else (
    ECHO %1 %~2
)
Goto :eof

Output mit gelöschtem D.-Volumenamen:

(=21:20:34  D:\temp=)
>e:\schnipsel\Logicaldrives.bat
C: System (Windows)
D: Keine Bezeichnung
Drücken Sie eine beliebige Taste . . .

Besser?

Grüße
Biber

Guten Abend Biber und paulepank,
find ich super das ihr noch weiter macht wenn ich mir ne Auszeit gönne, danke Jungs ;)

Einen kleinen Fehler habe ich noch, aber wahrscheinlich wird das zu schwierig den zu beheben, habs selber schon probiert.

Wenn der Laufwerkname aus 2 Teilen besteht, wie zb "Windows XP", dann wird hier nur "Windows" angezeigt. Das doofe is nur das man dann kp wie viele Parameter braucht um alle Fälle abdecken zu können..

Falls euch da noch was einfallen sollte wärs spitze! Aber auch ohne diese Lösung schon mal vielen Dank für eure super Arbeit!

Viele Grüße

Michi

Moin Theo Tatschebell,

wenn's weiter nichts ist...

:: -----snipp LogicalDrives.bat v.04
@echo off
for /f "skip=1 Tokens=1,*" %%a in (  
 'wmic logicaldisk where "Drivetype=3" get name^, volumename') do (  
        call :displayIt %%a "%%~b" "Keine Bezeichnung")  
pause
goto :eof

:displayIt 
IF "%1"=="%SystemDrive%" (  
    ECHO %1 %~2 ^(Windows^)
) else (
    ECHO %1 %~2
)
Goto :eof

Output:

(=21:51:51  D:\temp=)
>e:\schnipsel\Logicaldrives.bat
C: System XP    (Windows)
D: Daten
Drücken Sie eine beliebige Taste . . .

Grüße
Biber

Hehe danke Biber, damit wär glaub ich dieses Thema abgeschlossen, du bist mein Held ;) Morgen test ichs nochmal in der Arbeit dann wirds geschlossen. Aber freu dich nicht zu früh morgen wirds nen neuen Thread geben.. :P

Gute Nacht ;)

Hi zusammen,

während Ihr noch schlaft, wollte ich weiter machen machen musste aber feststellen, da jibt es ja gar nichts mehr zu machen. Schade ;-(
Dann kann ich mich ja wieder hinlegen.

Gruß
Stefan

Hehe danke trotzdem Stefan ;)
Letztendlich habe ich jetzt noch ein wenig rumexperimentiert und die Wechseldatenträger doch mitgenommen, ebenso wie Diskettenlaufwerke. Bis jetzt funktionierts bei mir super, wäre nett wenns noch jemand testen könnte =)

@echo off

::Suchen der HDDs und Ausgabe
::------------------------------------------------------------------------------------------------------
for /f "skip=1 Tokens=1,*" %%a in ('wmic logicaldisk where "Drivetype=3" get name^, volumename') do (  
        call :displayIt1 %%a %%~b "Keine Bezeichnung")  
goto :NEXT2

:displayIt1
IF "%1"=="%SystemDrive%" (  
    ECHO                    %1 %~2 ^(Windows Laufwerk^)
) else (
    ECHO                    %1 %~2
)
Goto :eof

::Suchen von Diskettenlaufwerken und Ausgabe
::------------------------------------------------------------------------------------------------------
:NEXT2
for /f "skip=1 Tokens=1,4,5* delims=, " %%a in ('wmic logicaldisk where "Drivetype=2" get description^, name^, volumename') do (  

call :displayIt2 %%a %%b %%~c "Keine Bezeichnung")  

goto :NEXT3

:displayIt2
IF "%1"=="3" (  
	dir a: 2>nul|find "A:">nul && ECHO                    %2 %~3 ^(Diskettenlaufwerk^)  
)
)
GOTO :eof

::Suchen von Wechseldatenträgern und Ausgabe
::------------------------------------------------------------------------------------------------------
:NEXT3
for /f "skip=1 Tokens=1,2,3* delims= " %%a in ('wmic logicaldisk where "Drivetype=2" get description^, name^, volumename') do (  

call :displayIt3 %%a %%b %%~c "Keine Bezeichnung")  

goto :NEXT4

:displayIt3
IF "%1"=="Wechseldatentr„ger" (  
	ECHO                    %2 %~3 ^(Wechseldatentra„ger^)

)
)
GOTO :eof

:NEXT4
pause

German solved Question Batch, Shell Development

Hotly discussed

Check of ZFW Firewallgleixnerd - 3 Comments

How to set up and configure a Linux GRE tunnelAlexWisha - 3 Comments

WIREGUARD VPN ON UDM PRO BEHIND FRITZBOX - HANDSHAKE DID NOT COMPLETEjstricker - 3 Comments

End of Support dates for Office 2016, 2019 Apps und Productivity ServersDani - 1 Comment