Lotus Notes schrottet PDF-Dateien von bestimmtem Absender

Sub Initialize
	Dim s As New NotesSession
	Dim db As NotesDatabase
	Dim dc As NotesDocumentCollection
	Dim doc As NotesDocument
	Dim mime As NotesMIMEEntity
	Dim child As NotesMIMEEntity
	Dim m As String
	Dim stream As NotesStream
	Dim i As Integer
	Dim status
	Dim fso
	
	i=1
	Set db = s.CurrentDatabase
	s.ConvertMIME = False
	Set dc = db.UnprocessedDocuments
	' Erstes markiertes Dokument nehmen (Agent ist nicht für mehrere Dokumente ausgelegt)  
	Set doc = dc.GetFirstDocument
	Set mime = doc.GetMIMEEntity
	' MIME zerlegen  
	While Not (mime Is Nothing)
		' Nach einem PDF Anhang suchen  
		If Lcase(mime.ContentType)="application" And Lcase(mime.ContentSubType)="pdf" Then  
			' Und das PDF rausschreiben  
			Set stream = s.CreateStream	
			Set fso = createObject("Scripting.FileSystemObject")  
			If fso.fileexists("c:\temp\" & doc.UniversalID & "_" & Cstr(i) & ".pdf") Then  
				Kill "c:\temp\" & doc.UniversalID & "_" & Cstr(i) & ".pdf"  
			End If
			Call stream.Open("c:\temp\" & doc.UniversalID & "_" & Cstr(i) & ".pdf")  
			Call mime.GetContentAsBytes(stream)
			Call stream.Close
			' Acrobat starten (Pfad anpassen)  
			status = Shell("e:\acrobat\reader\acrord32.exe c:\temp\" & doc.UniversalID & "_" & Cstr(i) & ".pdf", 1)  
		End If
		'Falls er mehr als 200 MIME Entities finden sollte, kann das eigentlich nur eine Endlosschleife sein, beenden  
		If i>200 Then
			s.ConvertMIME = True ' Restore conversion  
			Exit Sub
		End If
		i=i+1
		' Nächstes MIME Entity nehmen  
		Set mime = mime.GetNextEntity
	Wend
	s.ConvertMIME = True ' Restore conversion  
End Sub