Dateien auf dem FTP Server prüfen

@echo off

REM Infos zur überwachten Datei
set "FILE=readme.txt"  
set "SIZE=626"  
REM Benutzerdaten zum FTP-Server
set "FTP_SERVER=192.0.0.180"  
set "FTP_USER=benutzername"  
set "FTP_PASS=******"  

REM Logdatei zum speichern der "FTP-Verzeichnisliste"  
REM Mein FTP-Server listet so auf:
REM -rw-r--r--    1 arano    arano         626 Mar 12  2006 readme.txt
REM Token-5 = Bytes
REM Token-9 = Dateiname
set "LOG=batch-ftp.log"  
REM Datei in die die FTP-Komandos "zwischengespeichert" werden  
set "CMDS=ftp-commands.cmd"  
REM Lösche eventuelle "überbleibsel"  
if exist %LOG% del %LOG%
if exist %CMDS% del %CMDS%

REM Erstelle Temporäre FTP-Kommando-Datei
>>%CMDS% echo ls
REM FTP-Aktionen in Logdatei umleiten
>>%LOG% psftp.exe -b %CMDS% -l %FTP_USER% -pw %FTP_PASS% %FTP_SERVER%
REM Lösche FTP-Kommando-Datei
del %CMDS%

REM Suche in der Logdatei nach der Datei und überprüfe sie
for /F "tokens=5,9" %%i IN ('findstr "%FILE%" %LOG%') DO (  
  echo Datei %%j gefunden, teste Groesse %%i ^>= %SIZE%
  if %%i GEQ %SIZE% (
    echo Groesse OK
  ) else (
    echo zu klein !!
    goto send_mail
  )
  set "found=true"  
)

REM wenn %found% nicht "true" ist, wurde Datei nicht gefunden  
if not "%found%"=="true" (  
  echo Datei %FILE% existiert nicht
  goto send_mail
)


REM wenn das Programm bi hier her durch läuft,
REM war wohl alles in Ordnung.
REM "überspringe" E-Mail versand !  
goto ende


REM wird hierher gesprungen, gab es eine Differenz,
REM benachrichtige den Admin
:send_mail
echo Sende E-Mails an Admin (verwende blat.exe)


:ende
REM Programmende, lösche Verzeichnisliste
del %LOG%


pause

@echo off & setlocal


set "FileList="test1.txt" "test2.txt" "test3.txt""  
set "FileSizes=28537 1459 3469"  

set "FTPServer=DerFTPServer"  
set "FTPUser=FTPUsername"  
set "FTPPass=FTPPasswort"  


set "FTPScript=%Temp%\FTPScript.txt"  

> "%FTPScript%" echo open %FTPServer%  
>>"%FTPScript%" echo user %FTPUser% %FTPPass%  
>>"%FTPScript%" echo ascii  
>>"%FTPScript%" echo ls -l  
>>"%FTPScript%" echo bye  

for /f "tokens=5,8*" %%a in ('ftp -n -v -s:"%FTPScript%" ^| findstr /v "^ftp> ^bye ^d"') do (  
  call :ProcessFileName "%%c" %%a  
)

for %%f in (%FileList%) do (
  if %%f neq "" call :FileNotFound %%f  
)

del "%FTPScript%"  
exit /b



:ProcessFileName
  set "FileName=%1"  
  set /a Idx=1

  for %%f in (%FileList%) do (
    if %%f equ %FileName% (
      call :CheckFileSize %FileName% %2
      call set "FileList=%%FileList:%%~f=%%"  
    )
    set /a Idx+=1
  )
exit /b


:CheckFileSize
  for /f "tokens=%Idx%" %%s in ("%FileSizes%") do (  
    if %%s neq %2 call :FileSizeWrong %1 %2
  )
exit /b


:FileSizeWrong
  echo Dateigröße falsch: %1 %2 Bytes
  rem Hier ein BLAT-Aufruf
exit /b


:FileNotFound
  echo Datei nicht gefunden: %1
  rem Hier ein BLAT-Aufruf
exit /b

C:\DuE\Arano>ftp -n -v
ftp> open 192.168.178.180
ftp> user arano
Kennwort: ******
ftp> pwd
257 "/home/arano" is the current directory  
ftp> ls -l
Illegal PORT command
ftp> pwd
257 "/home/arano" is the current directory  
ftp>