ExitCode eines .VBS nicht richtig wenn ich es aus einem Batch aufrufe ...

Option Explicit
Dim exitcode
exitcode=1
' Check argument count  
If WScript.Arguments.Count < 2 Then
	MsgBox "Missing Arguments !" & VbCrLf & VbCrLf & Wscript.ScriptName & " VendorID DeviceID" & VbCrLf & VbCrLf & Wscript.ScriptName & " 8086 2592", 16, "Error"  
	exitcode=2
	Wscript.Quit(exitcode)
End If
' Check argument lenght  
If not Len(Wscript.Arguments(0))=4 Then 
	MsgBox " VendorID must be 4 digits !!! ", 16, "Error"	  
	exitcode=2
	Wscript.Quit(exitcode)
End If
If not Len(Wscript.Arguments(1))=4 Then 
	MsgBox " DeviceID must be 4 digits !!! ", 16, "Error"  
	exitcode=2
	Wscript.Quit(exitcode)
End If

Dim buses,bus,device,devices,strVendor2Search,strDevice2Search
Set buses = GetObject("winmgmts:").InstancesOf("Win32_Bus")  
strVendor2Search = "VEN_" & Wscript.Arguments(0)  
strDevice2Search = "DEV_" & Wscript.Arguments(1)  
For Each bus In buses
    Set devices = GetObject("winmgmts:").ExecQuery ("Associators of {Win32_Bus.DeviceID=""" & bus.DeviceID & """} WHERE AssocClass = Win32_DeviceBus")  
    For Each device In devices
		If InStr(UCase(device.PnPDeviceID),strVendor2Search) Then
			If InStr(UCase(device.PnPDeviceID),strDevice2Search) Then
				WScript.Echo "  ", device.name  
				WScript.Echo vbTab, device.PnPDeviceID
				WScript.Echo " "  
				exitcode=0
			End IF
		End IF
    Next
Next 
Wscript.Quit(exitcode)