Daten aus csv-Datei weiter verwenden

Hallo!

Ich möchte gern per vb-script aus einer csv-Datei Daten auslesen und dann per script z.B. Drucker installieren.
Nun bin ich wie schon oft gesagt Anfänger auf diesem Gebiet. Ich habe schon Daten aus dieser csv-Datei ausgelesen, aber nun möchte ich diese weiter verwenden. Kann mir da bitte jemand helfen!

hier mein script vom auslesen:

Option Explicit
' Konstanten definieren
Const ForReading = 1
' Variablen deklarieren
Dim FSO, Datei, objPrinter, strComputer, objWMIService, print
Dim TextZeile
'Objekt erzeugen
Set FSO=CreateObject("Scripting.FileSystemObject")
'Öffnen der Datei zum Lesen
Set Datei = FSO.OpenTextFile("csvdaten.csv", ForReading, False)
'Datei bis zum Ende durchlaufen
while not Datei.AtEndOfStream
'Lesen einer Zeile
TextZeile=Datei.Readline()
'Zeile an Semikolon trennen und die Werte
'in einem Array speichern
objPrinter=Split(TextZeile,";")
'Ausgabe der Benutzerdaten
wscript.echo objPrinter(0) & ";" & objPrinter(1) & ";" & objPrinter(2) & ";" & objPrinter(3) & ";" & objPrinter(4) & ";" & objPrinter(5) & ";" & objPrinter(6)

Und hier wäre das Skript zum erstellen eines einzelnen Druckers:

strComputer = "."
Set objWMIService = GetObject("winmgmts:" _
& "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")

Set objPrinter = objWMIService.Get("Win32_Printer").SpawnInstance_

objPrinter.DriverName = "Apollo P2200"
objPrinter.PortName = "Lpt1:"
objPrinter.DeviceID = "PR1Kat1B1"
objPrinter.Location = "USA/Redmond/Building 37/Room 114"
objPrinter.Network = False
objPrinter.Shared = True
objPrinter.ShareName = "PR1Kat1B1"
objPrinter.Put_

--> Wie kann ich diese beiden irgendwie zusammen fügen???

Option Explicit
' Konstanten definieren  
Const ForReading = 1
' Variablen deklarieren  
Dim FSO, Datei, objPrinter, strComputer, objWMIService, strPrinter
Dim TextZeile

strComputer = "."  
Set objWMIService = GetObject("winmgmts:" _  
& "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")  

'Objekt erzeugen  
Set FSO=CreateObject("Scripting.FileSystemObject")  
'Öffnen der Datei zum Lesen  
Set Datei = FSO.OpenTextFile("csvdaten.csv", ForReading, False)  
'Datei bis zum Ende durchlaufen  
Do While Not Datei.AtEndOfStream
	'Lesen einer Zeile  
	TextZeile = Datei.Readline()
	'Zeile an Semikolon trennen und die Werte  
	'in einem Array speichern  
	strPrinter = Split(TextZeile,";")  
	'Drucker erstellen  
	Set objPrinter = objWMIService.Get("Win32_Printer").SpawnInstance_  
	objPrinter.DriverName = strPrinter(0)
	objPrinter.PortName = strPrinter(1)
	objPrinter.DeviceID = strPrinter(2)
	objPrinter.Location = strPrinter(3)
	objPrinter.Network = strPrinter(4)
	objPrinter.Shared = strPrinter(5)
	objPrinter.ShareName = strPrinter(6)
	objPrinter.Put_
Loop
Datei.Close