sinixnd
Goto Top

Den größten mehrerer Werte herausfinden - Batch

Hi Leute ;)

nach ewigen Zeiten habe ich mal wieder eine Frage an meine Meister des Batch =)

Gibt es eine Möglichkeit in Batch, aus mehreren Werten den kleinsten Wert herauszufinden? und das Ergebnis dann in eine Variable zu speichern? Evtl mit for?
Erklärung folgt auf dem Fuße:

If %W002% GTR %W001% (
set CNT=01
goto :OK)

If %W003% GTR %W002% (
set CNT=02
goto :OK)

If %W004% GTR %W003% (
set CNT=03
goto :OK)

etc.

Grundsätzlich sei gesagt, das das Batch funktioniert!! Ich denke auch nicht, dass ich jemals mit dieser Version Probleme haben werde. Aber ich hab immer gern alles möglichkeiten abgedeckt.

Das Ziel des obigen Scripts (welches nur ein Auszug ist, im ersten Kommentar poste ich das gesamte Script - der Auszug steht dann für die Zeilen 108-149) soll sein, unter den verschiedenen %W00X%-Variablen den größten Wert herauszufinden.

Das Problem, das ich mit der oberigen Version sehe ist, dass wenn z.B. W002 größer ist als W003, dann bricht das File die suche nach dem kleinsten Wert zu früh ab.

Hintergrund ist folgender (ich muss dazu leider ein klein wenig ausholen):
  • Es geht um ein Spiel.
  • Die relevanten Faktoren in dem Spiel sind
    • dein Konto (z.B. ein Guthaben von 1000 Goldmünzen), und
    • kaufbare Gebäude. Gebäude bringen ein stündliches Income. z.B. Gebäude 1 kostet 100 Goldmünzen und bringt ein Income von 1 Goldmünze pro Stunde.
  • Man kann ein Gebäude mehrmals kaufen, jedoch kostet es mit jedem Kauf 1/10 vom Startpreis mehr, also 1=100g, 2=110g, 3=120g usw.
  • Mit steigendem Level stehen mehr Gebäude zur Verfügung, die jedoch im Verhältnis mehr kosten als sie bringen (z.B. Gebäude 2 kostet 210g und bringt "nur" 2 Goldmünzen)

Sinn des gesamten Batch-Files ist nun, aus der Wertigkeit der Gebäude (also Ertrag im Verhältnis zu den Kosten) das "effektivste" Gebäude herauszufinden und dann bei einem bestimmten Kontostand auszurechnen, wie viele Gebäude ich von welchem Typ kaufen kann bis mein Gold nicht mehr für das effektivste Gebäude reicht.
Ich hoffe dass es soweit verständlich ist. Wie schon gesagt poste ich das gesamte Script für Interessierte im ersten Kommentar. ;)

Der obige Auszug enthält nun den Bereich, der für das Vergleichen der Effektivität/Wertigkeit (daher auch %W00X%) zuständig ist. (Allerdings nur für 4 Gebäude, es sind in in meinem jetztigen File 11 Gebäude, siehe erster Kommentar)

Mein Problem ist nun: Ich bin mir nicht sicher, ob das in allen Fällen so funktioniert. (also undabhängig davon, wie viele Gebäude ich von der jeweiligen Nummer schon habe.)

Gibt es eine Möglichkeit in Batch, aus mehreren Werten den kleinsten Wert herauszufinden? und das Ergebnis dann in eine Variable zu speichern? Evtl mit for?

Falls weitere Fragen auftauchen, nur zu =)
Ich hoffe ich habe nichts vergessen.. und vielen Dank schon mal für jeden, der sich in diese (vielleicht ein bisschen komplizierte) Spielerei eindenkt ;)

Fame.Styler

PS.: Noch eine kurze Erklärung zu den Variablen:
  • %G% ist das Gold das ich auf dem Konto habe
  • %C00X% ist der Counter des jeweiligen Gebäudetyps, also die Anzahl die ich davon bereits besitze
  • %B00X% ist der Basispreis der Gebäude (also wenn ich keines besitzten würde)
  • %K00X% sind die Kosten des nächst höheren Gebäudes, berechnet aus Counter und Basis ;)
  • %I00X% ist das stündliche Income, das mir das Gebäude bringt
  • %W00X% ist die Effektivität/Wertigkeit des Gebäudes, berechnet aus Kosten und Income
