In Linkstruktur Sonderzeichen mit VB transformieren.

alter Dateiname=neuer Dateiname

Const sSonder = "C:\Skripts\SonderzeichenErsetzung.txt"  
Const sAusnahmen = "C:\Skripts\Ausnahmen.txt"  

Const sFileExtOld = ".bak"  

Const sStart = "href=""" 'linke Begrenzung der zu konvertierenden Sequenz  
Const sEnd = """" 'rechte Begrenzung der zu konvertierenden Sequenz  

lLenStart = Len(sStart)

If WScript.Arguments.Count = 0 Then
	WScript.Echo "Datei mit umzubenennenden Links als Parameter uebergeben!"  
	WScript.Quit(1)
End If

Set fso = CreateObject("Scripting.FileSystemObject")  
sFile = WScript.Arguments(0)

If Not fso.FileExists(sFile) Then
	WScript.Echo sFile & " ist kein gueltiger Dateiname!"  
	WScript.Quit(1)
End If

If Not fso.FileExists(sSonder) Then
	WScript.Echo "Sonderzeichendaten " & sSonder & " nicht gefunden."  
	WScript.Quit(1)
End If
Set oSonder = fso.OpenTextFile(sSonder, 1)
If Not oSonder.AtEndOfStream Then 
	aSonder = Split(oSonder.ReadAll, vbCrLF)
Else
	oSonder.Close
	WScript.Echo "Sonderzeichendatei " & sSonder & " enthält keine Daten!"  
	WScript.Quit(1)
End If
oSonder.Close

If Not fso.FileExists(sAusnahmen) Then
	R = MsgBox("Ausnahmendatei " & sAusnahmen & " nicht gefunden!" & vbCrLF & vbCrLF & _  
		"Sollen alle Links (ohne Ausnahmen) umgewandelt werden?",vbYesNo)  
	If R <> vbYes Then WScript.Quit(1)
	bAusnahmen = False
Else
	Set oAusnahmen = fso.OpenTextFile(sAusnahmen, 1)
	If Not oAusnahmen.AtEndOfStream Then 
		aAusnahmen = Split(oAusnahmen.ReadAll, vbCrLF)
		bAusnahmen = True
	Else
		R = MsgBox("Ausnahmendatei " & sAusnahmen & " enthält keine Daten!" & vbCrLF & vbCrLF & _  
		"Sollen alle Links (ohne Ausnahmen) umgewandelt werden?",vbYesNo)  
		If R <> vbYes Then WScript.Quit(1)
		bAusnahmen = False
	End If
	oAusnahmen.Close

End If

sFileBak = sFile & sFileExtOld
If fso.FileExists(sFileBak) Then fso.DeleteFile(sFileBak)
Set oFile = fso.GetFile(sFile)
oFile.Name = sFileBak
sText = oFile.OpenAsTextStream(1).ReadAll
Set oFile = Nothing

Set oFileNew = fso.OpenTextFile(sFile, 2, True)

bDone = False
lEnd = 0
lPos2Write = 1
Do
	lStart = InStr(lEnd + 1, sText, sStart, vBTextCompare)
	If lStart > 0 Then
		lStart = lStart + lLenStart
		oFileNew.Write Mid(sText, lPos2Write, lStart - lPos2Write)
		lPos2Write = lStart
		lEnd = InStr(lStart, sText, sEnd, vBTextCompare)
		If lEnd > 0 Then
			sLinkOld = Mid(sText, lStart, lEnd - lStart)
			sLinkNew = ReplaceSpecialChars(sLinkOld, bAusnahmen)
			oFileNew.Write sLinkNew
			lPos2Write = lEnd
		Else
			bDone = True
		End If
	Else
		bDone = True
	End If
Loop  Until bDone

oFileNew.Write Mid(sText, lPos2Write)
oFileNew.Close

Function ReplaceSpecialChars(sOld, bAus)
sTemp = sOld
If bAus Then
	For Each sLine In aAusnahmen
		aAus = Split(sLine, "=")  
		If InStr(sOld, "/" & aAus(0)) <> 0 Then  
			sTemp = Replace(sOld, "/" & aAus(0), "/" & aAus(1))  
			Exit For
		End If
	Next
End If

If sTemp = sOld Then
	For Each sLine In aSonder
		aChars = Split(sLine, ",")  
		For i = 1 To UBound(aChars)
			sTemp = Replace(sTemp, aChars(i), aChars(0))
		Next
	Next
End If
ReplaceSpecialChars = sTemp
End Function

oFile.Name = sFileBak

oFile.Name = oFile.Name & sFileExtOld

If bAus Then
	For Each sLine In aAusnahmen
		aAus = Split(sLine, "=")  
		If InStr(sOld, "/" & aAus(0)) <> 0 Then  
			sTemp = Replace(sOld, "/" & aAus(0), "/" & aAus(1))  
			Exit For
		End If
	Next
End If

If bAus Then
	For Each sLine In aAusnahmen
		If sLine <> "" Then  
			aAus = Split(sLine, "=")  
			If InStr(sOld, "/" & aAus(0)) <> 0 Then  
				sTemp = Replace(sOld, "/" & aAus(0), "/" & aAus(1))  
				Exit For
			End If
		End If
	Next
End If