bodyparts
Goto Top

Ordner verschieben ist Zielordner gleich dann nur den Inhalt

Hallo,

ich möchte vom Desktop Ordner verschieben, ist der Inhalt schon in Ziel dann soll nur der Inhalt kopiert werden in den bestehenden Ordner. Und der Ordner dann vom Desktop gelscht werden.
Befindet sich die Datei schon im Zielordner, dann soll sie verworfen werden.

mit move geht das nicht, bzw mit xcopy....

oder

Gruß

Content-Key: 159084

Url: https://administrator.de/contentid/159084

Ausgedruckt am: 28.03.2024 um 15:03 Uhr

Mitglied: Friemler
Friemler 20.01.2011 um 17:12:26 Uhr
Goto Top
Hallo bodyparts,

ich schlage vor, Du atmest mal gaaanz tief durch und sammelst Deine Gedanken. Dann schilderst Du Dein Problem nochmals, am besten unterstützt durch eine Beispiel-Verzeichnisstruktur. Dann kann evtl. auch jeder (außer Dir selbst) verstehen, was Du eigentlich willst.

Gruß
Friemler
Mitglied: bodyparts
bodyparts 20.01.2011 um 17:22:02 Uhr
Goto Top
????

auf dem Desktop vom User xyz befinden sich Ordner, in diesen Ordner sich Dateien.

Jetzt sollen die Ordner verschoben werden zb in d:\export befinden sich schon Ordner mit dem gleichen Namen in diesem Ordner soll nur der Inhalt verschoben werden.
Dann kann der Ordner vom Desktop gelöscht werden. Definden sich schon Dateien mit dem selben Namen im Ziel brauchen diese nicht verschoben werden sondern direkt gelöscht.

besser?????
Mitglied: Florian.Sauber
Florian.Sauber 20.01.2011 um 19:15:09 Uhr
Goto Top
Na ja, bodyparts,

unter uns Betschwestern: Dein Schreibstil ist schon unter aller Kanone, aber OK, Du wärst nicht der erste, der es eilig und daher den Grammatikmodus auf Off gestellt hat, mich eingeschlossen.

Zu Deiner Frage:
Schau Dir mal Robocpy an, im speziellen die Parameter /XN /XC und /XO, um zu verhindern, dass bereits vorhandenen Dateien im Zielverzeichnis ersetzt werde, selbst wenn sie neuer sind oder verändert wurden.

Beim "Verschieben" handelt es sich ja faktisch um nichts anderes, als ein Kopieren mit anschliessendem Löschen der QuellVerzeichnisse/Dateien. Da hilft dir eine Batchdatei weiter. Etwaige Fragen dazu kannst Du ja im entsprechenden Bereich hier im Forum stellen(EDIT: Ups, da sind wir ja bereits. Na mein Fehler)...

LG Florian
Mitglied: Friemler
Friemler 20.01.2011, aktualisiert am 18.10.2012 um 18:45:34 Uhr
Goto Top
Hallo bodyparts,

Zitat von @bodyparts:
besser?????
na ja, geht so...

Nichtsdestotrotz ein paar Codezeilen von mir, die Deinen Wünschen hoffentlich gerecht werden. Prüfe sie aber auf jeden Fall erstmal mit Testdateien, oder ersetzt die Befehle RD, MD und MOVE durch ECHO RD, ECHO MD bzw. ECHO MOVE (beim MOVE-Befehl musst Du dann noch das > NUL am Zeilenende entfernen, sonst siehst Du nix face-wink ). Hilfe zum FOR-Befehl gibt es übrigens in meinem ausführlichen Tutorial.
@echo off

setlocal

set "Src=%UserProfile%\Desktop"  
set "Dest=D:\export"  


for /d %%d in ("%Src%\*.*") do (  
  if exist "%Dest%\%%~nxd" (  
    call :ProcessDir "%%d"  
    for /f "delims=" %%f in ('dir /s /b /a:d "%%d"') do (  
      call :ProcessDir "%%f"  
    )
    rd "%%d" /s /q  
  )
)

endlocal
exit /b



:ProcessDir
  set "SrcDir=%~1"  
  set "Dir=%SrcDir%"  
  call set "Dir=%%Dir:%Src%=%%"  

  md "%Dest%%Dir%" 2>NUL  

  for %%i in ("%SrcDir%\*.*") do (  
    if not exist "%Dest%%Dir%\%%~nxi" (  
      move "%%i" "%Dest%%Dir%" > NUL  
    )
  )
exit /b

Das Skript verschiebt nur Dateien in Verzeichnissen, die sowohl auf dem Desktop als auch im Ziel vorhanden sind. Dabei wird die komplette Verzeichnisstruktur unterhalb dieser Verzeichnisse verarbeitet. Dateien, die im Ziel bereits vorhanden sind, werden nicht verschoben. Das Quell-Verzeichnis wird mit allen Unterverzeichnissen und verbliebenen Dateien gelöscht.

Gruß
Friemler
Mitglied: bastla
bastla 20.01.2011 um 19:56:38 Uhr
Goto Top
Hallo @all!

