destry
Goto Top

CMD-Batch - Problem mit Sonderzeichen beim Auslesen eines Textes in eine Variable

Hallo allerseits,

nachdem ich hier im Forum schon "lesenderweise" viel Hilfe erfahren habe, möchte ich mich heute "schreibenderweise" an Euch wenden.
Hier mein Problem:

Umgebung:
Windows XP, Sp3, keine dritten Programme.

Ich sammle zur Zeit mit den Befehlen "dsquery" und dsget" Informationen über Nutzerkonten.
Dabei sollen die Informationen in Variable gelenkt werden um sie weiter verwenden zu können.
Eine Information ist die Beschreibung eines Nutzerkontos. Durch eine Abfrage die ich in eine Textdatei umlenke bekomme ich folgende Ausgabe:

--desc------------------------------------------
--Mitarbeiter Systems & Application Management--
dsget succeeded

Erklärung:
In der ersten Zeile steht der Parameter der Abfrage (desc=Description)
In der zweiten Zeile stehe die eigentliche Information.
In der dritten Zeile steht die Erfolgsmeldung des Befehls.
ACHTUNG: Die Striche (-) sind kein Inhalt der Ausgabe. Sie sollen hier für die "unsichtbaren" Leerzeichen stehen.

Um die Textdatei auszulesen habe ich mich einer Batch (von Biber) aus dem Forum bedient:

::----- Schnipp -----
@echo off

echo Kennung eingeben:
set /P TPL_SAMID=

dsquery user -samid %TPL_SAMID% | dsget user -desc > %TPL_SAMID%_Description_Query_01.txt

for /f "delims=" %%i in (%TPL_SAMID%_Description_Query_01.txt) do call :SET_NEW_QUERY_DESC_VAR %%i  
goto :GO_ON_QUERY_DESC

:SET_NEW_QUERY_DESC_VAR
set NEW_QUERY_DESC_VAR=%NEW_QUERY_DESC_VAR%!%*
goto :EOF

:GO_ON_QUERY_DESC
for /f "tokens=1,2 delims=!" %%i in ("%NEW_QUERY_DESC_VAR%") do @set NEW_DESCRIPTION=%%j  

echo "%NEW_DESCRIPTION%"  
::----- Schnapp -----
Erklärung:
1.) Nutzerkennung eingeben.
2.) Abfrage nach der Beschreibung des Nutzerkontos.
3.) Zeilenweises Auslesen der Textdatei (Inhalt siehe oben) in eine Variable mit dem "!" als Delimiter.
4.) Auslesen dieser Variable des zweiten Tokens in eine neue Variable.

Diese Abfrage funktioniert im Normalfall auch wunderbar.
Hier das Problem:

Das "&".
Wenn im auszulesenden Text ein "&" vorkommt greift der Call-Befehl aus der ersten For-Schleife ins Leere weil es als Kommando interpretiert wird.
Ich habe schon versucht die Variablen in Anführungszeichen zu stellen, aber dann bekomme ich die ganzen Leerzeichen mit, und die kann ich nicht gebrauchen.

Ziel soll sein das der Text

Mitarbeiter Systems & Application Management

ohne Leer- oder Anführungszeichen in einer Variablen steht.

Habt ihr dafür vielleicht einen Vorschlag?
Bitte bleibt bei der DOS-Shell.
Ich weiß das es in anderen Programmiersprachen einfachere Lösungen gibt, aber mich reizt das Problem.

Vielen Dank für eure Unterstützung.

Gruß,
Destry


[Edit Biber] Als formatiert. Und wenigstens im Titel den "DOS-Batch" umbenannt in "CMD-Batch". [/Edit]

Content-Key: 84409

Url: https://administrator.de/contentid/84409

Ausgedruckt am: 28.03.2024 um 21:03 Uhr

Mitglied: bastla
bastla 01.04.2008 um 12:18:03 Uhr
Goto Top
Hallo Destry und willkommen als schreibender Teilnehmer!

