Prof. Hilfe für Backup per Drive Snapshot mit Batch

:- ********************************************************************************************
:- 
:- Wird das Skript in der "Aufgabenplanung" hinterlegt, muss unter "Starten in (Optional):"
:- das "%workdir%" Verzeichniss eingetragen werden.
:- 
:- ********************************************************************************************


:- --------------------------------------------------------------------------------------------
:- Variablen setzen (nicht vorhandene Verzeichnisse sind vorher zu erstellen!)
:- --------------------------------------------------------------------------------------------

setlocal enabledelayedexpansion

:- --------------------------------------------------------------------------------------------
:- Variablen wurden fürs Forum natürlich geändert!!!!
:- --------------------------------------------------------------------------------------------

set domain=domian
set user=Administrator
set password=Password123456
set mailserver=192.168.168.55
set maildomain=firma.com
set mailrecipient=mail@firma.com
set workdir=\\server01\it$\Snapshot
set logs=\\server01\it$\Snapshot\logs
set tools=\\server01\it$\Snapshot\tools
set serverlist=SERVER01,SERVER02,SERVER03
set countofsnapshots=7
set destination=\\backup\s$

:- --------------------------------------------------------------------------------------------
:- Snapshot Update: sichern, updaten, lizensieren
:- Bei Update Fehler: ruecksichern und benachrichtigen
:- --------------------------------------------------------------------------------------------
:snapshot_update

ren "%workdir%\snapshot.exe" snapshot_last.exe

"%tools%\wget\wget.exe" -t3 --retry-connrefused -w60 -T90 --no-cache -O"%workdir%\snapshot.exe" -o"%logs%\update.txt" "http://www.drivesnapshot.de/download/snapshot.exe"
"%workdir%\snapshot.exe" --register:"%workdir%\license.txt" >> "%logs%\update.txt"

if '%errorlevel%'=='0' goto update_success

copy "%workdir%\snapshot_last.exe" "%workdir%\snapshot.exe"
"%tools%\gbmail.exe" -v -to %mailrecipient% -h %mailserver% -from snapshot.update@%maildomain% -s "Snapshot-Meldung: Update fehlgeschlagen" -file "%logs%\update.txt"
:update_success
del "%workdir%\snapshot_last.exe"


:- --------------------------------------------------------------------------------------------
:- hash-Verzeichnisse anlegen
:- --------------------------------------------------------------------------------------------
:hash_create

for /F "delims=" %%i in ("!serverlist!") do for %%A in (%%i) do if not exist "\\%%A\c$\Snapshot_hash" md "\\%%A\c$\Snapshot_hash"

:- --------------------------------------------------------------------------------------------
:- COUNTOFSNAPSHOTS: Anzahl der Variable prüfen. Dateien älteren Datums werden gelöscht.
:- --------------------------------------------------------------------------------------------
:countofsnapshots

for /F "delims=" %%i in ("!serverlist!") do for %%A in (%%i) do for /F "skip=%countofsnapshots% delims=" %%j in ('dir "%destination%\%%A\*.sna" /A:-D /B /O:-D') do (del "%destination%\%%A\%%j")

:- --------------------------------------------------------------------------------------------
:- LOGICALDISKS: Anzahl der lokalen Laufwerke ermitteln und für eine vollständige Sicherung 
:- in eine Variable schreiben.
:- --------------------------------------------------------------------------------------------
:logicaldisks

for /F "delims=" %%i in ("!serverlist!") do for %%A in (%%i) do "%tools%\psexec.exe" /accepteula \\%%A -u %domain%\%user% -p %password% -h cmd /c for /F "tokens=2 delims==" %%d in ('wmic logicaldisk where "drivetype=3" get name /format:value') do echo %%d

:- --------------------------------------------------------------------------------------------
:- SNAPSHOT FUL: vollständiges Images erstellen, wenn keines vorhanden ist oder wenn lt.
:-               countofsnapshots das alte Images gelöscht wurde.
:- SNAPSHOT DIF: differentielles Image erstellen, wenn ein noch gültiges, vollständiges Image
:-               gefunden und die Anzahl der countofsnapshots noch nicht erreicht wurde.
:- --------------------------------------------------------------------------------------------
:snapshot_complete

for /F "delims=" %%i in ("!serverlist!") do for %%A in (%%i) do "%tools%\psexec.exe" /accepteula \\%%A -u %domain%\%user% -p %password% -c -f -h %workdir%\snapshot.exe C: %destination%\%%A\$computername_$disk_$type.sna -L307200 --AllWriters --AutoBackupSize:512 --CreateDir --FullIfHashIsMissing -RWT --exclude:"\Windows\Memory.dmp","\Windows\Minidump","\Windows\Temp" -h"%SystemDrive%\Snapshot_hash\$computername_$disk.hsh" --LogFile:%logs%\$computername.txt && (
   "%tools%\gbmail.exe" -v -to %mailrecipient% -h %mailserver% -from snapshot.%%A@%maildomain% -s "Snapshot-Meldung: Auftrag erfolgreich" -file "%logs%\%%A.txt"
   ) || (
   "%tools%\gbmail.exe" -v -to %mailrecipient% -h %mailserver% -from snapshot.%%A@%maildomain% -s "Snapshot-Meldung: Auftrag fehlgeschlagen" -file "%logs%\%%A.txt"
   )