Ich versuch' mich auch noch an der Interpretation und gehe mal davon aus, dass nur noch nicht im Ziel existierende Dateien verschoben werden sollen (allerdings auch solche, die sich in Unterordnern befinden) - falls ja, dann zB für alle Ordner auf dem Desktop:
@echo off & setlocal
set "User=xyz"  
set "Quelle=%userprofile%\..\%User%\Desktop"  
set "Ziel=D:\Export\%User%"  

REM für jeden einzelnen Ordner
for /d %%i in ("%Quelle%\*") do (  
    REM bereits im Ziel vorhandene Dateien sofort löschen
    for /f "delims=" %%d in ('xcopy /ehluy "%%i\*.*" "%Ziel%\%%~nxi\"^|findstr /v /c:"Datei(en) kopiert"') do echo del "%%d"  
    REM verbleibende Dateien inkl Ordnerstruktur kopieren
    xcopy /Leh "%%i\*.*" "%Ziel%\%%~nxi\"  
    REM Ordner löschen
    echo rd /s /q "%%i"  
)
bzw für einzelne Ordner:
@echo off & setlocal
set "User=xyz"  
set "Quelle=%userprofile%\..\%User%\Desktop\Der Ordner"  
set "Ziel=D:\Export\%User%\Der Ordner"  

REM bereits im Ziel vorhandene Dateien sofort löschen
for /f "delims=" %%d in ('xcopy /ehluy "%Quelle%\*.*" "%Ziel%\"^|findstr /v /c:"Datei(en) kopiert"') do echo del "%%d"  
REM verbleibende Dateien inkl Ordnerstruktur kopieren
xcopy /Leh "%Quelle%\*.*" "%Ziel%\"  
REM Ordner löschen
echo rd /s /q "%Quelle%"  
Beide Varianten sind zum Testen gedacht (hab' ich nämlich nicht gemahct) und daher durch das groß geschriebene "L" im jeweils zweiten "xcopy"-Befehl und das "echo" vor dem "del" bzw dem "rd" noch "gesichert" - werden diese Sicherheitsmaßnahmen entfernt, passiert's tatsächlich ...

Grüße
bastla

P.S.: Und das Ganze eigentlich nur wegen
mit move geht das nicht, bzw mit xcopy....
face-wink
Mitglied: Friemler
Friemler 20.01.2011 um 20:43:11 Uhr
Goto Top
Hi bastla,

schöne Lösung face-smile !

Aber Zeile 3 von Skript 1 muss nur
set "Quelle=%userprofile%\Desktop"
lauten, bzw. Zeile 3 in Skript 2
set "Quelle=%userprofile%\Desktop\Der Ordner"
Um das ganze Userspezifisch zu machen, muss man mit "ausgeschriebenen" Pfaden arbeiten (ohne %UserProfile%, da steckt der Username schon drin).

[EDIT]
Ich nehme alles zurück (ausser dem Lob face-wink ), habe nicht genau genug hingesehen.

Gruß
Friemler
Mitglied: Florian.Sauber
Florian.Sauber 20.01.2011 um 20:58:51 Uhr
Goto Top
Hallo Ihr zwei!

Ihr wisst hoffentlich, wie hoch ich Eure Batchkenntnisse schätze (!), aber warum so kompliziert?
Tät es da nicht auch ein (zugegebenermassen ungetestetes)

robocopy Quelle Ziel /S /XC /XN /XO /MOVE 

Mit /L kanns ja erst mal getestet und über das Logfile geprüft werden...

LG FLorian
Mitglied: Friemler
Friemler 20.01.2011 um 21:07:39 Uhr
Goto Top
Hallo Flo,

sicherlich ließe sich das auch mit Robocopy lösen, aber erstens ist das (bis XP) kein Bordmittel und zweitens bin ich ein Batch-Spielkind face-wink (Das muss doch auch mit Batchskript gehen!...).

Gruß
Friemler
Mitglied: Florian.Sauber
Florian.Sauber 20.01.2011 um 21:20:30 Uhr
Goto Top
[OT]
...zweitens bin ich ein Batch-Spielkind face-wink (Das muss doch auch mit Batchskript gehen!...).
Da bin ich doch ganz bei Dir. Ein Tor, wer anders dächte face-wink

LG Flo
Mitglied: bastla
bastla 20.01.2011 um 23:49:14 Uhr
Goto Top
[OT]
@Friemler
Schließe mich der Spielkinder-Fraktion an face-wink (und genieße das Lob face-smile, kann dieses aber gleich postwendend an Biber weiterreichen, bei dem ich die Variante mit "xcopy /l" - wie so vieles, was ich inzwischen auch sehr gerne verwende - zum ersten Mal gesehen habe) ...

BTW: Meine konkrete Motivation ist dem "P.S." zu entnehmen.

Grüße
bastla
[/OT]
Mitglied: bodyparts
bodyparts 21.01.2011 um 12:03:55 Uhr
Goto Top
danke euren Kreativenergüssen...

werde ich testen.

Die Ordner haben immer einen "Anfangsnamen"....

out-datxxxx

xxxx kann sich immer unterscheiden

vorab vielen Dank