Alle User aus dem AD in txt-Datei mittels .vbs

'* Original von: http://gallery.technet.microsoft.com/scriptcenter/1e3eca73-21c5-4ee4-9bb0-e43ed138aec7  
'*  
'* description: export users from Active Directory to a comma separated text file.   
'*  Use the text file to create users in a new AD with the accompanying import script.   
'*                 
'* author: Chris Pilling   
'* date: 18 June 2008   
'* edit the attributes exported to suit   
'* after running it is probably best to delete lines from the text file for system generated accounts   
  
Zieldatei = "C:\test.log"  
Delim = ";" ' Trennzeichen für Felder in der Zieldatei (im Original ",")  
  
Const ForAppending = 8 
  
Set objRoot = GetObject("LDAP://RootDSE")     ' \   
strDNC = objRoot.Get("DefaultNamingContext")  '  |-> Objekt für Domain-Root als Ausgangspunkt erstellen  
Set objDomain = GetObject("LDAP://" & strDNC) ' /  

Set objFSO = CreateObject("Scripting.FileSystemObject")  
  
Call enumMembers(objDomain) ' Aufruf der eigentlichen Verarbeitungsschleife  
'  Wenn ab einer bestimmten OU begonnen werden soll, oben zB mit  
'Set objDomain = GetObject("LDAP://OU=IT,DC=Test,DC=de")  
' diese OU vorgeben ...  

'Ende Hauptprogramm  

Sub enumMembers(objDomain) ' Unterprogramm, das für jeden Container / jede OU aufgerufen wird  
On Error Resume Next 'Fehler werden uns nicht stoppen! ;-)  
  
For Each objMember In objDomain ' alle Objekte durchgehen  
    If objMember.Class = "user" Then ' verarbeiten, wenn es ein "User"-Objekt ist  
        '* edit the attributes you want to export here - von den folgenden Zeilen nur jene  
        '  behalten, die benötigt werden (die übrigen auskommentieren oder löschen) und  
        '  fehlende Zeilen (wie zB für "company") ergänzen -   
        '  entsprechend dann auch unten die Erstellung des Datensatzes anpassen  
		
        If Not(IsEmpty(objMember.samAccountName)) Then  
            samAccountName = objMember.samAccountName  
        Else  
            samAccountName = ""    
        End If 
        If Not(IsEmpty(objMember.CN)) Then Cn = objMember.CN Else Cn = "" End If   
        If Not(IsEmpty(objMember.GivenName)) Then FirstName =objMember.GivenName Else FirstName = "" End If   
        If Not(IsEmpty(objMember.sn)) Then Lastname = objMember.sn Else LastName = "" End If   
        If Not(IsEmpty(objMember.UserPrincipalName)) Then  
            UserPrincipalName = objMember.UserPrincipalName  
        Else  
            Name = ""    
        End If 
        If Not(IsEmpty(objMember.ProfilePath)) Then  
            ProfilePath = objMember.ProfilePath  
        Else  
            Profile = ""    
        End If 
        If Not(IsEmpty(objMember.HomeDrive)) Then HomeDrive = objMember.HomeDrive Else HomeDrive = "" End If   
        If Not(IsEmpty(objMember.HomeDirectory)) Then  
            HomeDirectory = objMember.HomeDirectory  
        Else  
            HomeDirectory = ""  
        End If 
        If Not(IsEmpty(objMember.ScriptPath)) Then
            LoginScript = objMember.ScriptPath
        Else  
            LoginScript = ""    
        End If 

        ' ab jetzt stehen alle oben ausgelesenen Werte in den entsprechenden Variablen zur Verfügung  
		
        'Datensatz zusammenstellen, im Original Komma als Trennzeichen, in der adaptierten Fassung das oben per Variable festgelegte ";"  
        ' Original-Zeile:   
        strText1 = SamAccountName & "," & CN & "," & FirstName & "," & LastName & "," & UserPrincipalName & _   
            "," & ProfilePath & "," & HomeDrive & "," & HomeDirectory & "," & LoginScript  
        ' adaptiert:  
        strText1 = SamAccountName & Delim & CN & Delim & FirstName & Delim & LastName & Delim & UserPrincipalName & _ 
            Delim & ProfilePath & Delim & Homedrive & Delim & HomeDirectory & Delim & LoginScript
	
        'WScript.Echo strText1 ' Ausgabe des Datensatzes in der Konsole (wenn über "cscript" gestartet; zu empfehlen) oder als MsgBox   
 
        Set objTextFile = objFSO.OpenTextFile(Zieldatei, ForAppending, True) ' Textdatei zum Anfügen (des neuen Satzes / der neuen Zeilen) öffnen  
        objTextFile.WriteLine(strText1) ' Datensatz in Textdatei schreiben und  

        '### hier Deinen Ausgabecode als Ersatz für die einzeilige Version mit strText1 platzieren, also etwa:  
        'objTextFile.WriteLine objMember.ADSPath  
        'objTextFile.WriteLine  
        'objTextFile.WriteLine "CN: " & Cn  
        ' ...  
        ' ####  

        objTextFile.Close                ' Zieldatei wieder schließen  

    End If  
   
    If objMember.Class = "organizationalUnit" or objMember.Class = "container" Then  ' Ist das Objekt ein Container / eine OU ...  
        enumMembers (objMember)  ' ... das Unterprogramm (rekursiv) aufrufen, um dieses Objekt abzuarbeiten  
    End If  
Next  
End Sub

If Not(IsEmpty(objMember.CN)) Then Cn = objMember.CN Else Cn = "" End If

Cn = "" : Cn = objMember.CN