Top-Themen

AppleEntwicklungHardwareInternetLinuxMicrosoftMultimediaNetzwerkeOff TopicSicherheitSonstige SystemeVirtualisierungWeiterbildungZusammenarbeit

Aktuelle Themen

Administrator.de FeedbackApache ServerAppleAssemblerAudioAusbildungAuslandBackupBasicBatch & ShellBenchmarksBibliotheken & ToolkitsBlogsCloud-DiensteClusterCMSCPU, RAM, MainboardsCSSC und C++DatenbankenDatenschutzDebianDigitiales FernsehenDNSDrucker und ScannerDSL, VDSLE-BooksE-BusinessE-MailEntwicklungErkennung und -AbwehrExchange ServerFestplatten, SSD, RaidFirewallFlatratesGoogle AndroidGrafikGrafikkarten & MonitoreGroupwareHardwareHosting & HousingHTMLHumor (lol)Hyper-VIconsIDE & EditorenInformationsdiensteInstallationInstant MessagingInternetInternet DomäneniOSISDN & AnaloganschlüsseiTunesJavaJavaScriptKiXtartKVMLAN, WAN, WirelessLinuxLinux DesktopLinux NetzwerkLinux ToolsLinux UserverwaltungLizenzierungMac OS XMicrosoftMicrosoft OfficeMikroTik RouterOSMonitoringMultimediaMultimedia & ZubehörNetzwerkeNetzwerkgrundlagenNetzwerkmanagementNetzwerkprotokolleNotebook & ZubehörNovell NetwareOff TopicOpenOffice, LibreOfficeOutlook & MailPapierkorbPascal und DelphiPeripheriegerätePerlPHPPythonRechtliche FragenRedHat, CentOS, FedoraRouter & RoutingSambaSAN, NAS, DASSchriftartenSchulung & TrainingSEOServerServer-HardwareSicherheitSicherheits-ToolsSicherheitsgrundlagenSolarisSonstige SystemeSoziale NetzwerkeSpeicherkartenStudentenjobs & PraktikumSuche ProjektpartnerSuseSwitche und HubsTipps & TricksTK-Netze & GeräteUbuntuUMTS, EDGE & GPRSUtilitiesVB for ApplicationsVerschlüsselung & ZertifikateVideo & StreamingViren und TrojanerVirtualisierungVisual StudioVmwareVoice over IPWebbrowserWebentwicklungWeiterbildungWindows 7Windows 8Windows 10Windows InstallationWindows MobileWindows NetzwerkWindows ServerWindows SystemdateienWindows ToolsWindows UpdateWindows UserverwaltungWindows VistaWindows XPXenserverXMLZusammenarbeit
GELÖST

Dateien in verschiedene Ordner kopieren

Frage Entwicklung Batch & Shell

Mitglied: weaslflink

weaslflink (Level 1) - Jetzt verbinden

15.12.2011 um 15:14 Uhr, 3985 Aufrufe, 14 Kommentare

Hallo liebe Community,

Ich bin auf dem Gebiet von Batch ein totaler Neuling und kenn mich überhaupt nicht aus.
Deswegen bitte ich euch um Rat.

Nun zu meinem Problem.

Ich möchte via Batch Dateien auf ein anderes Laufwerk in verschiedene Ordner kopieren. Falls die Datei schon vorhanden ist soll diese im namen eweitert werden, sodass ich beide Dateien behalte.

Die Dateinamen sehen wie folgt aus:
3413_13354789.pdf
20501_55568749.pdf
4403_....
etc.

Ausgangsorder ist der windows "eigene dateien/myscans/" ordner und ziellaufwerk ein usb-stick.

Auf dem USB-Stick sind jeweis Ordner mit der mit der Bezeichnung "3413", "20501","4403" etc.

Also, ich möchte alle Dateien, die mit der Zahl vor dem Unterstrich anfangen, in den jeweils dazugehörigen Ordner verschieben. Falls dieser noch nicht existiert soll einer erstellt werden.

