42687
Goto Top

VBS in Batch einbauen (csv auslesen und abarbeiten)

Hallo,

ich brauche mal wieder eure Hilfe,

ich benutze für die Aufnahme neuer Schüler ins System csv dateien.

Anfang:
@echo on
echo Aufnahme von Willi Schmidt aus CSV
echo Juli 2009
title SNW-Systems - Aufnahme aus CSV
rem -----------------------------------------------------------------------------------------------------
Rem Dateibrowser zum anwählen der Datei
echo Bitte geben Sie den Namen der zu importierenden CSV-Datei an>info.tmp
echo quelle.csv>>info.tmp
echo %logonserver%%>>info.tmp
echo (*.csv):*.csv>>info.tmp
call winscript FileOpenBox info.tmp

Rem ### Ergebnis mitteilen
echo Ergebnis>info.tmp
echo OK>>info.tmp
echo Der Dateiname lautet "%wsresult%".>>info.tmp  
del info.tmp
rem --------------------------------------------------------------------------------------------------------
Bis hier her wird nur die CSV Datei über einen Browser angewählt.
rem nun auslesen
set "Namensliste=%wsresult%"  
set "Delim=;"  
for /f "usebackq tokens=1-6 delims=%Delim%" %%a in ("%Namensliste%") do (  
    set "vorname=%%a"  
    set "nachname=%%b"  
    set "fullname=%%c"  
    set "geschlecht=%%d"  
	set "bday=%%e"  
	set "klasse=%%f"  
nun wurden die erfoderlichen Infos ausgelesen und werden im folgenden Schritt weiter verarbeitet.
rem nun alles erforderliche unternehmen
if not exist "%logonserver%\KLASSEN\%%f" md "%logonserver%\KLASSEN\%%f"  
if not exist "%logonserver%\KLASSEN\%%f\%%a" md "%logonserver%\Klassen\%%f\%%a"   
echo %%a;%%b;%%c;%%d;%%e;no>> %logonserver%\KLASSEN\fullname_%%f.csv
xcopy "%logonserver%\vorlage" "%logonserver%\Klassen\%%f\%%a" /E /C /Y /Q /D  
echo Der/Die Schüler/in %%c wurde erfolgreich in die Klasse %%f aufgenommen. >> %logonserver%\LOG\aufnahme_schueler.log
echo %%c erfolgreich angemeldet.
Und nun soll für jede Klasse ein Share erstellt werden.
if exist == "%logonserver%\KLASSEN\%klasse%\TAUSCH" goto over  
if not exist == "%logonserver%\KLASSEN\%klasse%\TAUSCH" md "%logonserver%\KLASSEN\%klasse%\TAUSCH"  
set "Script=C:\Share.vbs"  

set "snw=server"  
set "sharename=TAUSCH_%Klasse%"  
set "comentar=Tauschverzeichnis der Klasse %%f"  

>"%Script%"  echo Const FILE_SHARE = 0  
>>"%Script%" echo Const MAXIMUM_CONNECTIONS = 100  
>>"%Script%" echo.  
>>"%Script%" echo strComputer = "%snw%"  
>>"%Script%" echo Set objWMIService = GetObject("winmgmts:" _  
>>"%Script%" echo ^& "{impersonationLevel=impersonate}!\\" ^& strComputer ^& "\root\cimv2")  
>>"%Script%" echo.  
>>"%Script%" echo Set objNewShare = objWMIService.Get("Win32_Share")  
>>"%Script%" echo.  
>>"%Script%" echo errReturn = objNewShare.Create _  
>>"%Script%" echo ("D:\KLASSEN\%klasse%\TAUSCH", _  
>>"%Script%" echo "%sharename%", FILE_SHARE, _  
>>"%Script%" echo MAXIMUM_CONNECTIONS, "%comentar%")  
"%Script%"  
echo In der naechsten Minute wird das Tauschverzeichnis Ihrer Klasse aktiviert sein.
echo Erstellung der Tauschfreigabe der Klasse %%f.>>%logonserver%\Problem\p.txt
del "%Script%"  
:over
)
Leider hört er einfach nach der 1. oder 2. Zeile auf, aber er soll die csv der Reihe nach abarbeiten.
Was mache ich falsch? muss ich noch ein goto wieder nach oben setzen? bb danke

Content-Key: 119546

Url: https://administrator.de/contentid/119546

Ausgedruckt am: 19.03.2024 um 02:03 Uhr

Mitglied: bastla
bastla 02.07.2009 um 01:33:40 Uhr
Goto Top
Hallo Peter161!

Da das VBScript ja nur die Klasse als Variable benötigt, würde ich es gleich am Anfang (und nur einmal) erzeugen und beim Aufruf die Klasse als Argument übergeben - gänzlich ungetestet könnte der Batch dann so aussehen:
@echo on & setlocal
title SNW-Systems - Aufnahme aus CSV

echo Aufnahme von Willi Schmidt aus CSV
echo Juli 2009

set "Script=C:\Share.vbs"  
set "snw=server"  
>"%Script%"  echo Klasse = WScript.Arguments(0)  
>>"%Script%" echo Const FILE_SHARE = 0  
>>"%Script%" echo Const MAXIMUM_CONNECTIONS = 100  
>>"%Script%" echo.  
>>"%Script%" echo strComputer = "%snw%"  
>>"%Script%" echo Set objWMIService = GetObject("winmgmts:" _  
>>"%Script%" echo ^& "{impersonationLevel=impersonate}!\\" ^& strComputer ^& "\root\cimv2")  
>>"%Script%" echo.  
>>"%Script%" echo Set objNewShare = objWMIService.Get("Win32_Share")  
>>"%Script%" echo.  
>>"%Script%" echo errReturn = objNewShare.Create _  
>>"%Script%" echo ("D:\KLASSEN\" ^& Klasse ^& "\TAUSCH", _  
>>"%Script%" echo "TAUSCH_" ^& Klasse, FILE_SHARE, _  
>>"%Script%" echo MAXIMUM_CONNECTIONS, "Tauschverzeichnis der Klasse " ^& Klasse)  