*Upkeep kann igroniert werden ;) Wen's doch interessiert, kann ja fragen.

PPS.: Ich speichere meine Gebäudezahl in einer MonsterWarlordGebaude.txt (Name des Spiels) als zahlenreihe aka 10.5.3.1 (<- 10 vom ersten, 5 vom zweiten etc.), sodass ich sie der Einfachheit halber in der Batch auslesen kann, falls ich nichts gekauft habe, ohne es in der Batch vorher berechnet zu haben.

PPPS.: Da ich mit der Batch oft Berechnungen teste, habe ich am Schluss die Frage nach dem Test (in dem fall wird nichts in dem Textfile verändert) und nach einem erneuten Starten der Batch gehängt ;)

Content-Key: 224655

Url: https://administrator.de/contentid/224655

Ausgedruckt am: 29.03.2024 um 15:03 Uhr

Mitglied: SinixND
SinixND 16.12.2013 um 20:36:29 Uhr
Goto Top
@echo off & setlocal enabledelayedexpansion
:0
cls

{{comment_single_line_remark:0}}
set /p G= Kontostand: 
set G0=%G%
echo. 

::GebaudeZahlerAutomatisch
for /f "tokens=1-11 delims=. " %%a in (MonsterWarlordGebaude.txt) do (  
set C001=%%a
set C002=%%b
set C003=%%c
set C004=%%d
set C005=%%e
set C006=%%f
set C007=%%g
set C008=%%h
set C009=%%i
set C010=%%j
set C011=%%k
)
echo Check for: %C001%.%C002%.%C003%.%C004%.%C005%.%C006%.%C007%.%C008%.%C009%.%C010%.%C011%

::AutoamtischOderManuell
set /p CHOICE= Automatische Gebaudeberechnung: [Y]es or [N]o:
if %CHOICE%==y goto BasisKosten
if %CHOICE%==Y goto BasisKosten

::GebaudeZahlerManuell
set /p C001= Anzahl Farmen (1): 
set /p C002= Anzahl Gehege (2): 
set /p C003= Anzahl Lagerraume (3): 
set /p C004= Anzahl Hutten (4): 
set /p C005= Anzahl Wasserrader (5): 
set /p C006= Anzahl Sagewerke (6): 
set /p C007= Anzahl Schmieden (7): 
set /p C008= Anzahl Backereien (8): 
set /p C009= Anzahl Markte (9): 
set /p C010= Anzahl Restaurants (10): 
set /p C011= Anzahl Windmuehlen (11): 

::BasisKosten
:BasisKosten
set B001=40
set B002=200
set B003=400
set B004=2000
set B005=5000
set B006=11000
set B007=40000
set B008=100000
set B009=200000
set B010=400000
set B011=750000

::GebaudeKosten

set /A K001=%B001%+(%C001%*(%B001%/10))
set /A K002=%B002%+(%C002%*(%B002%/10))
set /A K003=%B003%+(%C003%*(%B003%/10))
set /A K004=%B004%+(%C004%*(%B004%/10))
set /A K005=%B005%+(%C005%*(%B005%/10))
set /A K006=%B006%+(%C006%*(%B006%/10))
set /A K007=%B007%+(%C007%*(%B007%/10))
set /A K008=%B008%+(%C008%*(%B008%/10))
set /A K009=%B009%+(%C009%*(%B009%/10))
set /A K010=%B010%+(%C010%*(%B010%/10))
set /A K011=%B011%+(%C011%*(%B011%/10))

::GebaudeEinkommen

set I001=1
set I002=5
set I003=10
set I004=50
set I005=100
set I006=160
set I007=500
set I008=1000
set I009=1600
set I010=2500
set I011=3000

::GebaudeEffektivitat

