Top-Themen

AppleEntwicklungHardwareInternetLinuxMicrosoftMultimediaNetzwerkeOff TopicSicherheitSonstige SystemeVirtualisierungWeiterbildungZusammenarbeit

Aktuelle Themen

Administrator.de FeedbackApache ServerAppleAssemblerAudioAusbildungAuslandBackupBasicBatch & ShellBenchmarksBibliotheken & ToolkitsBlogsCloud-DiensteClusterCMSCPU, RAM, MainboardsCSSC und C++DatenbankenDatenschutzDebianDigitiales FernsehenDNSDrucker und ScannerDSL, VDSLE-BooksE-BusinessE-MailEntwicklungErkennung und -AbwehrExchange ServerFestplatten, SSD, RaidFirewallFlatratesGoogle AndroidGrafikGrafikkarten & MonitoreGroupwareHardwareHosting & HousingHTMLHumor (lol)Hyper-VIconsIDE & EditorenInformationsdiensteInstallationInstant MessagingInternetInternet DomäneniOSISDN & AnaloganschlüsseiTunesJavaJavaScriptKiXtartKVMLAN, WAN, WirelessLinuxLinux DesktopLinux NetzwerkLinux ToolsLinux UserverwaltungLizenzierungMac OS XMicrosoftMicrosoft OfficeMikroTik RouterOSMonitoringMultimediaMultimedia & ZubehörNetzwerkeNetzwerkgrundlagenNetzwerkmanagementNetzwerkprotokolleNotebook & ZubehörNovell NetwareOff TopicOpenOffice, LibreOfficeOutlook & MailPapierkorbPascal und DelphiPeripheriegerätePerlPHPPythonRechtliche FragenRedHat, CentOS, FedoraRouter & RoutingSambaSAN, NAS, DASSchriftartenSchulung & TrainingSEOServerServer-HardwareSicherheitSicherheits-ToolsSicherheitsgrundlagenSolarisSonstige SystemeSoziale NetzwerkeSpeicherkartenStudentenjobs & PraktikumSuche ProjektpartnerSuseSwitche und HubsTipps & TricksTK-Netze & GeräteUbuntuUMTS, EDGE & GPRSUtilitiesVB for ApplicationsVerschlüsselung & ZertifikateVideo & StreamingViren und TrojanerVirtualisierungVisual StudioVmwareVoice over IPWebbrowserWebentwicklungWeiterbildungWindows 7Windows 8Windows 10Windows InstallationWindows MobileWindows NetzwerkWindows ServerWindows SystemdateienWindows ToolsWindows UpdateWindows UserverwaltungWindows VistaWindows XPXenserverXMLZusammenarbeit
GELÖST

Dateierweiterungen umbenennen

Frage Entwicklung Batch & Shell

Mitglied: combat

combat (Level 1) - Jetzt verbinden

19.04.2008, aktualisiert 21:18 Uhr, 5708 Aufrufe, 4 Kommentare

Hallo Community,

zu meinem letzten Beitrag konntet Ihr mir schon sehr gut weiterhelfen aber in meiner Bilddatenbank habe ich immer noch einige Schwierigkeiten, die eure Hilfe wesentlich leichter lösbar wäre.
Folgendes Problem habe ich noch:

Die Bilddatenbank ist in zwei Bereichen aufgeteilt. Es gibt einmal Vorschaubilder und einmal Originalbilder. Diese Bilder sind in unterschiedliche Verzeichnisse abgelegt, wobei der Bildname des Vorschaubildes und des Originalbildes gleich sind. Nur die Dateierweiterung des Originalbildes kann unterschiedlich sein (z.B. .pcd, .tif, .jpg)

Die Vorschaubilder liegen im Verzeichnis:

