makrosan
Mar 12, 2015, updated at 22:42:48 (UTC)
view1496
view6
0
Goto Top

Setup dateien auf aktuellen stand halten

GermansolvedQuestionBatch, ShellDevelopment
Hi leute,

Ich habe eine Frage,

gibt es eine möglichkeit per Batch setupdateien auf den akutellesten stand zu halten ?


Ich meine wenn ich z.b. Firefox 35.0.1 als setupdatei habe, und das die Batchdatei automatisch die nächste Version herunterlädt in ein Verzeichnis.


Ich hoff Ihr könnt mir helfen


Vielen Dank im Vorraus

Makrosan
comment-contentCommentShareShare
Share on Facebook Share on Twitter Share on Reddit Share on Linkedin

Content-Key: 266084

Url: https://administrator.de/contentid/266084

Printed on: April 25, 2024 at 22:04 o'clock

6 Comments
Latest comment
Goto Top
Member: VGem-e
VGem-e Mar 12, 2015 updated at 22:43:01 (UTC)
Goto Top
Hallo,

willst Du dies mit einer Softwareverteilung über einen Server oder nur als Privatperson nutzen...?

Gruß,
VGem-e
Member: Makrosan
Makrosan Mar 12, 2015 at 22:44:52 (UTC)
Goto Top
Als Privatperson auf einem Server zu testzwecken
Member: Snowman25
Snowman25 Mar 13, 2015 updated at 08:13:51 (UTC)
Goto Top
Hallo @Makrosan,

ich habe mir dazu die Quellen der Setups herausgesucht und lade dieser über Batch-Dateien per FTP bzw. wget herunter.
Beispiel für Firefox:
::::::::::::::::::::::::::::::::::::::::::::::::::::::::
::                Download latest Firefox             ::
::                         V1.0                       ::
::                                                    ::
::                      Snowman25                     ::
::                      14/03/2013                    ::
::                                                    ::
::        Downloads and moves newest Firefox          ::
::          to \\server\public\firefox\               ::
::                                                    ::
::::::::::::::::::::::::::::::::::::::::::::::::::::::::

@ECHO off
COLOR 0a
CLS

:: Options
SET progName=Mozilla Firefox
SET prefix=ff
SET cleanLinks=true
SET proxy=ftp-proxy 21
SET networkpath=\\server\public\firefox
SET ftpscript=%prefix%firefox.ftp
SET menu=%prefix%menu.bat
SET ftptmp=%prefix%ftp.tmp
SET versionstring=%prefix%version.txt

:: Build Menu
ECHO cls>%menu%
ECHO ECHO.>>%menu%
ECHO ECHO %%*>>%menu%
ECHO ECHO =========================>>%menu%
ECHO ECHO.>>%menu%
ECHO ECHO.>>%menu%
ECHO ECHO.>>%menu%
ECHO title %progName% ~ %%*>>%menu%


:: FTP: Get Firefox latest version
CALL %menu% Getting latest Version
ECHO open %proxy%>%ftpscript%
ECHO anonymous@ftp.mozilla.org>>%ftpscript%
ECHO anonymous>>%ftpscript%
ECHO cd pub/firefox/releases/latest/win32/en-US>>%ftpscript%
ECHO ls>>%ftpscript%
ECHO quit>>%ftpscript%
FTP -s:%ftpscript% >%ftptmp%

IF ERRORLEVEL 1 SET error=1

:: Filter out Stub
TYPE %ftptmp%|findstr .exe>%versionstring%
TYPE %versionstring%|findstr /I /V stub>%ftptmp%
SET /p ffversion=<%ftptmp%

:: FTP: Download english installer
CALL %menu% Downloading en_%ffversion%
ECHO open %proxy%>%ftpscript%
ECHO anonymous@ftp.mozilla.org>>%ftpscript%
ECHO anonymous>>%ftpscript%
ECHO cd pub/firefox/releases/latest/win32/en-US>>%ftpscript%
ECHO bin>>%ftpscript%
ECHO get "%ffversion%" "en_%ffversion%">>%ftpscript%  
ECHO quit>>%ftpscript%
FTP -s:%ftpscript% >%ftptmp%

IF ERRORLEVEL 1 SET error=1

:: FTP: Download german installer
CALL %menu% Downloading de_%ffversion%
ECHO open %proxy%>%ftpscript%
ECHO anonymous@ftp.mozilla.org>>%ftpscript%
ECHO anonymous>>%ftpscript%
ECHO cd pub/firefox/releases/latest/win32/de>>%ftpscript%
ECHO bin>>%ftpscript%
ECHO get "%ffversion%" "de_%ffversion%">>%ftpscript%  
ECHO quit>>%ftpscript%
FTP -s:%ftpscript% >%ftptmp%

IF ERRORLEVEL 1 SET error=1

:: Delete old setups
CALL %menu% Delete old setups at %networkpath%
PUSHD "%networkpath%"  
DEL /F *_*.exe
IF ERRORLEVEL 1 SET error=1
POPD

:: move files to network location
CALL %menu% Move files to %networkpath%
MOVE /Y "de_%ffversion%" "%networkpath%"  
MOVE /Y "en_%ffversion%" "%networkpath%"  

IF ERRORLEVEL 1 SET error=1

:: Cleanup and EOF
DEL %menu%
del %ftptmp%
del %versionstring%
del %ftpscript%
ECHO.

IF ERRORLEVEL 1 SET error=1

ECHO Done!
IF %error%x==1x Echo there were errors! & pause>nul

Das holt immer das aktuelle Firefox-Setup auf deutsch und englisch ab.
Ist etwas verkompliziert durch den Einsatz eines FTP-proxies.

Habe ähnliche Skripte für Acrobat Reader, CDBurnerXP, Thunderbird und FlashPlayer.

Gruß,
@Snowman25
heart1
Member: igetyaall
igetyaall Mar 13, 2015 at 12:09:58 (UTC)
Goto Top
Hi,

wenn es für dich privat ist kenne ich eine gute Seite ....

https://ninite.com/

mit wenig Klicks hat man immer alles Aktuell und die Setup Dateien kannst du dir aus deinem Temp holen.

VG
Member: Makrosan
Makrosan Mar 13, 2015 at 16:24:18 (UTC)
Goto Top
Hy danke Snowman25 für deine Antwort und deine Mühe.

Genau das habe ich gesucht.

Gruß

Makrosan
Member: StefanKittel
StefanKittel Mar 14, 2015 at 15:35:20 (UTC)
Goto Top
Hallo,

schau mal hier: https://chocolatey.org/
Chocolatey ist eine Paketverwaltung wie unter Linux üblich.

cinst firefox

Viele Grüße

Stefan
GermansolvedQuestionBatch, ShellDevelopment
Hotly discussed
gleixnerdCheck of ZFW Firewallgleixnerd - 5 Comments