Rechnen oder ersetzten hat jemand eine Idee

Option Explicit


'Konstanten für Ein-/Ausgabe  
Const ForReading   = 1
Const ForWriting   = 2
Const ForAppending = 8

'Suchmuster  
Const Pattern1 = "(.*If zelle\.Address = \(""\$C\$)([1-9][0-9])(""\) Then.*)"  
Const Pattern2 = "(.*ActiveSheet\.Range\(""C)([1-9][0-9])(""\)\.Interior\.ColorIndex = 2.*)"  


'Deklaration der Variablen  
Dim objArgs, objFSO, objInStream, objOutStream, objRegExp
Dim strInFilePath, strOutFilePath, arrFileContent


'Hauptprogramm  
Set objFSO  = CreateObject("Scripting.FileSystemObject")  
Set objArgs = WScript.Arguments

If ParseCommandLine(objArgs) Then
  Set objInStream = objFSO.OpenTextFile(strInFilePath, ForReading, False)
  arrFileContent  = Split(objInStream.ReadAll, vbCrLf)
  objInStream.Close

  Set objRegExp        = New RegExp
  objRegExp.Global     = True
  objRegExp.IgnoreCase = True

  Call ReplaceNumbers(arrFileContent, Pattern1)
  Call ReplaceNumbers(arrFileContent, Pattern2)

  Set objOutStream = objFSO.OpenTextFile(strOutFilePath, ForWriting, True)
  objOutStream.Write Join(arrFileContent, vbCrLf)
  objOutStream.Close
End If



'---------------------------------------------------------------------------  
'Unterprogramme  
'---------------------------------------------------------------------------  

'///////////////////////////////////////////  
'Ersetzungen ausführen  
'///////////////////////////////////////////  
Sub ReplaceNumbers(ByRef arrFileContent, ByRef strPattern)
  Dim intLineCnt, objMatch

  objRegExp.Pattern = strPattern

  For intLineCnt = 0 To UBound(arrFileContent)
    For Each objMatch In objRegExp.Execute(arrFileContent(intLineCnt))
      If objMatch.SubMatches.Count > 0 Then
        arrFileContent(intLineCnt) = objMatch.SubMatches(0) & CStr(CInt(objMatch.SubMatches(1)) + 40) & objMatch.SubMatches(2)
      End If
    Next
  Next
End Sub


'///////////////////////////////////////////  
'Befehlszeile einlesen und Name von Ein-  
'und Ausgabedatei ermitteln  
'///////////////////////////////////////////  
Function ParseCommandLine(ByRef objArgs)
  ParseCommandLine = False

  If objArgs.Count > 0 Then
    strInFilePath = objFSO.GetAbsolutePathName(objArgs(0))

    If objFSO.FileExists(strInFilePath) Then
      strOutFilePath = objFSO.BuildPath(objFSO.GetParentFolderName(strInFilePath), _
                                        objFSO.GetBaseName(strInFilePath) _
                                        & "_neu." _  
                                        & objFSO.GetExtensionName(strInFilePath))
      ParseCommandLine = True
    End If
  End If
End Function

cscript /nologo rexplace.vbs "Pfad-zur-zu-ändernden-Datei"