st--ta
Goto Top

vbs Logon Script mit 2 gleichen Laufwerksbuchstaben - Gruppenabfrage

Hallo,


ich habe ein vbs-Logon-Script was auch wunderbar in der "normal" -Ausführung funktioniert.
Jedoch benötige ich eine extra-Funktion. Unser System: Windows 2003 Server RS2 und Windows XP Clients.

im Script werden die Gruppen abgefragt und anschließend ein Laufwerk zugeordnet, jede Abteilung/Gruppe erhält Ihr eigenes Laufwerk was immer X:\ ist. Jedoch gibt es einige Mitarbeiter welche zusätzlich das Laufwerk einer anderen Abteilung benötigen, also das X:\ von Abteilung2 z.B.

Jetzt ist meine Frage. Kann man im Script eine Abfrage einbauen mit der man prüft in welcher Gruppe man ist + falls X:\ schon vorhanden - als zweites Laufwerk Y:\ verbindet.


ein Auszug aus dem Script:

If IsAMemberOf(objNetwork.UserDomain,objNetwork.UserName,"Alle User") Then MapIt "Z:","\\filer\public"

If IsAMemberOf(objNetwork.UserDomain,objNetwork.UserName,"EDV") Then MapIt "x:","\\filer\edv"
If IsAMemberOf(objNetwork.UserDomain,objNetwork.UserName,"Einkauf") Then MapIt "x:","\\filer\einkauf"
If IsAMemberOf(objNetwork.UserDomain,objNetwork.UserName,"Konstruktion") Then MapIt "x:","\\filer\konstruktion"


Wie erweitere ich das Script wenn ein User in den Gruppen EDV und Einkauf ist?

Vielen Dank schon einmal für Eure Hilfe.


Gruß
ST

Content-Key: 115062

Url: https://administrator.de/contentid/115062

Ausgedruckt am: 29.03.2024 um 02:03 Uhr

Mitglied: bastla
bastla 30.04.2009 um 15:05:02 Uhr
Goto Top
Hallo st--ta und willkommen im Forum!

Etwa so:
'Ein "FileSystemObject" wird es vermutlich schon geben; dennoch der Vollständigkeit halber:  
Set fso = CreateObject("Scripting.FileSystemObject")  
'  
'  
If IsAMemberOf(objNetwork.UserDomain,objNetwork.UserName,"Einkauf") Then  
    If Not fso.DriveExists("x:") Then  
        MapIt "x:","\\filer\einkauf"  
    Else
        MapIt "y:","\\filer\einkauf"  
    End If
End If
Sollte es eine größere Anzahl von Gruppenmitgliedschaften geben, wäre es alternativ möglich, im "Sub MapIt" vorweg das zu vergebende Laufwerk zu prüfen und, falls bereits vorhanden, solange den Buchstaben zu "erhöhen", bis ein freier Laufwerksbuchstabe gefunden wird - die Vorgabe "x:" wäre dann allerdings eher kontraproduktiv ...

Grüße
bastla
Mitglied: st--ta
st--ta 30.04.2009 um 15:25:28 Uhr
Goto Top
Vielen Dank, klappt super.

Habe jedoch etwas nicht bedacht ;)

das Script läuft ja von oben nach unten. Gruppe EDV kommt vor Einkauf, jedoch bekomme ich wenn ich in beiden Gruppen bin immer beim Einkauf das "Y:" - Ist klar da X: schon vergeben ist. Jedoch soll "X:" immer den Usern zugewiesen werden in den Abteilungen Sie primär arbeiten. Gibts da noch ne Möglichkeit das aus den Benutzerinformationen im AD herauszulesen, etwa aus dem Feld unter "Organisation --> Position"

Gruß
ST
Mitglied: 20638
20638 30.04.2009 um 15:26:27 Uhr
Goto Top
Huhu Zusammen,
Wie wäre es denn Mit einer IFelse etwas weiter aufgebohrt
Ich klau mir den Code mal bei euch face-wink

If IsAMemberOf(objNetwork.UserDomain,objNetwork.UserName,"Einkauf" and objNetwork.UserDomain,objNetwork.UserName,"EDV") Then
MapIt "x:","\\filer\einkauf"
MapIt "y:","\\filer\edv"
Elseif IsAMemberOf(objNetwork.UserDomain,objNetwork.UserName,"Einkauf")
MapIt "x:","\\filer\einkauf"
Elseif....
Else
Endif

Hab ich jetzt nur mal schnell vorgeschrieben. Das die Syntax jetzt 100%tig ist kann ich nicht garantieren.

Gruß
JT
Mitglied: bastla
bastla 01.05.2009 um 19:08:13 Uhr
Goto Top
Hallo st--ta!
Gibts da noch ne Möglichkeit das aus den Benutzerinformationen im AD herauszulesen, etwa aus dem Feld unter "Organisation --> Position"
Besser passend schiene mir anstelle von "Position" den Eintrag aus "Abteilung" zu verwenden, was dann (vorausgesetzt, dass es maximal 2 Zugehörigkeiten geben kann) schematisch (und ungetestet) etwa so zu realisieren wäre:
Abt = GetObject("LDAP://" & CreateObject("ADSystemInfo").UserName).Department 'bzw ".Title", wenn es doch "Position" sein soll  

Select Case Abt
Case "EDV"  
    MapIt "x:","\\filer\edv"  
Case "Einkauf"  
    MapIt "x:","\\filer\einkauf"  
Case "Konstruktion"  
    MapIt "x:","\\filer\konstruktion"  
Case Else
    'was eben für alle Übrigen passieren soll  
End Select

If IsAMemberOf(objNetwork.UserDomain,objNetwork.UserName,"EDV") Then If Abt <> "EDV" Then MapIt "y:","\\filer\edv"  
If IsAMemberOf(objNetwork.UserDomain,objNetwork.UserName,"Einkauf") Then If Abt <> "Einkauf" Then MapIt "y:","\\filer\einkauf"  
'...  
Soferne die Einträge unter "Organisation", der Gruppenname und der Freigabename übereinstimmen (also etwa jeweils "EDV" lauten), ließe sich das Ganze verkürzen auf:
Abteilungen = Array("EDV", "Einkauf", "Konstruktion")  
Abt = GetObject("LDAP://" & CreateObject("ADSystemInfo").UserName).Department  

For Each Abteilung In Abteilungen
    If Abt = Abteilung Then
        MapIt "x:", "\\filer\" & Abteilung  
    ElseIf IsAMemberOf(objNetwork.UserDomain,objNetwork.UserName,Abteilung) Then
        MapIt "y:", "\\filer\" & Abteilung  
    End If
Next
In beiden Varianten sollte das Sub "MapIt" über die Prüfung auf Vorhandensein des Laufwerksbuchstabens ergänzt werden, zB als erste Zeile:
If fso.DriveExists(Parameter_Drive) Then Exit Sub
Grüße
bastla
Mitglied: st--ta
st--ta 04.05.2009 um 09:41:42 Uhr
Goto Top
Super, Danke.

werde ich mal versuchen.

Gruß
ST