Ich hoffe ich habe mein Vorhaben verständnisvoll geschildert.

Vielen Dank schon mal im voraus !
Mitglied: bastla
15.12.2011 um 16:13 Uhr
Hallo weaslflink und willkommen im Forum!

Ohne Berücksichtigung bereits vorhandener Dateien im Zielordner würde sich das in einer Zeile abhandeln lassen (ungetestet zur Direkteingabe in CMD, daher nur mit %i und nicht, wie in einem Batch, mit %%i; das "echo" vor dem "xcopy" sorgt für ein gefahrloses Testen, da so der Kopierbefehl nur angezeigt, aber nicht ausgeführt wird; Ziellaufwerk E: ):
for /f "tokens=1* delims=_" %i in ('dir /b /a-d "%userprofile%\Eigene Dateien\myscans\*_*.pdf"') do @echo xcopy "%userprofile%\Eigene Dateien\myscans\%i_%j" "E:\%i\%i_%j*"
Falls die Datei schon vorhanden ist soll diese im namen eweitert werden, sodass ich beide Dateien behalte.
solltest Du noch etwas näher ausführen ...

Grüße
bastla

[Edit] Fehlendes Anführungszeichen nach pdf ergänzt [/Edit]
Bitte warten ..
Mitglied: Friemler
15.12.2011 um 18:13 Uhr
Hallo weaslflink,

hier mein Vorschlag zur Lösung des Problems:
01.
@echo off & setlocal 
02.
 
03.
set "SrcDir=%UserProfile%\Eigene Dateien\myscans" 
04.
set "DestDir=E:" 
05.
set "FileType=pdf" 
06.
 