\\server1\D:\Previews\mbarchiv\2002\02010100001\DIR001\bildnr_xy1.jpg
\\server1\D:\Previews\mbarchiv\2002\02010100001\DIR001\bildnr_xy2.jpg
...
\\server1\D:\Previews\mbarchiv\2002\02011200001\DIR001\bildnr_xy100.jpg
\\server1\D:\Previews\mbarchiv\2002\02011200001\DIR001\bildnr_xy1101.jpg
...
Info:
\\server1\D:\Previews\mbarchiv\2002\ das Verzeichnis bis 2002 ändert sich nicht, nur danach sind Verzeichnisse (von der Anzahl aber wie oben beschrieben) vorhanden die ich nicht kenne.

Die Originalbilder liegen im Verzeichnis:

\\netapp\raid\2002\020100001\images\DIR001\bildnr_xy1.pcd
\\netapp\raid\2002\020100001\images\DIR001\bildnr_xy2.pcd
...
\\netapp\raid\2002\021200001\images\DIR001\bildnr_xy100.tif
\\netapp\raid\2002\021200001\images\DIR001\bildnr_xy1.jpg
...
Info:
\\netapp\raid\2002\
Das Verzeichnis bis hier ändert sich nicht

Das Verzeichnis danach 020100001 (Datum und Anzahl) ist bei Vorschaubild und Originalbild auch immer gleich. Ist dieses Vezeichnis im Vorschaubereich ein anderes (021200001) muss es im Originalbereich dann auch 021200001 heißen.

Da ich jetzt wissen möchte ob zu jedem Vorschaubild ein Originalbild mit dem gleichen Dateinamen existiert (wobei die Dateierweiterung unterschiedlich sein kann) habe ich mit Totalcommander (Verzeichnisse synchronisieren..) die Dateien verglichen.
Da die Dateierweiterung in den Originalbilder unterschiedlich sind, zeigt jetzt Totalcommander das die Bilder (Vorschaubild zu Originalbild) unterschiedlich sind, obwohl nur die Erweiterung anders ist. Bei ein paar hundert Bildern könnte man noch erkennen, dass die Bilder bis auf die Dateierweiterung gleich sind, aber bei 500.000 Bildern ist das einfach nicht mehr möglich.

Ich möchte jetzt mit einer Batch die Erweiterung in den Originalbildern auslesen und die Vorschaubilder mit der Dateierweiterung umbenennen.

Mit einer for-Schleife und findstr habe ich schon etwas versucht aber richtig weiter gekommen bin ich nicht.
for /r \\server1\D:\Previews\s %%i in ("*.*") do @echo %%i > d:\verzeichnis.txt

findstr /b \\server1\D:\Previews d:\verzeichnis.txt

Könnt Ihr mir vielleicht weiterhelfen?

Gruß combat
Mitglied: bastla
19.04.2008 um 18:25 Uhr
Hallo combat!

Ich möchte jetzt mit einer Batch die Erweiterung in den Originalbildern auslesen und die Vorschaubilder mit der Dateierweiterung umbenennen.
Ganz klar ist mir nicht, wie das gemeint ist (denn aus einem "bildnr_xy1.jpg" ein "bildnr_xy1.tiff" machen zu wollen hast Du doch sicher nicht vor), aber als Vorarbeit könntest Du die entsprechenden Originalbilder einmal auflisten.

Aufgrund der großen Menge an Bildern würde ich folgende Vorgangsweise vorschlagen: Erzeugen je einer Liste der Originale und der Vorschaubilder mit relativen Pfaden - für die Vorschaubilder kann, da es sich ohnehin durchwegs um ".jpg"-Dateien handelt, auch der Typ weggelassen werden (macht die Auswertung später einfacher) und als dritten Schritt Abgleichen der beiden Listen.

Originalliste erzeugen:
01.
@echo off & setlocal 
02.
set "Liste=D:\Originale.txt" 
03.
If exist "%Liste%" del "%Liste%" 
04.
for /f %%i in ('dir /b /s /a-d \\netapp\raid\2002\*.*') do call :ProcessFile "%%i" 
05.
goto :eof 
06.
 