Vielleicht (allerdings gänzlich ungetestet) so:
@echo off

echo Kennung eingeben:
set /P TPL_SAMID=

dsquery user -samid %TPL_SAMID% | dsget user -desc > %TPL_SAMID%_Description_Query_01.txt

for /f "delims=" %%i in (%TPL_SAMID%_Description_Query_01.txt) do call :SET_NEW_QUERY_DESC_VAR "%%i"  
goto :GO_ON_QUERY_DESC

:SET_NEW_QUERY_DESC_VAR
set "NEW_QUERY_DESC_VAR=%NEW_QUERY_DESC_VAR%!%~*"  
goto :EOF

:GO_ON_QUERY_DESC
for /f "tokens=1,2 delims=!" %%i in ("%NEW_QUERY_DESC_VAR%") do @set NEW_DESCRIPTION=%%j  

echo "%NEW_DESCRIPTION%"  

Grüße
bastla
Mitglied: Destry
Destry 01.04.2008 um 13:38:54 Uhr
Goto Top
Hallo Bastla,

danke für den warmen Empfang und den Hilfeversuch.
Leider geht es so nicht.

Das sind die Fehlermeldungen:

Die folgende Verwendung des Pfadoperators zur Ersetzung eines Batchparameters
ist ungültig: %~*"

Geben Sie CALL /? oder FOR /? ein, um herauszufinden, welche Formate gültig sind.
":SET_NEW_QUERY_DESC_VAR
" ist syntaktisch an dieser Stelle nicht verarbeitbar.

Klingt übel, aber danke.

Gruß,
Destry
Mitglied: bastla
bastla 01.04.2008 um 14:11:34 Uhr
Goto Top
Hallo Destry!

Na gut, dann neuer Versuch:
@echo off & setlocal

echo Kennung eingeben:
set /P TPL_SAMID=

dsquery user -samid %TPL_SAMID% | dsget user -desc > %TPL_SAMID%_Description_Query_01.txt

for /f "delims=" %%i in (%TPL_SAMID%_Description_Query_01.txt) do call :SET_NEW_QUERY_DESC_VAR "%%i"  
goto :GO_ON_QUERY_DESC

:SET_NEW_QUERY_DESC_VAR
set "NEW_QUERY_DESC_VAR=%NEW_QUERY_DESC_VAR%!%~1"  
goto :EOF

:GO_ON_QUERY_DESC
for /f "tokens=1,2 delims=!" %%i in ("%NEW_QUERY_DESC_VAR%") do @set NEW_DESCRIPTION=%%j  

:Loop1
if "%NEW_DESCRIPTION:~0,1%" neq " " goto :Loop2  
set "NEW_DESCRIPTION=%NEW_DESCRIPTION:~1%"  
goto :Loop1

:Loop2
if "%NEW_DESCRIPTION:~-1%" neq " " goto :Done  
set "NEW_DESCRIPTION=%NEW_DESCRIPTION:~0,-1%"  
goto :Loop2

:Done
echo "%NEW_DESCRIPTION%"  

Grüße
bastla
Mitglied: Destry
Destry 01.04.2008 um 14:45:22 Uhr
Goto Top
Hey Bastla,

es klappt. Vielen Dank dafür.
Es bleiben zwar noch die Anführungszeichen am Anfang und am Ende, aber immerhin.
Super Arbeit.

Magst Du mir noch erklären was in den Loops passiert?
Die Parameter sind mir nicht geläufig und im Test habe ich Deiner Logik nicht folgen können.

Nochmals danke.

Gruß,
Destry
Mitglied: Destry
Destry 01.04.2008 um 15:05:56 Uhr
Goto Top
Hallo Bastla,

ich habe nochmal genauer hingeguckt und da sind ja gar keine Anführungsstriche mehr.
Die Loops habe ich jetzt auch verstanden.

Nochmals danke für das Licht.

Gruß,
Destry