07.
for /f "tokens=1* delims=_" %%a in ('dir /b /a:-d "%SrcDir%\*_*.%FileType%" 2^>NUL') do ( 
08.
  call :RenOldVersion "%DestDir%\%%a\%%a_%%b" 
09.
  xcopy "%SrcDir%\%%a_%%b" "%DestDir%\%%a\%%a_%%b*" > NUL 
10.
11.
 
12.
exit /b 
13.
 
14.
 
15.
:RenOldVersion 
16.
  set /a "NumFiles=0" 
17.
 
18.
  for /f "tokens=1 delims=:" %%c in ('dir /b /a:-d "%~dpn1*%~x1" 2^>NUL ^| findstr /n "^"') do ( 
19.
    set /a "NumFiles=%%c" 
20.
21.
 
22.
  if %NumFiles% gtr 0 ren "%~1" "%~n1(%NumFiles%)%~x1" 
23.
exit /b
In den Zeilen 3-5 musst Du die Pfade ggf. anpassen. Dabei gilt zu beachten, dass keiner der beiden Pfade in Zeile 3 und 4 mit einem \ (Backslash) enden darf. Im Beispielcode oben würden die Zielverzeichnisse 3413, 20501, 4403 etc. im Wurzelverzeichnis von Laufwerk E: gesucht.

Falls im Zielverzeichnis bereits Dateien vorhanden sind, die umbenannt werden müssen, geht das Script nach Art des Windows Explorers vor und hängt eine in Klammern stehende Zahl an den Dateinamen an (aus 3413_13354789.pdf wird z.B. 3413_13354789(1).pdf oder 3413_13354789(2).pdf). Die Zahl hängt von der Anzahl bereits existierender Versionen der Datei ab. Erledigt wird das ganze im Unterprogramm RenOldVersion.

Gruß
Friemler


[EDIT]
Ich habe die Anregung von bastla aufgegriffen, und das Nicht-Vorhanden-Sein des Zielverzeichnisses im Script berücksichtigt (wird durch die Verwendung von XCOPY bei Bedarf angelegt).
[/EDIT]

[EDIT2]
Außerdem auch von mir noch eine Erklärung zur Funktionsweise des Unterprogramms RenOldVersion (das Hauptprogramm baut auf bastlas ursprünglichem Code auf und lässt sich deshalb mit Hilfe seiner ausführlichen Erklärung verstehen):

Dem Unterprogramm wird in Zeile 8 der Zielpfad+Name der aktuell betrachteten Quelldatei als Parameter übergeben. Im Unterprogramm kann er über %1 (der erste Parameter) angesprochen werden.

Mit %~dpn1 in Zeile 18 wird der Parameter in Laufwerk (d) + Pfad (p) + Dateiname (n) ohne Dateierweiterung zerlegt (aus E:\PDF-Dokumente\3413_13354789.pdf wird E:\PDF-Dokumente\3413_13354789). Dem wird ein * angehängt (damit vom DIR-Befehl auch schon existierende Dateien mit einer in Klammern eingeschlossenen Laufnummer gefunden werden). Daran wird mit %~x1 die Dateierweiterung (also .pdf) angehängt.

Die somit erzeugte Dateimaske wird dem DIR-Befehl übergeben, der wegen dem Parameter /a:-d nur Dateien findet und wegen dem Parameter /b nur eine Liste mit deren Namen ohne Pfad und ohne den üblichen Header und Footer der DIR-Ausgabe erzeugt. Falls der Pfad nicht bzw. keine passende Datei existiert, würde DIR eine Fehlermeldung ausgeben, was dazu führen würde, dass der Code innerhalb der FOR-Schleife fälschlicherweise ausgeführt wird. Deshalb wird mit 2^>NUL der Fehlerkanal zum NUL-Device umgeleitet, die Fehlermeldung wird somit verschluckt und der Schleifenrumpf nicht ausgeführt (das Zirkumflex-Zeichen ^ in 2^>NUL ist nur an dieser Stelle, im Kopf der FOR-Schleife, erforderlich, um das >-Zeichen zu "escapen").

Die Ausgabe von DIR wird wegen ^| (auch hier dient das ^ zum "escapen" von |) über eine Pipe an den Befehl FINDSTR weitergeleitet, der wegen dem Parameter "^" (ein sog. regulärer Ausdruck) Zeilen mit einem Anfang findet (also alle Zeilen) und wegen /n Zeilennummern mit einem nachfolgenden Doppelpunkt vor jede Zeile schreibt.

Der Doppelpunkt ist mit delims=: für die FOR-Schleife als Trennzeichen innerhalb einer Zeile definiert. Wegen tokens=1 wird nur der Teil des Zeileninhalts an die Laufvariable %%c zugewiesen, der vor dem Doppelpunkt steht, also die Zeilennummer, die von FINDSTR erzeugt wurde.

Innrhalb der FOR-Schleife wird diese Zeilenummer bei jedem Durchlauf an die Variable NumFiles zugewiesen. Nach dem Abschluss der Schleife enthält NumFiles also die Anzahl der Dateien, auf die das Suchmuster passt oder (wegen Zeile 16) den wert 0, wenn es keine solchen Dateien gibt.

In Zeile 22 wird geprüft, ob der Wert von NumFiles größer 0 ist, wenn ja wird die gefundene Datei mit REN umbenannt.

Der ursprüngliche Name steht in der Variablen %1 (die Tilde ~ in "%~1" entfernt evtl. vorhandene Anführungszeichen, in die der Inhalt von %1 eingeschlossen sein könnte; außerdem wird damit der Inhalt von %1 auf jeden Fall mit Anführungszeichen eingeschlossen; hier nicht unbedingt notwendig, ist aber eine Angewohnheit von mir, solche Dinge zu coden), der neue Name wird mit %~n1(%NumFiles%)%~x1 erzeugt (%~n1 liefert den Dateinamen ohne Dateierweiterung, daran wird mit (%NumFiles%) die in Klammern eingeschlossene Laufnummer und mit %~x1 die Dateierweiterung angehängt).

Mit exit /b in Zeile 23 wird zum Hauptprogramm zurückgesprungen.
[/EDIT2]
Bitte warten ..
Mitglied: weaslflink
15.12.2011 um 18:14 Uhr
Vielen Dank für deine schnelle Antwort. Habe es auch direkt ausprobiert (als als bat mit zwei %%) jedoch ohne Erfolg.

Könntest du vielleicht zu den einzelnen Schritten kurz erklären was diese bewirken ?


Falls die Datei, nehmen wir mal "20501_55568749.pdf" schon vorhanden ist soll wie in windows diese so umbenannt werden "20501_55568749 (2).pdf"
Bitte warten ..
Mitglied: weaslflink
15.12.2011 um 18:18 Uhr
Vielen Dank Friemler,

ich werde es morgen ausprobieren und direkt resummee geben.
Bitte warten ..
Mitglied: bastla
15.12.2011 um 19:37 Uhr
Hallo weaslflink!
Habe es auch direkt ausprobiert (als als bat mit zwei %%) jedoch ohne Erfolg.
Wenn Du es nochmals (und jetzt auch mit dem inzwischen oben nachgetragenen fehlenden Anführungszeichen) versuchst, sollte es klappen ...

Zur gewünschten Erklärung:
for /f "tokens=1* delims=_" %i in
trennt die in weiterer Folge erzeugten Zeilen anhand des ersten "_", sodass in %i der Teil davor und in %j der Teil danach steht (sollten noch weitere "_" enthalten sein, bleiben diese erhalten, da wegen des "*" in "1*" keine weitere Zerlegung vorgenommen wird).
('dir /b /a-d "%userprofile%\Eigene Dateien\myscans\*_*.pdf"')
erzeugt wegen "/a-d" ein Inhaltsverzeichnis nur von Dateien, nicht auch von Ordnern, welch ev ebenfalls dem Suchmuster "*_*.pdf" entsprechen würden und gibt (wegen "/b") als einzige Information je Datei nur deren Namen + Typ aus (zur Zerlegung wie oben besprochen).
do @echo xcopy "%userprofile%\Eigene Dateien\myscans\%i_%j" "E:\%i\%i_%j*"
Da sich jetzt in %i und %j die benötigten Namensteile befinden, können diese für das Kopieren nach Wunsch zusammengesetzt werden - für die Datei "3413_13354789.pdf" wäre demnach %i=3413 und %j=13354789.pdf und daraus ergäbe sich der Befehl
@echo xcopy "%userprofile%\Eigene Dateien\myscans\3413_13354789.pdf" "E:\3413\3413_13354789.pdf*"
Die Verwendung von "xcopy" hat den Vorteil, dass bei Bedarf der Zielordner erstellt wird. Nachteilig wäre die Nachfrage
Ist das Ziel E:\3413\3413_13354789.pdf ein Dateiname 
oder ein Verzeichnisname 
(D = Datei, V = Verzeichnis)?
welche nicht mit einem Schalter analog zu "/I" (womit festgelegt wird, dass das Ziel ein Verzeichnis sein soll) verhindert werden kann - daher der Trick mit dem angefügten "*" (der könnte nicht am Ende eines Verzeichnisnamens verwendet werden, daher muss das Ziel eine Datei sein).
Was das ev erforderliche Umbenennen angeht, hat Friemler ja schon einen Vorschlag unterbreitet (wobei ich allerdings eher die bereits vorhandenen Dateien unverändert lassen und der neu zu kopierenden Datei die Laufnummer hinzufügen würde) ...

Grüße
bastla
Bitte warten ..
Mitglied: bastla
15.12.2011 um 20:02 Uhr
@Friemler
Dein Ansatz berücksichtig (noch) nicht, dass der Zielordner ev erst erstellt werden muss ...

Grüße
bastla
Bitte warten ..
Mitglied: Friemler
15.12.2011 um 21:56 Uhr
Hallo bastla,

Zitat von bastla:
Dein Ansatz berücksichtig (noch) nicht, dass der Zielordner ev erst erstellt werden muss ...

da Du dafür schon einen schönen Trick präsentiert hast (danke, wieder was gelernt ), habe ich ihn kurzerhand in mein Script eingebaut.

Btr. "Umbenennen der alten Versionen": Meine Methode hat den Vorteil, dass die aktuelle Version der Datei zu jeder Zeit den gleichen Namen hat. Somit ist es einfacher, aus anderen Scripten/Programmen darauf Bezug zu nehmen. Was letztendlich besser ist, kommt auch auf die (vom TO nicht näher erläuterten) Anforderungen an.

Gruß
Friemler
Bitte warten ..
Mitglied: bastla
15.12.2011 um 22:16 Uhr
Hallo Friemler!
Meine Methode hat den Vorteil, dass die aktuelle Version der Datei zu jeder Zeit den gleichen Namen hat.
ACK - allerdings wäre das dann genau genommen nicht mehr die "Art des Windows Explorers" ...

... aber das muss sich letztlich der TO überlegen ...

Grüße
bastla
Bitte warten ..
Mitglied: weaslflink
16.12.2011 um 08:11 Uhr
Guten Morgen.

And dieser Stelle nochmal danke für eure bemühungen.

Habe den Code nun ausprobiert. Das CMD öffnet sich, schließt sich jedoch dann direkt wieder.
Was mache ich denn falsch ? Kann ich irgendwie über das Script ein debugger modus laufen lassen ?

[Edit]
also ich habe mal das "exit /b" aus der Mitte entfernt und vor dem am ende ein "pause" gesetzt. Jetzt kommt er schon weiter aber ich poste euch mal was ich bekomme:

01.
 
02.
C:\Users\pzhqch\Documents\My Scans\test>set "SrcDir=C:\Users\pzhqch\Eigene Datei 
03.
en\myscans\test" 
04.
 
05.
C:\Users\pzhqch\Documents\My Scans\test>set "DestDir=C:\Users\pzhqch\Eigene Date 
06.
ien\myscans\test2" 
07.
 
08.
C:\Users\pzhqch\Documents\My Scans\test>set "FileType=pdf" 
09.
 
10.
C:\Users\pzhqch\Documents\My Scans\test>for /F "tokens=1* delims=_" %a in ('dir 
11.
/b /a:-d "C:\Users\pzhqch\Eigene Dateien\myscans\test\*_*.pdf" 2>NUL') do ( 
12.
call :RenOldVersion "C:\Users\pzhqch\Eigene Dateien\myscans\test2\%a\%a_%b" 
13.
 xcopy "C:\Users\pzhqch\Eigene Dateien\myscans\test\%a_%b" "C:\Users\pzhqch\Eige 
14.
ne Dateien\myscans\test2\%a\%a_%b*"   1>NUL 
15.
16.
 
17.
C:\Users\pzhqch\Documents\My Scans\test>set /a "NumFiles=0" 
18.
 
19.
C:\Users\pzhqch\Documents\My Scans\test>for /F "tokens=1 delims=:" %c in ('dir / 
20.
b /a:-d "*" 2>NUL | findstr /n "^"') do (set /a "NumFiles=%c"  ) 
21.
 
22.
C:\Users\pzhqch\Documents\My Scans\test>(set /a "NumFiles=1"  ) 
23.
 
24.
C:\Users\pzhqch\Documents\My Scans\test>(set /a "NumFiles=2"  ) 
25.
 
26.
C:\Users\pzhqch\Documents\My Scans\test>(set /a "NumFiles=3"  ) 
27.
 
28.
C:\Users\pzhqch\Documents\My Scans\test>(set /a "NumFiles=4"  ) 
29.
 
30.
C:\Users\pzhqch\Documents\My Scans\test>(set /a "NumFiles=5"  ) 
31.
 
32.
C:\Users\pzhqch\Documents\My Scans\test>(set /a "NumFiles=6"  ) 
33.
 
34.
C:\Users\pzhqch\Documents\My Scans\test>(set /a "NumFiles=7"  ) 
35.
 
36.
C:\Users\pzhqch\Documents\My Scans\test>(set /a "NumFiles=8"  ) 
37.
 
38.
C:\Users\pzhqch\Documents\My Scans\test>(set /a "NumFiles=9"  ) 
39.
 
40.
C:\Users\pzhqch\Documents\My Scans\test>(set /a "NumFiles=10"  ) 
41.
 
42.
C:\Users\pzhqch\Documents\My Scans\test>(set /a "NumFiles=11"  ) 
43.
 
44.
C:\Users\pzhqch\Documents\My Scans\test>(set /a "NumFiles=12"  ) 
45.
 
46.
C:\Users\pzhqch\Documents\My Scans\test>(set /a "NumFiles=13"  ) 
47.
 
48.
C:\Users\pzhqch\Documents\My Scans\test>(set /a "NumFiles=14"  ) 
49.
 
50.
C:\Users\pzhqch\Documents\My Scans\test>(set /a "NumFiles=15"  ) 
51.
 
52.
C:\Users\pzhqch\Documents\My Scans\test>(set /a "NumFiles=16"  ) 
53.
 
54.
C:\Users\pzhqch\Documents\My Scans\test>(set /a "NumFiles=17"  ) 
55.
 
56.
C:\Users\pzhqch\Documents\My Scans\test>(set /a "NumFiles=18"  ) 
57.
 
58.
C:\Users\pzhqch\Documents\My Scans\test>(set /a "NumFiles=19"  ) 
59.
 
60.
C:\Users\pzhqch\Documents\My Scans\test>if 19 GTR 0 ren "" "(19)" 
61.
Das System kann die angegebene Datei nicht finden. 
62.
 
63.
C:\Users\pzhqch\Documents\My Scans\test>pause 
64.
Drücken Sie eine beliebige Taste . . . 
65.
 
Nach drücken der Taste schließt sich das fenster.

Habe die Batch datei im Ordner "test" und dort sind 18 pdf files drin zum testen der batch

Ich hoffe euch hilft das weiter
Bitte warten ..
Mitglied: bastla
16.12.2011 um 08:45 Uhr
Hallo weaslflink!

Wenn ich
C:\Users\pzhqch\Documents\My Scans\test>set "SrcDir=C:\Users\pzhqch\Eigene Dateien\myscans\test"
betrachte (was mir mit der passenden Formatierung leichter fällt ), bin ich mir nicht so ganz sicher, dass der Quellpfad
C:\Users\pzhqch\Eigene Dateien\myscans\test
lauten sollte ...

Grüße
bastla
Bitte warten ..
Mitglied: weaslflink
16.12.2011 um 09:21 Uhr
ah das war der kleine Übeltäter

habe es gemacht mit:
01.
%userprofile%\Documents\My Scans\test
und siehe da es funktioniert

Jetzt habe ich aber noch eine Frage. Abe erst mal zu dem Hintergrund. Ich scanne momentan Dokumente so ca 50-70 Stk am Tag und vergebe denen eine Namen wie oben schon erwähnt. Jetzt kommt es auch oft vor das diese doppelt sind. D.h das ich im Scan-Ordner schon dateien habe mit Namen
3376_55582593(2)
3376_55582593(3)
....

wenn ich diese mit hilfe des tools kopiere dann wird aus
3376_55582593(2)
3376_55582593(2)(1)

Ist es machbar das die datei nicht in ...(2)(1) umbenannt wird sondern in ...(3) wenn diese jedoch auch schon vergeben ist dann ind ...(4) usw. Ich hoffe Ihr habt verstanden was ich meine. So wirdh nämlich später von dem Projekt jeweils das aktuellste mit der höchsten Zahl angezeigt.


Wenn ich das jetzt richtig verstanden habe dann müsste das doch so klappen, dass im Hauptordner Dateien die ein "([Zahl]).pdf" am Ende haben diese vor dem kopieren entfernt und dann erst in den Ziel kopiert wird.
Würde das so gehen ?


Ich danke für eure Hilfe
Bitte warten ..
Mitglied: bastla
17.12.2011 um 00:03 Uhr
Hallo weaslflink!

Wenn sicher gestellt ist, dass nur der Dateiname vor einer ev ersten Klammer benötigt wird, dann (weitgehend ungetestet) etwa so:
01.
@echo off & setlocal 
02.
set "SrcDir=%userprofile%\Documents\My Scans\test" 
03.
set "DestDir=%userprofile%\Documents\My Scans\test2" 
04.
set "FileType=pdf" 
05.
 
06.
for /f "tokens=1* delims=_" %%a in ('dir /b /a-d "%SrcDir%\*_*.%FileType%" 2^>NUL') do ( 
07.
  for /f "delims=(" %%i in ("%%~nb") do call :Kopieren "%SrcDir%\%%a_%%b" "%%a" "%%i" "%%~xb" 
08.
09.
exit /b 
10.
 
11.
:Kopieren 
12.
set /a "NumFiles=0" 
13.
for /f "tokens=1 delims=:" %%c in ('dir /b /a-d "%DestDir%\%~2\%~2_%~3*%~4" 2^>NUL ^| findstr /n "^"') do set /a "NumFiles=%%c" 
14.
set /a NumFiles+=1 
15.
if %NumFiles% gtr 1 ( 
16.
    xcopy %1 "%DestDir%\%~2\%~2_%~3(%NumFiles%)%~4*" 
17.
) else ( 
18.
    xcopy %1 "%DestDir%\%~2\%~2_%~3%~4*" 
19.
20.
exit /b
Eine Alternative zu den Zeilen 12 und 13 könnte übrigens so aussehen:
for /f %%c in ('dir /b /a-d "%DestDir%\%~2\%~2_%~3*%~4" 2^>NUL ^|find /c /v "?"') do set /a "NumFiles=%%c"
Grüße
bastla
Bitte warten ..
Mitglied: Biber
31.12.2011 um 16:20 Uhr
Moin weaslflink,

Zitat von weaslflink:
Ich danke für eure Hilfe
Wärest du bereit, diesen Dank für die weniger lesefähigen in diesem Forum zu visualisieren, vorzugsweise in diesem dezenten Wacholderton?
Brennesselfarben ginge zur Not auch....

Grüße
Biber
Bitte warten ..
Mitglied: weaslflink
02.01.2012 um 07:32 Uhr
[image]http://www.tippy.de/ecards/motive/danke.jpg[/image]

Hiermit bedanke ich mich herzlich für die großartige Unterstützung die ich von allen erhalten habe !
Bitte warten ..
Neuester Wissensbeitrag
Humor (lol)

Linkliste für Adventskalender

(3)

Information von nikoatit zum Thema Humor (lol) ...

Ähnliche Inhalte
C und C++
Dateien in Ordner kopieren anhand vom Teil eines Dateinamen (22)

Frage von onlyforu8373 zum Thema C und C ...

Batch & Shell
gelöst Ordner anhand von Dateinamen erstellen und Dateien in Ordner kopieren (3)

Frage von getmoving zum Thema Batch & Shell ...

Windows Tools
gelöst Tool um neue Dateien aus Ordner A EINMAL in Ordner B zu kopieren (6)

Frage von Archimedes zum Thema Windows Tools ...

Heiß diskutierte Inhalte
Windows Server
DHCP Server switchen (25)

Frage von M.Marz zum Thema Windows Server ...

SAN, NAS, DAS
gelöst HP-Proliant Microserver Betriebssystem (14)

Frage von Yannosch zum Thema SAN, NAS, DAS ...

Grafikkarten & Monitore
Win 10 Grafikkarte Crash von Software? (13)

Frage von Marabunta zum Thema Grafikkarten & Monitore ...

Windows 7
Verteillösung für IT-Raum benötigt (12)

Frage von TheM-Man zum Thema Windows 7 ...