VBS - Suchen und Ersetzen

Datei = "D:\1.txt"  
Korr = "D:\TXT-korrektur.txt"  

Set fso = CreateObject("Scripting.FileSystemObject")  

'Ersetzungsdaten in Array einlesen  
Nach = Split(fso.OpenTextFile(Korr).ReadAll, vbCrLf)
MaxIndex = UBound(Nach)
ReDim Von(MaxIndex)
For i = 0 To MaxIndex
    Von(i) = "," & Split(Nach(i), ",")(1) & ",,"  
Next

'in gesamter Zieldatei alle Ersetzungen versuchen  
T = fso.OpenTextFile(Datei).ReadAll
For i = 0 To MaxIndex
    T = Replace(T, Von(i), Nach(i))
Next
fso.CreateTextFile(Datei).Write T

Ordner = "D:\Kunde1"  
Korr = "D:\TXT-korrektur.txt"  
Typ = "txt" 'in Kleinbuchstaben  

Set fso = CreateObject("Scripting.FileSystemObject")  
'gesamte Ersetzungsdatei einlesen, anhand der Zeilenschaltungen aufteilen und  
'die einzelnen Zeilen im Array "Nach" speichern  
Nach = Split(fso.OpenTextFile(Korr).ReadAll, vbCrLf)
MaxIndex = UBound(Nach) 'Anzahl der eingelesenen Zeilen ermitteln  
ReDim Von(MaxIndex) 'Array für die Suchbegriffe ("inhalt6") in passender Größe erstellen  
For i = 0 To MaxIndex 'alle Ersetzungszeilen durchgehen, ...  
    '... anhand der Kommata aufteilen und alles zwischen 1. und 2. Komma  
    '    (="inhalt6" dieser Zeile) als Suchbegriff in das Array-Element schreiben  
    Von(i) = "," & Split(Nach(i), ",")(1) & ",,"  
Next

'alle Unterordner von "Ordner" durchgehen  
For Each Unterordner In fso.GetFolder(Ordner).SubFolders
    'alle Dateien des jeweiligen Unterordners durchgehen  
    For Each Datei In Unterordner.Files
        'verarbeiten, wenn der Dateityp dem Inahlt der Variablen "Typ" (="txt") entspricht;  
        'dabei den ermittelten Typ in Kleinbuchstaben umwandeln, damit der Vergleich  
        'unabhängig von Groß-/Kleinschreibung funktioniert  
        If LCase(fso.GetExtensionName(Datei.Name)) = Typ Then
            'gesamten Dateiinhalt in die Variable "T" einlesen  
            T = Datei.OpenAsTextStream.ReadAll
            'alle Ersetzungszeilen durchgehen, ...  
            For i = 0 To MaxIndex
                '... die Ersetzung vornehmen und das Ergebnis wieder in "T" schreiben  
                T = Replace(T, Von(i), Nach(i))
            Next
            'Inhalt von "T" in eine neue Datei (mit altem Namen) schreiben  
            fso.CreateTextFile(Datei.Path).Write T
        End If
    Next
Next