07.
:ProcessFile 
08.
set "Datei=%~1" 
09.
echo %Datei:\\netapp\raid\2002\=%>>"%Liste%" 
10.
goto :eof
Vorschauliste erzeugen (ich schreibe den Pfad so, wie von Dir angegeben, also inkl "D:"):
01.
@echo off & setlocal 
02.
set "Liste=D:\Vorschau.txt" 
03.
If exist "%Liste%" del "%Liste%" 
04.
for /f %%i in ('dir /b /s /a-d \\server1\D:\Previews\mbarchiv\2002\*.*') do call :ProcessFile "%%i" 
05.
goto :eof 
06.
 
07.
:ProcessFile 
08.
set "Datei=%~dpn1" 
09.
echo %Datei:\\server1\D:\Previews\mbarchiv\2002\=%>>"%Liste%" 
10.
goto :eof
Auswertung:
01.
@echo off & setlocal 
02.
set "OListe=D:\Originale.txt" 
03.
set "VListe=D:\Vorschau.txt" 
04.
set "DListe=D:\Differenzen.txt" 
05.
set "FListe=D:\Fehlende.txt" 
06.
 
07.
if exist "%DListe%" del "%DListe%" 
08.
if exist "%FListe%" del "%FListe%" 
09.
for /f "usebackq delims=" %%i in ("%VListe%") do findstr /b /c:"%%i.jpg" "%OListe%">nul || call :ProcessFile "%%i" 
10.
goto :eof 
11.
 
12.
:ProcessFile 
13.
set Original= 
14.
for /f "delims=" %%a in ('findstr /b /c:%1 "%OListe%"') do set "Original=%%a" 
15.
if not defined Original (echo %~1.jpg)>>"%FListe%" & goto :eof 
16.
(echo %Original%)>>"%DListe%" 
17.
goto :eof
Kurz zu den beiden Ergebnisdateien: "Differenzen.txt" enthält eine Liste aller Originaldateien, welche nicht den Typ ".jpg" haben, zu denen es aber gleichnamige Vorschaubilder gibt, und "Fehlende.txt" listet alle Vorschaudateien auf, zu denen keine gleichnamigen (Erweiterung egal) Originale gefunden wurden.

Nicht aufgelistet werden Originale, zu denen es keine Vorschau gibt.

Grüße
bastla
Bitte warten ..
Mitglied: combat
19.04.2008 um 20:06 Uhr
Hallo bastla,

danke dass Du mir wieder hilfst.

Dass ich die Dateierweiterung von den Vorschaubildern ändern möchte ist schon beabsichtigt. Zuvor mache ich mir aber eine Kopie von den ganzen Vorschaubildern. Bei den Kopierten werde ich die Änderung der Dateierweiterung vornehmen und damit den Vergleich mit den Originalbildern vornehmen. Beim Vergleich (mit Totalcommander) schau ich nur zu welchem Vorschaubild es kein Originalbild gibt und andersrum. Damit dies funktioniert müssen die Dateierweiterungen leider gleich sein. Nach dem Suchen und Finden der fehlenden Bildern werden die Veränderten Vorschaubildern wieder gelöscht.

Die Skripte von Dir sind aber auch sehr gut. Mit der Liste "Fehlende.txt" kann ich dann auch nach den verlorenen Dateien suchen gehen.
Bin mir nur noch nicht sicher wie übersichtlich es bei ein paar tausend fehlenden Bildern es sein wird. Ich weiß nur das es insgesamt ca. 455000 Vorschaubilder und nur ca. "447000" Originalbilder sind. Wobei es aber auch vorkommen kann das zu Originalbilder manchmal keine Vorschaubilder gibt.

Kann man vielleicht nicht doch die Dateierweiterung ändern, damit man den Vergleich mit Totalcommander durchführen kann? Die Übersicht kommt mir ein bißchen einfache vor. Aber nur wenn es nicht zu komplex wird.

Danke für die Hilfe!

Gruß combat
Bitte warten ..
Mitglied: bastla
19.04.2008 um 20:38 Uhr
Hallo combat!

