BATch soll neuste Datei eines bestimmten Dateiy-Typs auf einem FTP-Server finden

@echo off & setlocal


::Daten für die FTP-Verbindung
set "FTPServer=Server"  
set "FTPUser=Username"  
set "FTPPassword=Passwort"  
set "FTPDir=/"  
set "FTPFileType=zip"  

::Pfade von temporären Dateien
set "GetFTPDirListing=%TEMP%\GetFTPDirListing.txt"  
set "FTPDirListing=%TEMP%\FTPDirListing.txt"  
set "FTPDirListing2=%TEMP%\FTPDirListing2.txt"  


::Die temporäre Datei leeren, die das Verzeichnislisting aufnimmt
type NUL > "%FTPDirListing%"  

::FTP-Script in temporäre Datei schreiben
> "%GetFTPDirListing%" echo open %FTPServer%  
>>"%GetFTPDirListing%" echo user %FTPUser% %FTPPassword%  
>>"%GetFTPDirListing%" echo ascii  
>>"%GetFTPDirListing%" echo cd "%FTPDir%"  
>>"%GetFTPDirListing%" echo ls -l "%FTPDirListing%"  
>>"%GetFTPDirListing%" echo bye  

::FTP-Script ausführen
::Das Verzeichnislisting wird dabei lokal in eine temporäre Datei geschrieben
ftp /inv /s:"%GetFTPDirListing%" > NUL  


::Aus dem Verzeichnislisting die Zeilen herausfiltern, die Dateien des gewünschten Typs enthalten
::Die Angaben zum Datum und den Dateinamen an das Unterprogramm ProcessFile übergeben
::Dessen Ausgaben werden in eine temporäre Datei umgeleitet
(for /f "tokens=6-8*" %%a in ('findstr /i /r /c:"^-.*\.%FTPFileType%$" "%FTPDirListing%" 2^>NUL') do (  
   call :ProcessFile %%c %%a %%b "%%d"  
)) > "%FTPDirListing2%"  


::Die im letzten Schritt erzeugte Datei mit SORT in absteigender Reihenfolge sortieren
::Dadurch steht die jüngste Datei in der ersten Zeile. Diese Zeile auslesen und dann Abbruch
for /f "tokens=3*" %%a in ('sort /r "%FTPDirListing2%" 2^>NUL') do (  
  set "NewestFile=%%b"  
  goto :ReadResultLoopBreak
)

:ReadResultLoopBreak
::Ergebnis ausgeben
echo.%NewestFile%


::Temporäre Dateien löschen
del "%FTPDirListing%"  
del "%FTPDirListing2%"  
del "%GetFTPDirListing%"  

::Script Ende
exit /b 0



::Unterprogramm
::Erzeugung der 2-stelligen numerischen Darstellung eines Monatsnamens
:ProcessFile
  set "MonthNames=Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec"  
  set "MonthA=%2"  
  set /a MonthN=0

  ::Monatsnummer aus dem Namen ermitteln
  for %%m in (%MonthNames%) do (
    set /a MonthN+=1
    if /i "%%m" equ "%MonthA%" goto :MapLoopBreak  
  )

  :MapLoopBreak
  ::Aus der Monatsnummer die 2-stellige Darstellung erzeugen
  set "MonthN=0%MonthN%"  
  set "MonthN=%MonthN:~-2%"  

  ::Datum und Dateiname ausgeben
  ::Anschließend ein Zeilenumbruch
  <NUL set /p "=%1 %MonthN% %3 %~4"  
  echo.

::Back to caller
exit /b 0

-rw-r--r--    1 ftp      ftp         74610 Jun 06  2012 hist-deu.txt
-rw-r--r--    1 ftp      ftp         28537 Oct 22  2010 hist-eng.txt
-rw-r--r--    1 ftp      ftp          1468 Jul 27  2010 info-deu.txt
-rw-r--r--    1 ftp      ftp          1672 Jul 27  2010 info-eng.txt
dr-xr-xr-x   11 ftp      ftp          4096 Nov 28  2006 programs
drwxr-xr-x    2 ftp      ftp          4096 Mar 11  2003 public
dr-xr-xr-x   13 ftp      ftp          4096 Dec 08  2008 tools

cd /d "%UserProfile%\Desktop"
ftp -n
open ftp.pcklick.net
user w00ec0b6 DeinPasswort
ascii
ls -l ftpdir.txt
bye