Top-Themen

AppleEntwicklungHardwareInternetLinuxMicrosoftMultimediaNetzwerkeOff TopicSicherheitSonstige SystemeVirtualisierungWeiterbildungZusammenarbeit

Aktuelle Themen

Administrator.de FeedbackApache ServerAppleAssemblerAudioAusbildungAuslandBackupBasicBatch & ShellBenchmarksBibliotheken & ToolkitsBlogsCloud-DiensteClusterCMSCPU, RAM, MainboardsCSSC und C++DatenbankenDatenschutzDebianDigitiales FernsehenDNSDrucker und ScannerDSL, VDSLE-BooksE-BusinessE-MailEntwicklungErkennung und -AbwehrExchange ServerFestplatten, SSD, RaidFirewallFlatratesGoogle AndroidGrafikGrafikkarten & MonitoreGroupwareHardwareHosting & HousingHTMLHumor (lol)Hyper-VIconsIDE & EditorenInformationsdiensteInstallationInstant MessagingInternetInternet DomäneniOSISDN & AnaloganschlüsseiTunesJavaJavaScriptKiXtartKVMLAN, WAN, WirelessLinuxLinux DesktopLinux NetzwerkLinux ToolsLinux UserverwaltungLizenzierungMac OS XMicrosoftMicrosoft OfficeMikroTik RouterOSMonitoringMultimediaMultimedia & ZubehörNetzwerkeNetzwerkgrundlagenNetzwerkmanagementNetzwerkprotokolleNotebook & ZubehörNovell NetwareOff TopicOpenOffice, LibreOfficeOutlook & MailPapierkorbPascal und DelphiPeripheriegerätePerlPHPPythonRechtliche FragenRedHat, CentOS, FedoraRouter & RoutingSambaSAN, NAS, DASSchriftartenSchulung & TrainingSEOServerServer-HardwareSicherheitSicherheits-ToolsSicherheitsgrundlagenSolarisSonstige SystemeSoziale NetzwerkeSpeicherkartenStudentenjobs & PraktikumSuche ProjektpartnerSuseSwitche und HubsTipps & TricksTK-Netze & GeräteUbuntuUMTS, EDGE & GPRSUtilitiesVB for ApplicationsVerschlüsselung & ZertifikateVideo & StreamingViren und TrojanerVirtualisierungVisual StudioVmwareVoice over IPWebbrowserWebentwicklungWeiterbildungWindows 7Windows 8Windows 10Windows InstallationWindows MobileWindows NetzwerkWindows ServerWindows SystemdateienWindows ToolsWindows UpdateWindows UserverwaltungWindows VistaWindows XPXenserverXMLZusammenarbeit
GELÖST

Installationspfad einer Anwendung suchen auf unbekanntem PC

Frage Entwicklung Batch & Shell

Mitglied: onegasee59

onegasee59 (Level 2) - Jetzt verbinden

09.10.2006, aktualisiert 18.10.2006, 9738 Aufrufe, 14 Kommentare

Hallo an Alle,

ist es möglich per Batch eine bekannte Anwendung, in meinem Falle nero.exe auf einem unbekannten Windows-PC-System zu finden und als Ergebnis das LW und den Installationspfad bis zu ../nero.exe jeweils getrennt als Variablen auszugeben?

Alle meine Versuche mit Fertig-Tools, wie z. Bsp. which.exe und fpath.exe, schlagen bei mir fehl. Sie suchen und finden generell alle nur auf LW C. Mit dem For-Befehl komme ich leider auch nicht weiter - zu wenig Erfahrung.

Danke für jede Hilfe

Gruß
Onegasee59
Mitglied: Biber
09.10.2006 um 21:55 Uhr
Moin Onegasee,
endlich mal eine Frage, die ich beantworten kann:

am CMD-Prompt wären Eingabe und Output:
01.
>for %a in (c d e f g h) do @for /f %i in ('dir /s /b %a:\nero.exe ^2^>nul') do @echo "Lw=%~di" path="%~pi" 
02.
"Lw=c:" path="\Programme\Ahead\Nero\"
...wobei diese Lw-Liste "c d e f g h" von Dir beliebig verkürzt/erweitert werden kann.

Im Batch jeweils 2 Prozentzeichen statt einem und statt "@echo" am Ende
"....do Set "neroLw=%%~di" & set "neropath=%%~pi"

Gruß
Biber
Bitte warten ..
Mitglied: onegasee59
09.10.2006 um 22:52 Uhr
Danke Biber,

Man Du bist ja Genial - was habe ich mich abgeqält.
Ich muss das mit dem for-Befehl nochmals intensiver lernen.


Nochmals herzlichen Dank.

Gruß onegasee59
Bitte warten ..
Mitglied: Biber
10.10.2006 um 10:54 Uhr
thx, Onegasee59,

zum Üben habe ich noch eine schnellere Variante für Dich:
[am CMD-Prompt]
01.
>for /f "tokens=2 delims==% " %i in ('ftype^|find /i "nero.exe"') do @echo lw:[%~di] pfad:[%~pi]
Der findet auf jeden Fall die "zugeordnete" Nero.exe-Installation.
Unschön daran ist, dass meistens die Pfade in der Kurzform "C:\PROGRA~1\...." dargestellt sind, was ich nicht ganz zeitgemäß und etwas unästhetisch finde.
Aber für die Programmlogik ist es sicherlich egal.

Wenn Du hier statt "@echo ....." wieder "set lw=... & set pfad=.." nimmst, passt das auch.

Gruß
Biber
Bitte warten ..
Mitglied: onegasee59
10.10.2006 um 17:06 Uhr
Hallo Biber,

auch dafür herzlichen Dank.
Es ergaben sich gestern beim Testen (funktioniert wie gesagt tadellos) aber doch noch Fragen.
Beim Testen habe ich noch auf LW H: eine 2. Nero Installation gehabt. Das war Zufall, denn ich hatte mal das komplette Nero-Verzeichnis von C: auf H: zum testen kopiert und vergessen. Dabei fand ich aber heraus das die for-Schleife immer nur das letzte Pfadverzeichnis speichert, auch wenn es mehrere findet. Wie gesagt ist Zufall, aber was wenn jetzt jemand ein virtuelles LW hat und dort z. Bsp. zum Testen einen 2. echte Nero-Installation hat, wie kann ich virtuelle LW auschließen?

Konkrete Frage also, kann man mit einer Batch CD/DVD und Virtuelle LW, bei Bedarf vom Suchlauf auschließen?

Weitere Frage die sich für mich aus dem Verzeichnis-test ergab. Ich gehe davon aus das gesuchte Programm existiert und jetzt will ich noch wissen ob es mindestens Nero Version 6 oder höher hat. Bisher löse ich das mit der in Nero-Installationspfad selbst enthaltenen NeroCMD.exe. Die liefert mir diese Werte und noch mehr. NeroCMD.exe selbst übergibt die Angaben an eine "neroerr.txt". Daraus teste ich dann die Version., allerdings sehr primitiv.

wie folgt:
@echo off
"C:\Programme\Ahead\Nero\nerocmd.exe" --version > nul
set neroversion=0
findstr /C:"Nero API version: 6." neroerr.txt >> vers_test.txt
if %ERRORLEVEL% EQU 0 set neroversion=6
findstr /C:"Nero API version: 7." neroerr.txt >> vers_test.txt
if %ERRORLEVEL% EQU 0 set neroversion=7

Kann man mit einer Batch auch eleganter, als vorstehend, die Programm-Versionen abfragen?

Danke und Gruß
onegasee59
Bitte warten ..
Mitglied: Biber
10.10.2006 um 18:48 Uhr
Moin onegasee59,