Zum Thema Umbenennen: Sobald die Liste "Differenzen.txt" erstellt ist, kann diese als Basis für eine derartige Aktion dienen - allerdings frage ich mich, was Du dann als nächstes vorhast ...

Anyhow - hier das Umbenennen:
01.
@echo off & setlocal 
02.
set "Liste=D:\Differenzen.txt" 
03.
set "Pfad=\\server1\D:\Previews\mbarchiv\2002" 
04.
 
05.
pushd \ 
06.
for /f "usebackq delims=" %%i in ("%Liste%") do ren "%Pfad%%%~pni.jpg" *%%~xi 
07.
popd
Originaldateien ohne zugehörige Vorschaubilder lassen sich aber natürlich auch noch herausfiltern:
01.
@echo off & setlocal 
02.
set "OListe=D:\Originale.txt" 
03.
set "VListe=D:\Vorschau.txt" 
04.
set "FListe=D:\FehlendeVorschaubilder.txt" 
05.
 
06.
if exist "%FListe%" del "%FListe%" 
07.
pushd \ 
08.
for /f "usebackq delims=" %%i in ("%OListe%") do call :ProcessFile "%%~pni" 
09.
popd 
10.
goto :eof 
11.
 
12.
:ProcessFile 
13.
set "Datei=%~1" 
14.
set "Datei=%Datei:~1%" 
15.
findstr /b /c:"%Datei%" "%VListe%">nul || (echo %Datei%)>>"%FListe%" 
16.
goto :eof
Grüße
bastla
Bitte warten ..
Mitglied: combat
19.04.2008 um 21:18 Uhr
Hallo bastla,

Genau so habe ich mir das vorgestellt Dankeschön!!!

Zur Erklärung warum die Dateierweiterung gleich sein sollten:

Wenn das Vorschaubild so aussehen würde

\\server1\D:\Previews\mbarchiv\2002\02010100001\DIR001\bildnr_xy1.jpg
und das Original so
\\netapp\raid\2002\02010100001\images\DIR001\bildnr_xy1.pcd

dann wären die Bilder in der Datenbank richtig angelegt. Der Vergleich mit "Total Commander" würde aber sagen das es zu diesem Vorschaubild kein Originalbild existiert und zu dem Originalbild kein Vorschaubild, und das nur weil das Vorschaubild die Erweiterung "jpg" hat und nicht "pcd".

Nach dem Ändern der Erweiterung

\\server1\D:\Previews\mbarchiv\2002\02010100001\DIR001\bildnr_xy1.pcd

\\netapp\raid\2002\02010100001\images\DIR001\bildnr_xy1.pcd

sieht der Total Commander die Dateien als gleich und zeigt mir dann nur noch die Fehlenden Dateien an.

Deine Skripte sind echt super. Sie werden mir den Vergleich der Bilddateien erheblich erleichtern.

Vielen dank nochmal

Gruß combat
Bitte warten ..
Neuester Wissensbeitrag
Windows 10

Powershell 5 BSOD

(1)

Tipp von agowa338 zum Thema Windows 10 ...

Ähnliche Inhalte
Batch & Shell
gelöst Dateiname entsprechend einem um x-Ebenen übergeordeten Ordnernamen umbenennen (3)

Frage von Booster07 zum Thema Batch & Shell ...

Batch & Shell
Pdf Files umbenennen (7)

Frage von Sacred zum Thema Batch & Shell ...

Windows Server
gelöst WSUS SUSDB umbenennen (6)

Frage von vessev zum Thema Windows Server ...

Heiß diskutierte Inhalte
Windows Userverwaltung
Ausgeschiedene Mitarbeiter im Unternehmen - was tun mit den AD Konten? (34)

Frage von patz223 zum Thema Windows Userverwaltung ...

LAN, WAN, Wireless
gelöst Server erkennt Client nicht wenn er ausserhalb des DHCP Pools liegt (28)

Frage von Mar-west zum Thema LAN, WAN, Wireless ...

Windows Server
Server 2008R2 startet nicht mehr (Bad Patch 0xa) (18)

Frage von Haures zum Thema Windows Server ...