set /A W001=%K001%/%I001%
set /A W002=%K002%/%I002%
set /A W003=%K003%/%I003%
set /A W004=%K004%/%I004%
set /A W005=%K005%/%I005%
set /A W006=%K006%/%I006%
set /A W007=%K007%/%I007%
set /A W008=%K008%/%I008%
set /A W009=%K009%/%I009%
set /A W010=%K010%/%I010%
set /A W011=%K011%/%I011%

::Ausgaben
echo.
set /p Upkeep= Upkeep: 

::Einkommen(Income)
set /A Income0=(%C001%*%I001%)+(%C002%*%I002%)+(%C003%*%I003%)+(%C004%*%I004%)+(%C005%*%I005%)+(%C006%*%I006%)+(%C007%*%I007%)+(%C008%*%I008%)+(%C009%*%I009%)+(%C010%*%I010%)+(%C011%*%I011%)-%Upkeep%

::===========
:Calc
If %W002% GTR %W001% (
set CNT=01
goto :OK)

If %W003% GTR %W002% (
set CNT=02
goto :OK)

If %W004% GTR %W003% (
set CNT=03
goto :OK)

If %W005% GTR %W004% (
set CNT=04
goto :OK)

If %W006% GTR %W005% (
set CNT=05
goto :OK)

If %W007% GTR %W006% (
set CNT=06
goto :OK)

If %W008% GTR %W007% (
set CNT=07
goto :OK)

If %W009% GTR %W008% (
set CNT=08
goto :OK)

If %W010% GTR %W009% (
set CNT=09
goto :OK)

If %W011% GTR %W010% (
set CNT=10
goto :OK)

set CNT=11

:OK
If !K0%CNT%! GEQ %G% goto :Anzeige

::NeuerKontostand
set /A G=%G%-!K0%CNT%!

::NeueGebaudeanzahl
set /A C0%CNT%=!C0%CNT%!+1

::NeueGebaudekosten
set /A K0%CNT%=!K0%CNT%!+(!B0%CNT%!/10)

::NeueGebaudeeffektivitat
set /A W0%CNT%=!K0%CNT%!/!I0%CNT%!

::Neueseinkommen
set /A Income=((%C001%*%I001%)+(%C002%*%I002%)+(%C003%*%I003%)+(%C004%*%I004%)+(%C005%*%I005%)+(%C006%*%I006%)+(%C007%*%I007%)+(%C008%*%I008%)+(%C009%*%I009%)+(%C010%*%I010%)+(%C011%*%I011%))-%Upkeep%

goto :Calc

:Anzeige
cls
echo ============================================================
echo.
echo Kontostand ist am Anfang: %G0%G 
echo Kontostand ist am Ende: %G%G  
echo. 
echo Income (Anfang): %Income0% 
echo Income (Ende): %Income% 
echo Upkeep (Momentan): %Upkeep% 
echo. 
echo Gebaudebesitz (Ende): 
echo Farm:%C001% - Gehege:%C002% - Lagerraum:%C003% -Hutte:%C004%  
echo Wasserrad:%C005% - Sagewerk:%C006% - Schmiede:%C007% - Backerei:%C008%  
echo Markt:%C009% - Restaurant:%C010% - Windmuehle:%C011% 

echo.
echo ============================================================
echo.

set /P TEST= Was this a test? - [Y]es or [N]o: 
if %TEST%==Y goto jump
if %TEST%==y goto jump
echo %C001%.%C002%.%C003%.%C004%.%C005%.%C006%.%C007%.%C008%.%C009%.%C010%.%C011% > MonsterWarlordGebaude.txt
:jump

echo.

set /p Res= Restart?         - [Y]es or [N]o: 
if %Res%==Y goto :0
If %Res%==y goto :0
:eof
Mitglied: bastla
Lösung bastla 16.12.2013 aktualisiert um 23:25:12 Uhr
Goto Top
Hallo fame.styler!

Schematisch könnte das (wenn alle mit "W0" beginnenden Variablen ausgewertet werden sollen) etwa so gehen:
set /a MAX=-999999
for /f "tokens=1-2 delims==" %%a in ('set W0') do if %%b gtr !MAX! (  
    set /a MAX=%%b
    set "CNT=%%a"  
)
set "CNT=%CNT:~2%"  
Grüße
bastla
Mitglied: SinixND
SinixND 16.12.2013 aktualisiert um 23:03:06 Uhr
Goto Top
Hey Bastla,