wenn es um die eine installierte Version geht, würde ich die Registry befagen:
01.
:: ----snipp getNeroInfo.bat 
02.
@echo off & setlocal 
03.
for /f "tokens=3" %%a in ('reg query "HKCU\Software\AHead" /s ^|find /i "RegisteredTypesNeroVersion"') do Set "NeroVers=%%a" 
04.
for /f "tokens=3" %%a in ('reg query "HKCU\Software\AHead" /s ^|find /i "RegisteredTypesNeroPath"') do Set "NeroPath=%%a" 
05.
for /f %%i in ("%neropath%") do echo Nero-Version [%NeroVers%], Installiert auf Drive:[%%~di] Pfad: [%%~pi]
Output:
01.
>getNeroInfo.bat 
02.
Nero-Version [6.6.0.16], Installiert auf Drive:[C:] Pfad: [\PROGRA~1\Ahead\Nero\]
Deine Variante über NeroCMD (am Prompt gezeigt
01.
>>for /f "tokens=4" %a in ('c:\PROGRA~1\Ahead\Nero\nerocmd.exe --version^|find "API"') do @echo Nero-API-Version: %a 
02.
Nero-API-Version: 6.6.0.16
Gruß
Biber
Bitte warten ..
Mitglied: onegasee59
10.10.2006 um 19:13 Uhr
Moin Biber,

Deine Variante über NeroCMD (am Prompt gezeigt
for /f "tokens=4" %a in ('c:\PROGRA~1\Ahead\Nero\nerocmd.exe --version^|find "API"') do @echo Nero-API-Version: %a Nero-API-Version: 6.6.0.16

also....mir fehlen momentan die Worte um mein Staunen auszudrücken.
Ernsthafte Frage - Machst Du zu Batch&Shell-Programmierung auch richtige Lehrkurse?
Falls ja - ich wäre sehr interessiert!

Meine letzte Bitte kannst Du noch was zu meiner obigen 1. Frage sagen?:
Konkrete Frage also, kann man mit einer Batch CD/DVD und Virtuelle LW, bei Bedarf vom Suchlauf auschließen?


Herzliche Grüße in den Norden
onegasee59
Bitte warten ..
Mitglied: onegasee59
11.10.2006 um 03:59 Uhr
Moin Biber,

dank Dir habe ich noch einen andere Variante der Versionsprüfung gefunden.
Ausgangspunkt ist das finden des Installationspfad.

01.
**Programm finden Variante 1** 
02.
set proglw="kein LW" 
03.
set progpfad="kein Installationspfad"  
04.
for %%a in (c d e f g h i j k l m n o p q r s t u v w x y z) do @for /f %%i in ('dir /s /b %%a:\nero.exe ^2^>nul') do set "proglw=%%~di" & set "progpfad=%%~pi"
01.
**Programm finden Variante 2** 
02.
set proglw="kein LW" 
03.
set progpfad="kein Installationspfad" 
04.
for /f "tokens=2 delims==%% " %%i in ('ftype^|find /i "nero.exe"') do set "proglw=%%~di" & set "progpfad=%%~pi" 
01.
**Erstelle VBS-Skript zur Prüfung von Dateiversionen** 
02.
set progver=progversion.vbs 
03.
echo Set oFSO = CreateObject("Scripting.FileSystemObject") >%progver% 
04.
echo WScript.Echo oFSO.GetFileVersion(WScript.Arguments.Item(0)) >>%progver% 
05.
**Prüfe Version von nero.exe** 
06.
set nerofile=%proglw%%progpfad%\nero.exe 
07.
for /f "tokens=*" %%a in ('cscript.exe //Nologo %progver% %nerofile%') do set nerofilever=%%a 
08.
IF %nerofilever% GEQ 7.0.0.0 (echo nero 7 ist installiert) ELSE (echo nero 6 ist installiert) 
09.
 
10.
rem call cscript.exe //Nologo %progver% %nerofile% - liefert als Ergebnis 6.6.1.4 (ist die aktuellste Nero 6-Version)
Gruß
onegasee59
Bitte warten ..
Mitglied: onegasee59
11.10.2006 um 04:08 Uhr
Moin Biber,

DANKE für die "Lehrstunde" im for-Befehl. So langsam komme ich dahinter.

Gruß
onegasee59
Bitte warten ..
Mitglied: Biber
11.10.2006 um 10:07 Uhr
Sieht doch gut aus, onegasee59,

aber das
for %%a in (c d e f g h i j k l m n o p q r s t u v w x y z) ..
ist ja wirklich unschön, da gebe ich Dir Recht.

Ich hatte zwar gehofft, ich könnte mich vor der Antwort auf die Frage nach der Batch-Laufwerksidentifizierung drücken. Aber what shalls...

Also, schlechte Nachricht: Kann ich mit Batch-Bordmitteln nicht prüfen/erkennen.
Gute Nachricht - in solchen Fällen mach ich es wie MacGyver und schraube mir aus zwei Strohhalmen und einer Erdnuss irgendwas zusammen.

Ich kann mit VBS oder JS (was ich wohl auf jedem Rechner vorfinde) ja eben mal die Laufwerke, die ich brauche, abfragen.

In VBS gibt es das FileSystemObject, das wiederum eine Drives-Collection liefern kann (alle Lw, die der Rechner kennt).
Und jeder Drive hat einen DriveType mit einem von diesen 6 Werten:
01.
"0" = "Unknown type of drive" 
02.
"1" = "Removable drive" 
03.
"2" = "Fixed drive" 
04.
"3" = "Network drive" 
05.
"4" = "CD-ROM drive" 
06.
"5" = "RAM Disk"
Also brate ich mir einen kleinen VBS-Schnipsel zusammen (den ich zur Not aus im Batch mit "echo" erzeugen kann).
Folgende Quick&Dirty-Strategie: Ich will
- eine GetDrives.vbs
- die mir beim Aufruf OHNE Paramter alle Fixed-Laufwerke als Text(liste) zurückgibt, z.B. "C,D,E"
- optional noch bestimmte andere Laufwerkstypen (meinetwegen Netz-Laufwerke) ergänzt.
Die optionalen gebe ich als Parameter (num. Lw-Typ wie oben) an, wenn ich will

Das sieht dann im ganzen Satz so aus:

01.
:: --- getDrivesIWant2C.bat 
02.
@echo off & setlocal 
03.
set vbsSnippet=%temp%\%random%.vbs 
04.
 >%vbsSnippet% echo Set FSO = CreateObject("Scripting.FileSystemObject")  
05.
>>%vbsSnippet% echo Set Drives = FSO.Drives 
06.
>>%vbsSnippet% echo set Args = wscript.arguments 
07.
>>%vbsSnippet% echo alldrives="" 
08.
>>%vbsSnippet% echo wanteddrvs="2" 
09.
>>%vbsSnippet% echo for i=0 to Args.count-1 
10.
>>%vbsSnippet% echo   wanteddrvs= wanteddrvs + "," + args(i) 
11.
>>%vbsSnippet% echo next 
12.
>>%vbsSnippet% echo For Each d in Drives 
13.
>>%vbsSnippet% echo    if instr(1,wanteddrvs,d.Drivetype) then alldrives= alldrives +"," + d.Driveletter 
14.
>>%vbsSnippet% echo Next>>%vbsSnippet% 
15.
>>%vbsSnippet% echo wscript.echo mid(alldrives,2) 
16.
>>%vbsSnippet% echo Set Drives = nothing 
17.
>>%vbsSnippet% echo Set FileSystemObject = nothing 
18.
>>%vbsSnippet% echo wscript.quit 
19.
REM Ein bisschen Demo: 
20.
For /f %%i in ('cscript //nologo %vbsSnippet%') do echo [DEBUG Lw-Liste nur Fixed ] %%i 
21.
For /f %%i in ('cscript //nologo %vbsSnippet% 1 4 ') do echo [DEBUG Lw-Liste Fixed + Removable+ CDRom] %%i 
22.
REM Ende von: Ein bisschen Demo: 
23.
For /f %%i in ('cscript //nologo %vbsSnippet%') do set "lwliste=%%i" 
24.
echo [Lw-Liste Fixed] %lwliste% 
25.
echo [Der For-Befehl nur Fixed-Lw:.. for %%%%a in (%%lwliste%%) ..-^>.. for %%%%a in (%lwliste%) 
26.
del %vbsSnippet%
Dieser Schnipsel liefert am CMD-Prompt:
01.
>getdrivesIWant2C.bat 
02.
[DEBUG Lw-Liste nur Fixed ] C,D 
03.
[DEBUG Lw-Liste Fixed + Removable+ CDRom] A,C,D,F,R 
04.
[Lw-Liste Fixed] C,D 
05.
[Der For-Befehl nur Fixed-Lw:.. for %%a in (%lwliste%) ..->.. for %%a in (C,D)
Denke, den kannst Du noch einbauen bei Bedarf.

Gruß
Biber
Bitte warten ..
Mitglied: onegasee59
11.10.2006 um 18:17 Uhr
Moin Biber,

Den "Braten" muss ich erstmal verdauen.
Ich teste alles gründlich und melde mich wieder. Versprochen!
Kann aber ein bischen dauern.

Danke erstmal bis hierhin.

Herzlichen Gruß
onegasee59
Bitte warten ..
Mitglied: Biber
11.10.2006 um 18:58 Uhr
Okay, onegasee59,

war ja nicht fair von mir, auch noch einen Mehrzeiler ganz ohne Kommentare hier abzuladen.
So was tun nicht mal Batchler...vollkommen kommentarlose Schnipsel irgendwo hinstellen.
Eigentlich nicht.

Ich hatte mir die Kommentare im VBS-Teil geschenkt, weil die definitiv keiner lesen kann
in den anderthalb Sekunden, in denen dieses temporäre Snippet im %temp%-Verzeichnis existiert.

Würde es ein dauerhaftes VBS-Schnipselchen sein sollen, wäre meine Kommentierung in etwa so:
01.
' GetDrives.vbs 
02.
Set FSO = CreateObject("Scripting.FileSystemObject") ' Ein FileSystemObject brauche ich... 
03.
Set Drives = FSO.Drives	         ' denn das liefert mir die Drive-Collection 
04.
set Args = wscript.arguments	         ' Falls der Benutzer Argumente angegeben hat, nenn ich die "Args" 
05.
alldrives=""                               ' Alldrives will ich später zurückgeben..einen String der Form "C,D,R" 
06.
wanteddrvs="2"			 ' immer will ich die Laufwerke Type "2"="Fixed Drives" 
07.
for i=0 to Args.count-1		 ' Falls Parameter angegeben, dann in einen String schreiben ("2,4,5") 
08.
  wanteddrvs= wanteddrvs + "," + args(i)    ' "wanteddrvs", weil es der User ja so wants... 
09.
next   
10.
For Each d in Drives		 ' Für jeden Drive d, den der Rechner kennt.... 
11.
   if instr(1,wanteddrvs,d.Drivetype) > 0 then alldrives= alldrives +"," & d.Driveletter 
12.
   ' wenn der Type ("0" oder "1" oder..."5") in dem Text "wanteddrvs" (= "2.4.5") ist.... 
13.
   ' dann ein Komma und den zugehörigen DriveLetter zu "alldrives" dazu... 
14.
Next 
15.
wscript.echo mid(alldrives,2)  ' In alldrives steht MINIMAL ",C" ; NORMAL "C,D,E" oder sowas.  
16.
                               ' Erstes zeichen=Komma hauen wir wech. 
17.
Set Drives = nothing	       ' ja, ja ..mein Ordnungsfimmel...diese und die folgenden Zeilen sind nicht Pflicht. 
18.
Set FileSystemObject = nothing ' selbst erschaffene Objects auch selbst zerstören...welcher Bill sollte das für uns tun? 
19.
wscript.quit                   ' und damit es auch jedes M$ mitbekommt, dass hier Ende ist, schreiben wir das.
Dann lässt es sich wenigstens in Ansätzen nachvollziehen.
Gruß
Biber
P.S. was ich immer noch nicht verstanden habe: Wozu brauchst Du diese Trennung von Drive und Path der "Nero.exe"?
Du verwendest die doch ohnehin nur in Kombination.
Bitte warten ..
Mitglied: onegasee59
11.10.2006 um 20:23 Uhr
Moin Biber,

es war absolut Ok. Ich hätte mich da schon "durchgefuttert".
Dennoch ist natürlich Deine ausführliche Erklärung für mich sehr hilfreich.

Zu Deiner Frage im PS:
Zum einem wollte ich wissen ob und wie man die Aufsplittung von Pfadbestandteilen mit den Mitteln einer Batch-Programmierung erreichen kann. Zum Anderen ist es so das ich ein Tool schreibe für die Bereinigung der Decoderarchitektur _NACH_ einer Installation von Nero 6 oder höher. Nero reißt die Decoder und Directshowfilter (für Audi und Video) nämlich ungefragt an sich. Viele User haben irgendwann unerklärliche Probleme mit anderen Multimedia-Anwendungen. Was ich bis vor kurzem nicht wusste, Nero kauft seine Decoder dazu und entwickelt sie nicht selbt. Wäre alles nicht so schlimm, wenn sich die Decoderarchitektur von Nero absolut Systemkonform verhalten würden und nicht bei den anderen Anwendungen in den Vordergrund drängeln würde und dabei oftmals nicht wirklich unterstützen. Ergebnis sind leider immer wieder nicht funktionierende Multimedia-Anwendungen wie Zoom-Player, MPC, Quicktime Player usw.

Ich zitiere mal einen absoluten Könner (Thomas Beyer) auf dem Multimedia-Gebiet (Aussage gilt analog für Nero 6)
01.
Auch wenn der Installer von Nero bei der 7er Version suggeriert, er würde bei Abwahl der entsprechenden 
02.
Komponenten die dazugehörigen Decoder und Parser nicht installieren: Man tut es trotzdem. 
03.
 
04.
Bei einer vollständigen Deinstallation werden die DLLs zwar physikalisch entsorgt, es bleibt aber noch jede 
05.
Menge Müll in der Registry übrig, u.a. auch verwaiste Einträge auf Decoder, welche dann Deine 
06.
DirectShowarchitektur beeinträchtigen können.
Wichtig das Tool fasst die Dateien von Nero nicht physisch an, sonst bekäme ich ernsthaft Probleme mit Neros Anwälten.

Deine Tips zur Versionsprüfung und vor allem zum Umgang mit dem For-Befehl haben mir da unheimlich Schub gegeben. Bis auf Feinheiten habe ich es fertig. Wichtig war hier vor allem das ich den echten/richtigen Installationspfad finde und dann aufsplitten kann, da sich erst daraus automatisch die Pfade ergeben die ich dann als feste Variable festlegen kann und ich sicher sein kann das die enthaltene Pfade tatsächlich existieren. Diese Pfade benötige ich für die eigentliche Bereinigung (Deregistrierung und ReDeregistrierung) der Decoder und Directshowfilter von Nero. Die LW-Angabe ermöglicht mir in einer späteren Phase zu prüfen und abzusichern das sich Nero 6 (oder höher) weder auf einem virtuellen noch externen LW befindet, sondern eine "echte" Nero-Installation vorliegt.

Wenn ich es fertig habe stelle ich es auf meiner Website und auf der Website des Initiators (Thomas Beyer) als Freeware zu Verfügung. Systemvorausetzungen sind WIN 2000/XP und Nero 6 (oder höher). siehe hierzu Video- und Audio-Codecs ermitteln, installieren oder reparieren

Falls Du Interesse hast und schon vorab einen Blick drauf werfen willst, sende ich Dir die Version zum gegenwärtigen Stand gerne zu.

Gruß
onegasse59 (meine Website http://www.der-wmp.de)
Bitte warten ..
Mitglied: Biber
11.10.2006 um 21:43 Uhr
Moin onegasee59,

eine TOP-Seite, die Du da hast. Respekt.
Dann noch mal der Vollständigkeit halber:
Wenn es tatsächlich um die installierte Nero-Version geht, dann würde ich natürlich
- als erste Wahl die Registry befragen
- als zweite Wahl dieses FType-Geraffel nutzen (das ja auch nur über Bande die Registry-Einträge widerspiegelt).
- als definitiv letzte Krücke bleibt dieser Weg über das Dateisystem - der ist ja gerade bei solchen beliebten Tools wie WinZip oder Nero höchst unsicher.
Denn da hat ja jeder DAU/jede DAUin irgendwo eine alte, eine Beta, eine halbe Installation in irgendeinem vergessenen Ordner.
Von Sicherungen auf Festplatte 3 oder 4 ganz zu schweigen.

Ach ja, was den Vorab-Blick betrifft: das Angebot nehme ich dankend an.

Schönen Abend
Biber
Bitte warten ..
Mitglied: onegasee59
18.10.2006 um 23:11 Uhr
Moin Biber,

eine TOP-Seite, die Du da hast. Respekt.

Danke

Wenn es tatsächlich um die installierte Nero-Version geht, dann würde ich natürlich
- als erste Wahl die Registry befragen

Nach einigen Tests hat sich das absolut bestätigt und.......

Denn da hat ja jeder DAU/jede DAUin irgendwo eine alte, eine Beta, eine halbe Installation
in irgendeinem vergessenen Ordner. Von Sicherungen auf Festplatte 3 oder 4 ganz zu schweigen.

....das ebenso. Alle anderen Varianten der Emittlung des Installationspfades einer Anwendung (in diesem Fall für Nero) sind tatsächlich viel zu ungenau.

Schönen Abend
onegasee59
Bitte warten ..
Neuester Wissensbeitrag
Internet

Unbemerkt - Telekom Netzumschaltung! - BNG - Broadband Network Gateway

(3)

Erfahrungsbericht von ashnod zum Thema Internet ...

Ähnliche Inhalte
Batch & Shell
WinXP-PC mit einem Barcodescanner herunterfahren (6)

Frage von Sinzal zum Thema Batch & Shell ...

CPU, RAM, Mainboards
Angetestet: PC Engines APU 3a2 im Rack-Gehäuse (2)

Erfahrungsbericht von ashnod zum Thema CPU, RAM, Mainboards ...

Batch & Shell
Powershell - In Textdatei suchen und ersetzen (3)

Frage von Raaja89 zum Thema Batch & Shell ...

Router & Routing
Spielzeiten auf pc und handy steuern (7)

Frage von fisch56 zum Thema Router & Routing ...

Heiß diskutierte Inhalte
Windows Server
Outlook Verbindungsversuch mit Exchange (15)

Frage von xbast1x zum Thema Windows Server ...

Grafikkarten & Monitore
Tonprobleme bei Fernseher mit angeschlossenem Laptop über HDMI (11)

Frage von Y3shix zum Thema Grafikkarten & Monitore ...

Microsoft Office
Keine Updates für Office 2016 (11)

Frage von Motte990 zum Thema Microsoft Office ...