Ordner und Dateinamen mit dazugehöriger Besitzerinformation auslesen und in csv Datei ausgeben

@echo off & setlocal

::Das Verzeichnis, in dem das Script gespeichert ist, zum aktuellen Verzeichnis machen
pushd "%~dp0"  

::Aktuelles Datum bestimmen und in die Variable DateStamp schreiben
call :GetDate DateStamp


::Basisverzeichnis
set "Ordner=D:\"  

::Zieldatei
set "Liste=D:\%DateStamp% Liste.csv"  

::Pfad+Name des VBScripts, das die Datei- und Verzeichnisdaten ermittelt
set "VBSGetTreeInfo=GetTreeInfo.vbs"  


::Evtl. bereits existierende Zieldatei löschen
del "%Liste%" 2>NUL  

::VBScript ausführen, dabei das Basisverzeichnis als Parameter übergeben
::Die Ausgabe des VBScripts in die Zieldatei umleiten
cscript /nologo "%VBSGetTreeInfo%" "%Ordner%" > "%Liste%"  

::Das Verzeichnis, das beim Scriptstart das aktuelle Verzeichnis war,
::wieder zum aktuellen Verzeichnis machen
popd

::Script Ende
exit /b



::Unterprogramm, das mit Hilfe eines temporären VBScripts
::das aktuelle Datum bestimmt und im Format DD-MM-YYYY zurückgibt
:GetDate
  ::Pfad für temporäres Script
  set "VBSGetDate=%TEMP%\GetDate.vbs"  
  
  ::Temporäres VBScript schreiben
  > "%VBSGetDate%" echo dtToday = Date()  
  >>"%VBSGetDate%" echo WScript.Echo Year(dtToday) ^& "-" ^& Right("0" ^& Month(dtToday), 2) ^& "-" ^& Right("0" ^& Day(dtToday), 2)  
  
  ::Temporäres VBScript ausführen und das Ergebnis in der Variablen speichern,
  ::deren Name als 1. Parameter übergeben wurde
  for /f "delims=" %%d in ('cscript /nologo "%VBSGetDate%"') do (  
    set "%~1=%%d"  
  )
  
  ::Temporäres VBScript löschen
  del "%VBSGetDate%"  

::Rücksprung
exit /b

Option Explicit

Const typeFolder = 0
Const typeFile   = 1

Dim objFSO, objWMIService, intRetVal

Set objFSO        = CreateObject("Scripting.FileSystemObject")  
Set objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate}!\root\cimv2")  

If WScript.Arguments.Count > 0 Then
  If objFSO.FolderExists(WScript.Arguments(0)) Then
    TraverseFolderTree objFSO.GetFolder(WScript.Arguments(0))
    intRetVal = 0
  Else
    WScript.StdErr.WriteLine "Fehler: Verzeichnis wurde nicht gefunden."  
    intRetVal = 2
  End If
Else
  WScript.StdErr.WriteLine "Fehler: Bitte geben Sie ein Verzeichnis an."  
  intRetVal = 1
End If

WScript.Quit intRetVal



Sub TraverseFolderTree(objFolder)
  Dim colSubFolders, objSubFolder, colFiles, objFile
  
  Set colSubFolders = objFolder.SubFolders
  Set colFiles      = objFolder.Files

  For Each objSubFolder In colSubFolders
    WScript.StdOut.WriteLine GetItemInfo(typeFolder, objSubFolder)
  Next
  
  For Each objFile In colFiles
    WScript.StdOut.WriteLine GetItemInfo(typeFile, objFile)
  Next
  
  For Each objSubFolder In colSubFolders
    TraverseFolderTree objSubFolder
  Next
End Sub


Function GetItemInfo(intType, objItem)
  Dim arrItemInfo(4), dtTimeStamp
  
  dtTimeStamp = objItem.DateLastModified
  
  arrItemInfo(0) = Right("0" & Day(dtTimeStamp), 2) & "." & Right("0" & Month(dtTimeStamp), 2) & "." & Year(dtTimeStamp)  
  arrItemInfo(1) = Right("0" & Hour(dtTimeStamp), 2) & ":" & Right("0" & Minute(dtTimeStamp), 2)  
  
  Select Case intType
    Case typeFolder arrItemInfo(2) = "<DIR>"  
    Case typeFile   arrItemInfo(2) = objItem.Size
  End Select  

  arrItemInfo(3) = GetOwner(objItem.Path)
  arrItemInfo(4) = objItem.Path
  
  GetItemInfo = Join(arrItemInfo, ";")  
End Function


Function GetOwner(strItemName)
  Dim objFileSecuritySettings, objSecurityDescriptor
  
  strItemName = Replace(strItemName, "\", "\\")  

  Set objFileSecuritySettings = objWMIService.Get("Win32_LogicalFileSecuritySetting=""" & strItemName & """")  
  objFileSecuritySettings.GetSecurityDescriptor objSecurityDescriptor

  GetOwner = objSecurityDescriptor.Owner.Domain & "\" & objSecurityDescriptor.Owner.Name  
End Function

Option Explicit

Const typeFolder = 0
Const typeFile   = 1

Dim objFSO, objShell, intRetVal

Set objFSO   = CreateObject("Scripting.FileSystemObject")  
Set objShell = CreateObject("Shell.Application")  

If WScript.Arguments.Count > 0 Then
  If objFSO.FolderExists(WScript.Arguments(0)) Then
    TraverseFolderTree objShell.NameSpace(WScript.Arguments(0))
    intRetVal = 0
  Else
    WScript.StdErr.WriteLine "Fehler: Verzeichnis wurde nicht gefunden."  
    intRetVal = 2
  End If
Else
  WScript.StdErr.WriteLine "Fehler: Bitte geben Sie ein Verzeichnis an."  
  intRetVal = 1
End If

WScript.Quit intRetVal




Sub TraverseFolderTree(objFolder)
  Dim objItem

  For Each objItem In objFolder.Items
    If objItem.IsFolder And objItem.IsFileSystem And (objItem.Size = 0) Then
      WScript.StdOut.WriteLine GetItemInfo(typeFolder, objItem)
    End If
  Next
  
  For Each objItem In objFolder.Items
    If ((Not objItem.IsFolder) And objItem.IsFileSystem) Or (objItem.IsFolder And objItem.IsFileSystem And (objItem.Size <> 0)) Then
      WScript.StdOut.WriteLine GetItemInfo(typeFile, objItem)
    End If
  Next
  
  For Each objItem In objFolder.Items
    If objItem.IsFolder And objItem.IsFileSystem And (objItem.Size = 0) Then
      TraverseFolderTree objItem.GetFolder
    End If
  Next
End Sub


Function GetItemInfo(intType, objItem)
  Dim arrItemInfos(4), dtTimeStamp

  dtTimeStamp = objItem.ModifyDate
  
  arrItemInfos(0) = Right("0" & Day(dtTimeStamp), 2) & "." & Right("0" & Month(dtTimeStamp), 2) & "." & Year(dtTimeStamp)  
  arrItemInfos(1) = Right("0" & Hour(dtTimeStamp), 2) & ":" & Right("0" & Minute(dtTimeStamp), 2)  
  
  Select Case intType
    Case typeFolder arrItemInfos(2) = "<DIR>"  
    Case typeFile   arrItemInfos(2) = objItem.Size
  End Select

  arrItemInfos(3) = objItem.ExtendedProperty("Owner")  
  arrItemInfos(4) = objItem.Path
  
  GetItemInfo = Join(arrItemInfos, ";")  
End Function