Binär Übersetzer per Batch (Vbs)

FILEPATH = "C:\DeineTextDatei.txt"  
Set objFSO = CreateObject("Scripting.FileSystemObject")  
Set objText = objFSO.OpenTextFile(FILEPATH, 1)
strText = objText.ReadAll
objText.Close()

'----------------Umwandlungen---------------------  
'String zu Binär  
sBinary = StringToBinary(strText)
'String zu Hex  
sHex = StringToHex(strText)
'String zu Dezimal  
sDec = StringToDec(strText)
'Binär zu String  
sString = BinaryToString(sBinary)
'-------------------------------------------------  
'Ausgabe  
MsgBox "Binärwerte des Strings: " & vbNewLine & sBinary  
MsgBox "Hexwerte des Strings: " & vbNewLine & sHex  
MsgBox "Dezimalwerte des Strings: " & vbNewLine & sDec  
MsgBox "Umwandlung der Binärwerte zurück in den Text: " & vbNewLine & sString  
'-------  

'------ Funktionen ------------  
Function StringToDec(sText)
	sDec = ""  
	aByte = StringToByteArray(sText)
	For Each b In aByte
		sDec = sDec & b
	Next
	StringToDec = sDec
End Function

Function StringToByteArray(sText)
	Dim iByte()
	For i = 1 To Len(sText)
		ReDim Preserve iByte(i)
		iByte(i-1) = CByte(Asc(Mid(sText,i,1)))
	Next
	StringToByteArray = iByte
End Function

Function ByteArrayToString(aByte)
	sString = ""  
	For i = 0 To UBound(aByte)
		sString = sString & Chr(CStr("&h" & Hex(aByte(i))))  
	Next
	ByteArrayToString = sString
End Function

Function StringToHex(sText)
	sHex = ""  
	For i = 1 To Len(sText)
		sHex = sHex & Right("0" & Hex(CByte(Asc(Mid(sText,i,1)))),2)  
	Next
	StringToHex = sHex
End Function

Function HexToString(sHex)
	sString = ""  
	For i = 1 To Len(sHex) Step 2
		sString = sString & Chr(CStr("&h" & Mid(sHex,i,2)))  
	Next
	HexToString = sString
End Function

Function StringToBinary(sText)
	sBinary = ""  
	For i = 1 To Len(sText)
		iByte = CByte(Asc(Mid(sText, i, 1))) 
	  	For b = 7 To 0 Step -1
	  		If iByte >= 2 ^ b Then
	  			sBinary = sBinary & "1"  
	  			iByte = iByte - (2 ^ b)
	  		Else
	  			sBinary = sBinary & "0"  
	  		End If
	  	Next
	Next
	StringToBinary = sBinary
End Function

Function BinaryToString(sBinary)
	sString = ""  
	For i = 1 To Len(sBinary) Step 8
		sByte = Mid(sBinary,i,8)
		iByte = 0
		For b = 7 To 0 Step - 1
			If Mid(sByte,8-b,1) = 1 Then
				iByte = iByte + (2^b)
			End If
		Next
		sString = sString & Chr(CStr("&h" & Hex(iByte)))  
	Next
	BinaryToString = sString
End Function
'----------------------  

Const strFileBin = "C:\Test\Bin.txt"  
Const strFileHex = "C:\Test\Hex.txt"  
Const strFileDec = "C:\Test\Dec.txt"  

Const strInput = "Herr Meier schießt mit gewählten Schüssen auf André"  

'Text To Bin, Dez, Hex________________________________________________  

For i = 1 To Len(strInput)
    iByte = CByte(Asc(Mid(strInput, i, 1)))
    
    strHex = Right("0" & Hex(iByte), 2)  
    strDec = Right("00" & iByte, 3)  
    
    strBin = ""  
    For b = 7 To 0 Step -1
        If iByte And (2 ^ b) Then
            strBin = strBin & 1
        Else
            strBin = strBin & 0
        End If
    Next
        
    strHexText = strHexText & strHex
    strDecText = strDecText & strDec
    strBinText = strBinText & strBin
Next

With CreateObject("Scripting.FileSystemObject")  
    With .CreateTextFile(strFileBin)
        .Write strBinText:  .Close
    End With
    With .CreateTextFile(strFileHex)
        .Write strHexText:  .Close
    End With
    With .CreateTextFile(strFileDec)
        .Write strDecText:  .Close
    End With
End With

'Bin To Text__________________________________________________________  

With CreateObject("Scripting.FileSystemObject")  
    strBinText = .OpenTextFile(strFileBin).ReadAll
End With

strText = ""  
For i = 1 To Len(strBinText) Step 8
    strBin = StrReverse(Mid(strBinText, i, 8))
    
    iByte = 0
    For b = 0 To 7
        If Mid(strBin, b + 1, 1) = 1 Then
            iByte = iByte Or (2 ^ b)
        End If
    Next
        
    strText = strText & Chr(iByte)
Next
MsgBox strText,,"BinToText..."  

'Dec To Text__________________________________________________________  

With CreateObject("Scripting.FileSystemObject")  
    strDecText = .OpenTextFile(strFileDec).ReadAll
End With

strText = ""  
For i = 1 To Len(strDecText) Step 3
    strText = strText & Chr(CByte(Mid(strDecText, i, 3)))
Next
MsgBox strText,,"DecToText..."  

'Hex To Text__________________________________________________________  

With CreateObject("Scripting.FileSystemObject")  
    strHexText = .OpenTextFile(strFileHex).ReadAll
End With

strText = ""  
For i = 1 To Len(strHexText) Step 2
    strText = strText & Chr(CByte("&H" & Mid(strHexText, i, 2)))  
Next
MsgBox strText,,"HexToText..."