Per Batch Recursive nach Log-files des heutigen Datums suchen und diese in einen Ordner kopieren

Liebe Community

Ich würde gerne mit einem Batch-Script den Ordner d:\data0 inklusive aller Unterordner nach *.log dateien durchsuchen.
Falls die gefundenen *.log dateien am heutigen Tag verändert/angelegt wurden, sollten diese in den Ordner d:\data0\logs gespeichert werden.

Da ich mich mit Batch-Scripting nicht wirklich auskenne, bitte ich um Lösungsansätze.

Derzeit habe ich das Script wie folgt umgesetzt :

Habe mal manuell geschaut in welchen Ordnern Logdateien vorhanden sind und habe die Pfade als Quelle1 - Quelle73 definiert.
Als Ziel habe ich nur eines angegeben d:\data0\logs. Das Script durchforstet also eine Quelle nach der anderen und überprüft das Datum
und kopiert die heutigen Logs in den Zielordner.

Da dieses Script nun auf diverse Server verteilt werden soll und dort die Pfade nicht umbedingt ident sind,
bedeutet dies für mich einen ordentlichen Mehraufwand, den man sich mit einem Script eventuell Sparen könnte.

Vielen Dank
liebe Grüße
Xziped

@echo off & setlocal
set "Basis=D:\data0"  
set "Ziel=%Basis%\logs"  
set "Typ=log"  

if not exist "%Ziel%" md "%Ziel%"  

REM Dateien aus Basisordner einsammeln
for /f "delims=" %%f in ('dir /b "%Basis%\*.%Typ%" 2^>nul') do call :ProcessFile "%Basis%\%%f"  
REM Dateien aus den Unterordnern (rekursiv) einsammeln ...
for /d %%d in ("%Basis%\*.*") do (  
    REM ... dabei aber den Zielordner aussparen
    if /i "%%d" neq "%Ziel%" (  
        for /f "delims=" %%f in ('dir /s /b "%%d\*.%Typ%" 2^>nul') do call :ProcessFile "%%f"  
    )
)
goto :eof

:ProcessFile
echo %~t1|findstr /b "%date%">nul && (  
    echo %~1
    copy %1 "%Ziel%">nul  
)
goto :eof