TCP-IP Ports mit Konfiguration auflisten - Win2008Server - Printserver

' Aufruf mit cscript printerData.vbs <optional: servername>  

Set oArgs = WScript.Arguments
if WScript.Arguments.Count <> 1 then
	strComputer = "."  
Else
	strComputer = oArgs(0)
End If


Set objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")  
Set OpSysSet = objWMIService.ExecQuery("select * from Win32_ComputerSystem")  
for each i in OpSysSet
		computerDomain = i.Domain
		computerName = i.DNSHostName
Next

strOutFile = "printerResult_" & computerName & ".txt"  
set fso = createobject("scripting.filesystemobject")  
fso.createtextfile(strOutFile)
set out = fso.opentextfile(strOutFile, 2)

out.writeline "DomainName	ServerName	PrinterName	ShareName	Location (GNS 4.3 konform)	Comment	PortName	PortHostAddress	SAP-Name	DNS-Name	IP-Address	MAC (xx-xx-...)	DriverName	PortNumber	Datatype RAW or LPR	LPRQueue	Owner (email address)	Devicetype (MuFu or normal printer)	Fax enabled	mail enabled	print enabled"  


Set colInstalledPrinters =  objWMIService.ExecQuery("Select * from Win32_Printer")  

For Each objPrinter in colInstalledPrinters
	PrinterName = objPrinter.Name
	ShareName = objPrinter.ShareName
	PrinterLocation = objPrinter.Location
	Comment = objPrinter.Comment
	PortName = objPrinter.PortName
	DriverName = objPrinter.DriverName

	Set colPorts =  objWMIService.ExecQuery("Select * from Win32_TCPIPPrinterPort where Name='" & objPrinter.PortName & "'")  
	For Each objPort in colPorts
		P_HostAddress = objPort.HostAddress
		P_Name = objPort.Name
		P_Number = objPort.PortNumber
		If (objPort.Protocol = 1) Then
			P_Protocol = "RAW"  
		ElseIf (objPort.Protocol = 2) Then
			P_Protocol = "LPR"  
		End If
		P_Queue = objPort.Queue
		P_SNMPEnabled = objPort.SNMPEnabled
	Next

	out.writeline computerDomain & "	" & computerName & "." & computerDomain & "	" & PrinterName & "	" & ShareName & "	" & PrinterLocation & "	" & Comment & "	" & PortName & "	" & P_HostAddress & "					" & DriverName & "	" & P_Number & "	" & P_Protocol & "	" & P_Queue  
Next

out.close