rem -----------------------------------------------------------------------------------------------------
Rem Dateibrowser zum Anwählen der Datei
echo Bitte geben Sie den Namen der zu importierenden CSV-Datei an>info.tmp
echo quelle.csv>>info.tmp
echo %logonserver%>>info.tmp
echo (*.csv):*.csv>>info.tmp
call winscript FileOpenBox info.tmp
rem --------------------------------------------------------------------------------------------------------
rem nun auslesen
set "Namensliste=%wsresult%"  
set "Delim=;"  
for /f "usebackq tokens=1-6 delims=%Delim%" %%a in ("%Namensliste%") do (  
    
    rem nun alles Erforderliche unternehmen
    if not exist "%logonserver%\KLASSEN\%%f" md "%logonserver%\KLASSEN\%%f"  
    if not exist "%logonserver%\KLASSEN\%%f\%%a" md "%logonserver%\KLASSEN\%%f\%%a"   
    echo %%a;%%b;%%c;%%d;%%e;no>> %logonserver%\KLASSEN\fullname_%%f.csv
    xcopy "%logonserver%\vorlage" "%logonserver%\Klassen\%%f\%%a" /E /C /Y /Q /D  
    echo Der/Die Schüler/in %%c wurde erfolgreich in die Klasse %%f aufgenommen. >> %logonserver%\LOG\aufnahme_schueler.log
    echo %%c erfolgreich angemeldet.
    
    if not exist "%logonserver%\KLASSEN\%%f\TAUSCH" (  
        md "%logonserver%\KLASSEN\%%f\TAUSCH"  

        cscript //nologo "%Script%" "%%f"  
    
        echo In der naechsten Minute wird das Tauschverzeichnis Ihrer Klasse aktiviert sein.
        echo Erstellung der Tauschfreigabe der Klasse %%f.>>%logonserver%\Problem\p.txt
    )

)
Die Variablenzuweisungen für Namen, Geschlecht etc habe ich weggelassen, da diese Variablen ohnehin nicht verwendet wurden und ohne "delayedExpansion" oder ein entsprechendes Unterprogramm auch nicht verwendbar gewesen wären.

Auch die Zeilen 13 bis 18 schienen mir unnötig, da das, was Du ab Zeile 14 in die Datei "info.tmp" geschrieben hast, in Zeile 17 ohnehin wieder gelöscht wird ...

Grüße
bastla

[Edit Biber] in Zeile 28 [echo %logonserver%%>>info.tmp ] ist ein Prozentzeichen zuviel. [/Edit]
[Edit] @Biber aka "Adlerauge": Fehler durch C&P entstanden; ist korrigiert [/Edit]
Mitglied: 42687
42687 02.07.2009 um 16:57:56 Uhr
Goto Top
aha, naja also es können auch verschiene Klassen in einer csv Datei stehen
BSP:
Hans;Meier;Hans Meier,männl.;15.1.1999;Klasse1
Karl;Meier;Karl Meier,männl.;15.1.1999;Klasse2
Eduard;Meier;Eduard Meier,männl.;15.1.1999;Klasse3


Die Variablenzuweisungen für Namen, Geschlecht etc habe ich weggelassen, da diese Variablen ohnehin nicht verwendet wurden und ohne "delayedExpansion" oder ein entsprechendes Unterprogramm auch nicht verwendbar gewesen wären.

GENAU, das war auch ein Problem. wusste aber delayexpansion ni

Auch die Zeilen 13 bis 18 schienen mir unnötig, da das, was Du ab Zeile 14 in die Datei "info.tmp" geschrieben hast, in Zeile 17 ohnehin wieder gelöscht wird ...

Ich hab das einfach so aus der winscriptdemo.bat übernommen.

OK, erstmal vielen Dank.

Also das mit der Share (also die VBS) soll bei jeder Zeile ausgeführt werden, (jedem schüler)

vielen Dank. Peter
Mitglied: bastla
bastla 02.07.2009 um 17:15:59 Uhr
Goto Top
Hallo Peter161!
es können auch verschiene Klassen in einer csv Datei stehen
Trotzdem wird für das Erstellen des Shares nur die jeweilige Klasse benötigt (was ich auch versucht habe, so umzusetzen) ...

Also das mit der Share (also die VBS) soll bei jeder Zeile ausgeführt werden, (jedem schüler)
Das wäre auch mein Plan gewesen - funktioniert es nicht?

Grüße
bastla
Mitglied: 42687
42687 02.07.2009 um 18:36:43 Uhr
Goto Top
ok, na ich bin leider seit heute im Urlaub, aber kann am Montag nochmal testen, ich dachte nur es geht nicht, weil es ja vorher ausgelesen wird. Vielen Dank erstmal. bb peter
Mitglied: bastla
bastla 02.07.2009 um 19:14:17 Uhr
Goto Top
Hallo Peter161!

Der Formulierung "leider im Urlaub" begegnet man auch nicht so oft. face-wink

BTW: Leider bin ich dann ab Montag im Urlaub ... face-wink

Grüße
bastla
Mitglied: 42687
42687 02.07.2009 um 19:15:55 Uhr
Goto Top
naja ich meinte, das ich Leider im Urlaub bin, weil ich das zu zeit nicht testen kann,
na dann danke und schönen urlaub, wird schon nicht so schlimm werden face-wink