Is ja der Wahnsinn, wie schnell du immer antwortest =D

Zu deiner Einschränkung, dass alle mit W0 angehn: Rein theoretisch gäbe es vielleicht mehr als 99 Gebäude, hab sowas aber im Spiel bis jetzt noch nicht gesehen, glaub das Maximale was ich mal gesehen habe, sin ca. 30, also geht das in Ordnung =)

Um das mal im Vorraus schon mal zu verstehen. set /a kenn ich, for /f kenn ich auch.
  • Warum legst du als tokens 1-2 fest?
  • delims==" löscht alle Grenzzeichen(?) also auch leer und tab werden ignoriert, hab ich das richtig in Erinnerung?
  • ('set W0') ... versteh ich nicht ganz =D

set /a MAX=%%b, set "CNT=%%a" -> du setzt also das MAX mit dem momentanen Wert, und als CNT, also als Auswahl, welches Gebäude ich nehmen muss, ist %%a... oder?

Danke schon mal ;)

fame.styler

[Edit]
okay. ('set W0') benutzt einen Befehl. Nur versteh ich nicht recht warum? =)
bei set wird doch nichts verwertbares ausgegeben?! Oder steh ich grade auf dem Schlauch =D
[/Edit]
Mitglied: bastla
Lösung bastla 16.12.2013 aktualisiert um 23:25:18 Uhr
Goto Top
Hallo fame.styler!

okay. ('set W0') benutzt einen Befehl. Nur versteh ich nicht recht warum? =)
Einfach mal als Zeile 99 (ohne Apostroph davor und danach) in Deinem Ansatz verwenden, dann siehst Du gleich den Sinn ...
delims==" löscht alle Grenzzeichen(?)
Nein; damit wird "=" als Trennzeichen (zwischen Variablenname und Wert der Variablen - siehe die Ausgabe von "set W0" - daher auch tokens 1-2: %%a und %%b) festgelegt.
set /a MAX=%%b, set "CNT=%%a" -> du setzt also das MAX mit dem momentanen Wert,
... wenn der aktuell betrachtete Wert größer als das bisherige Maximum ist ...
und als CNT, also als Auswahl, welches Gebäude ich nehmen muss, ist %%a... oder?
Genau genommen ist das zunächst der Variablenname, der am Ende noch um die ersten beiden Stellen ("W0") gekürzt wird.

Grüße
bastla
Mitglied: SinixND
SinixND 16.12.2013, aktualisiert am 17.12.2013 um 00:06:14 Uhr
Goto Top
Hallo bastla,

inwzischen hab ich alles verstanden, daher auch den "alten" Kommentar hier im Prizip komplett gelöscht =D

Eine letzte Frage noch (der Thread wird als gelöst markiert):

Muss man am Anfang set /a MAX=-999999 setzten? Die Variable wird doch in der Schleife sowieso gesetzt, oder? Bzw. tuts dann nicht ein einfaches set MAX=0 nicht auch?


Vielen Dank nochmal dafür, bastla, wie immer warst/bist du eine riesen Hilfe =)

fame.styler

[Edit1]
Habs grade eingebaut, aber er verwendet !MAX! im If-Befehl leider nicht (gibt immer !MAX! aus statt dem Wert)... wenn ich die "!" durch "%" ersetze, wird zwar -999999 ausgegeben, allerdings ändert dieser sich nicht (das versteh ich aber, wegen den %)

[Edit2]
Habe jetzt gtr mit leq ersetzt (ich brauch ja den kleinsten Wert), und jetzt funktionierts.
Ich habe ebenfalls nochmal ein paar Versuche mit MAX und GTR gemacht, aber hat nie geklappt... Warum auch immer, es bleibt mir ein Rätsel ;)
set MIN=999999 

for /f "tokens=1-2 delims==" %%a in ('set W0') do if %%b leq !MIN! (   
    set MIN=%%b 
    set CNT=%%a
)

set CNT=%CNT:~2%
[/Edit]